Manufacturing DevBlog

Inventor API: Change Size of CC Component Placed as Custom

by Vladimir Ananyev

Q: I may use the Change Size command to change a key parameter for a Content Center part placed as a Custom component. But how can I do it programmatically?

A: If we talk about “Change Size as custom”, there is no existed API to support currently. There is a series of internal logic that are implemented in CC.

For example,

• Get the target CC table row

• Get all parameters you need to change

• Get the new values

• Batch Edit the parameters

• …

• Update Part

In this case Inventor changes existing part document via Parameters API and iProperties API directly – no new part, no file replacement. Of course, it is always better to have an appropriate API function, but in this particular case we are able to implement this workflow ourselves.

We access our CC custom component saved locally, then get its current row in the CC family table and suppose we know the new target row number.

User parameter’s names in the CC component are the same as the corresponding InternalNames of the ContentTableColumns in the ContentFamily. So we may read target parameter’s values from the cells in the target ContentTableRow and then update the user parameters in the file on disk.

We should also update several iProperties – the part number, stock number, MemberId and may be other iProperties as well. Finally we should rename component in the browser (name is usually based on part number) and then update both the part and assembly documents.

It is not easy to implement a general purpose utility that could work with any CC family, but fortunately in most cases you work with several particular families (e.g., structural shapes). This could simplify this specific implementation.

The attached VBA code demonstrates the workflow that mimics the “Change Size” UI command for the CC component placed as Custom. This code reads family data from the last component in the browser assuming that it is a CC member and asks the user to enter the new row number. New model parameters and iProperties values are applied to the member file on disk. New file is not created.

Download Mod_CC_4

As a ”proof of concept” this code contains a lot of debug printing and was tested with some structural profiles families only — angles, channels, and i-beams. Hope it could be modified to process other CC families.

Inventor API: Volume and surface area of the multibody part with overlapped bodies

by Vladimir Ananyev

let’s consider the part that consists of two equal overlapped bodies:

	+		=
Volume=2cm3 Area=10 cm2		Volume=2cm3 Area=10 cm2		Expected: Volume=3cm3 Area=14 cm2

Expected volume is 3 cm³.  But on the Physical property tab I see unexpected values:

It looks like UI ignores bodies overlapping.  So the question is how can we calculate the correct values in case of bodies overlapping?

The easiest way is to use TransientBRep API. The following code sample calculates volume and surface area of the transient body that is the result of the Boolean union of the two “real” bodies.

Sub TransientBRep_DoBoolean_Multibody()

'uses TransientBRep to calculate area and volume

'of the two overlapped bodies in the multibody part

 

    Dim oPartDoc As PartDocument

    Set oPartDoc = ThisApplication.ActiveDocument

    Dim oPartDef As PartComponentDefinition

    Set oPartDef = oPartDoc.ComponentDefinition

   

    Dim oRealBody1 As SurfaceBody

    Set oRealBody1 = oPartDef.SurfaceBodies.Item(1)

    Dim oRealBody2 As SurfaceBody

    Set oRealBody2 = oPartDef.SurfaceBodies.Item(2)

 

    Dim oTransientBRep As TransientBRep

    Set oTransientBRep = ThisApplication.TransientBRep

   

    Dim oBody1 As SurfaceBody

    Set oBody1 = oTransientBRep.Copy(oRealBody1)

    Dim oBody2 As SurfaceBody

    Set oBody2 = oTransientBRep.Copy(oRealBody2)

   

    'do Boolean operation on the two bodies

    'only oBody1 has to be transient

    Call oTransientBRep.DoBoolean( _

        oBody1, oBody2, BooleanTypeEnum.kBooleanTypeUnion)

''    Call oTransientBRep.DoBoolean( _

''        oBody1, oBody2, BooleanTypeEnum.kBooleanTypeIntersect)

   

    Debug.Print "Volume = " & oBody1.volume(0.001)

    Debug.Print "Area   = " & GetBodyArea(oBody1)

End Sub

 

Private Function GetBodyArea(ByRef oBody As SurfaceBody) As Double

        Dim area As Double

        area = 0

        Dim oFace As Face

        For Each oFace In oBody.faces

            Dim oEval As SurfaceEvaluator

            Set oEval = oFace.Evaluator

            area = area + oEval.area

        Next

        GetBodyArea = area

End Function

Results:

Volume = 3

Area   = 14

 

If you need to know the volume of the intersections then you should change the type of the Boolean operation to BooleanTypeEnum.kBooleanTypeIntersect.

Results:

Volume = 1

Area   = 6

Texture rotation in the Inventor API

by Vladimir Ananyev

Q: How can I access the rotation and scale data of the texture?

All these values are stored in the appearance asset in the Inventor document.  An asset is a collection of values of different types. They can be simple types like floats, integers, strings, and Booleans, but they can also be more complex types like color, filename, reference to other assets, textures, and choices. In this case we need to find texture and access its values.

The following VBA sample prints all values stored in the AssetTexture object from the active Appearance object.

Sub AssetTextureSample()

    Dim oDoc As PartDocument

    Set oDoc = ThisApplication.ActiveDocument

    Dim oAppearance As Asset

    Set oAppearance = oDoc.ActiveAppearance

 

    Dim oValue As AssetValue

    For Each oValue In oAppearance

 

        If oValue.ValueType = AssetValueTypeEnum.kAssetValueTextureType Then

 

            Dim oTextureAssetValue As TextureAssetValue

            Set oTextureAssetValue = oValue

            Dim oTexture As AssetTexture

            Set oTexture = oTextureAssetValue.value

 

            If oTexture.Item("unifiedbitmap_Bitmap").value <> "" Then

                Debug.Print "---------------------------"

                Debug.Print oAppearance.DisplayName

                Debug.Print "---------------------------"

                Dim v As Variant

                For Each v In oTextureAssetValue.value

                    Debug.Print v.name, v.value

                Next

                Debug.Print "---------------------------" & vbNewLine

            End If

           

        End If  'texture

    Next   'AssetValue

 

    Beep

End Sub

Output:

---------------------------

Birch - Natural Polished

---------------------------

AssetLibID    AFEFC330-5E61-4E24-814F-AE810148B79D

ExchangeGUID 

common_Shared_Asset         common_shared

common_Tint_color            50383104

common_Tint_toggle          False

texture_LinkTextureTransforms             False

texture_MapChannel           1

texture_MapChannel_ID_Advanced             1

texture_MapChannel_UVWSource_Advanced      0

texture_OffsetLock          False

texture_RealWorldOffsetX     0

texture_RealWorldOffsetY     0

texture_RealWorldScaleX      10

texture_RealWorldScaleY      10

texture_ScaleLock           True

texture_UOffset              0

texture_URepeat             True

texture_UScale               1

texture_UVScale              1

texture_VOffset              0

texture_VRepeat             True

texture_VScale               1

texture_WAngle               0

unifiedbitmap_Bitmap        1/Mats/Woods & Plastics.Finish Carpentry.Wood.Red Birch.png

unifiedbitmap_Blur           0,01

unifiedbitmap_Blur_Offset    0

unifiedbitmap_Filtering      0

unifiedbitmap_Invert        False

unifiedbitmap_RGBAmount      1

---------------------------

Highlighted members are responsible for the texture rotate angle (texture_Wangle) and scale (texture_RealWorldScaleX and texture_RealWorldScaleY).  Adding the lines below to the VBA sample you may get the current angle and scale data in more convenient format: 

If oTexture.Item("unifiedbitmap_Bitmap").value <> "" Then

    Debug.Print "---------------------------"

    Debug.Print oAppearance.DisplayName

    Debug.Print "---------------------------"

    Debug.Print "    unified bitmap path:  ", _

        oTexture.Item("unifiedbitmap_Bitmap").value

    Debug.Print "    Rotation angle,deg (texture_WAngle): " _

        & oTexture.Item("texture_WAngle").value

    Debug.Print "    X Size    (texture_RealWorldScaleX): " _

        & oTexture.Item("texture_RealWorldScaleX").value & "  " _

        & oTexture.Item("texture_RealWorldScaleX").Units

    Debug.Print "    Y Size    (texture_RealWorldScaleY): " _

        & oTexture.Item("texture_RealWorldScaleY").value & "  " _

        & oTexture.Item("texture_RealWorldScaleY").Units

    Debug.Print "---------------------------" & vbNewLine

End If

Output:

---------------------------

Birch - Natural Polished

    unified bitmap path:    1/Mats/Woods & Plastics.Finish Carpentry.Wood.Red Birch.png

    Rotation angle,deg (texture_WAngle): 30

    X Size    (texture_RealWorldScaleX): 10  Inch

    Y Size    (texture_RealWorldScaleY): 10  Inch

---------------------------

Note: Rotation angle is represented in degrees in the range 0° – 360°.

Rotation and scale properties are read and write, so we may change them.  Attached part document (Inventor 2016 format) contains the iLogic rule that rotates the active texture according the current value on the slider in the iLogic form:

Here is the iLogic code:

' this iLogic rule rotates the active texture in the range 0° - 360°

' User parameter TextureAngle is controlled by the slider on the iLogic form

DimoDocAsPartDocument = ThisDoc.Document

DimoAppearanceAsAsset = oDoc.ActiveAppearance

DimoValueAsAssetValue

ForEachoValueInoAppearance

    IfoValue.ValueType = AssetValueTypeEnum.kAssetValueTextureTypeThen

        DimoTextureAssetValueAsTextureAssetValue = oValue

        DimoTextureAsAssetTexture = oTextureAssetValue.Value

        IfoTexture.Item("unifiedbitmap_Bitmap").Value <> ""Then

              oTexture.Item("texture_WAngle").Value = TextureAngle

        EndIf

    EndIf

Next

 

Download TestPlate

 

Please refer “Materials and Appearances” overview in the Inventor API Help for additional information on this topic.

Selecting holes in the drawing view filtered by orientation

by Vladimir Ananyev

Let’s suppose we should select all the hole features on the drawing view that are orthogonal to the view plane.

In other words, for every hole feature that is projected on the drawing view we should check its orientation and if this hole is orthogonal to the drawing view plane we should add all its drawing curve segments to the DrawingDocument.SelectSet collection.

.

The part model used here has two non-parallel hole features.

There is a pair of places in the code that are worth noting.

1) DrawingView API provides the magic property that returns all the drawing curves within my drawing view filtered to the input model object. Here the HoleFeature objects were used.

DrawingView.DrawingCurves( [ModelObject] As Variant ) As DrawingCurvesEnumerator

2) How we can check if the hole is orthogonal to the view plane or not?  I did it comparing two vectors. One vector is defined by the view camera orientation. It could be created by two points – Eye and Target.  Calculations of the second vector depend on the hole placement definition. Here I used the normal to the sketch where the center points were created. Vector.IsParallelTo() method gives the answer if these two vectors are parallel or not. If they are parallel all drawing curve segments projected from this hole feature should be added to the SelectSet collection.

 

Sub HoleSelect()

   

    Dim oTG As TransientGeometry

    Set oTG = ThisApplication.TransientGeometry

   

    'active drawing doc

    Dim oDrawDoc As DrawingDocument

    Set oDrawDoc = ThisApplication.ActiveDocument

    'active sheet

    Dim oSheet As Sheet

    Set oSheet = oDrawDoc.ActiveSheet

    'the 1st drawing view

    Dim oView As DrawingView

    Set oView = oSheet.DrawingViews.Item(1)

   

    'camera

    Dim oCamera As Camera

    Set oCamera = oView.Camera

   

    Dim oEye As Point, oTarget As Point

    Set oEye = oCamera.Eye

    Set oTarget = oCamera.Target

    Dim oVec As Vector

    Set oVec = oTG.CreateVector( _

            oEye.x - oTarget.x, _

            oEye.y - oTarget.y, _

            oEye.z - oTarget.z)

   

    Dim oSSet As SelectSet

    Set oSSet = oDrawDoc.SelectSet

    Call oSSet.Clear

   

    'model document, need to find hole features

    Dim oDoc As PartDocument

    Set oDoc = oView.ReferencedDocumentDescriptor.ReferencedDocument

    Dim oDef As PartComponentDefinition

    Set oDef = oDoc.ComponentDefinition

    Dim oHoleFeatures As HoleFeatures

    Set oHoleFeatures = oDef.Features.HoleFeatures

   

    'collection for segments to be selected

    Dim oColl As ObjectCollection

    Set oColl = ThisApplication.TransientObjects.CreateObjectCollection

   

    Dim oHole As HoleFeature

    For Each oHole In oHoleFeatures

   

        Dim oCurves As DrawingCurvesEnumerator

        Set oCurves = oView.DrawingCurves(oHole)

        Debug.Print oHole.name, oCurves.Count

       

        If oCurves.Count > 0 Then

            'this hole feature is seen in the drawing view

            'so we need to check the hole orientation.

            'Method depends on the hole placement definition !

            Dim oSketch As PlanarSketch

            Set oSketch = oHole.PlacementDefinition.HoleCenterPoints.Item(1).Parent

           

            Dim oNormal As UnitVector

            Set oNormal = oSketch.PlanarEntity.Geometry.normal

           

            If oVec.IsParallelTo(oNormal.AsVector, 0.0000001) Then

           

                Debug.Print "Hole is orthogonal"

               

                'populate the collection to select segments later

                Dim oCurve As DrawingCurve

                Dim dcs As DrawingCurveSegment

                For Each oCurve In oCurves

                    For Each dcs In oCurve.Segments

                        Call oColl.Add(dcs)

                    Next

                Next

               

            Else

                Debug.Print "Hole is slanted"  'do nothing

            End If

       

        End If

    Next

   

    'select drawing curve segments found

    Beep

    If oColl.Count > 0 Then

        Call oSSet.SelectMultiple(oColl)

        MsgBox "Done :)"

    Else

        MsgBox "No orthogonal holes found"

    End If

   

End Sub

 

Output to the Immediate Window:

Hole1          8

Hole is slanted

Hole2          2

Hole is orthogonal

 

Selected curves:

Download HoleSelect

Inventor API to Redefine Work Features

by Vladimir Ananyev

The work feature collection objects – WorkPoints, WorkAxes, WorkPlanes – provide the wide range of Add methods to create corresponding work features in the part document. Autodesk Inventor API also provides a rich toolset for manipulating existing work features. In particular, you may redefine the existing work feature to re-associate it to another input geometry.

Take for example the work axis Axis1 in a part that was created by the intersection of two planes Plane1 and Plane2.

Workaxis.SetByTwoPlanes method allows you to redefine the Axis1 by specifying another pair of work planes – Plane1 and Plane3.

Sub RedefineWorkAxis()
  Dim oDoc As PartDocument
  Set oDoc = ThisApplication.ActiveDocument
  Dim oDef As PartComponentDefinition
  Set oDef = oDoc.ComponentDefinition
  Dim oAxis As WorkAxis
  Set oAxis = oDef.WorkAxes.Item("Axis1")
  Dim oPlane1 As WorkPlane
  Set oPlane1 = oDef.WorkPlanes.Item("Plane1")
  Dim oPlane3 As WorkPlane
  Set oPlane3 = oDef.WorkPlanes.Item("Plane3")
  Call oAxis.SetByTwoPlanes(oPlane1, oPlane3)
End Sub

Result:

 

You may redefine work features from iLogic rule as well.
Here is the equivalent iLogic code:

'parent Part document
Dim oDoc As PartDocument = ThisDoc.Document
'part document definition
Dim oDef As PartComponentDefinition = oDoc.ComponentDefinition
'reference to the existing work axis
Dim oAxis As WorkAxis = oDef.WorkAxes.Item("Axis1")
'1st workplane
Dim oPlane1 As WorkPlane = oDef.WorkPlanes.Item("Plane1")
'2nd workplane
Dim oPlane3 As WorkPlane = oDef.WorkPlanes.Item("Plane3")
'redefine Axis1 to be at the intersection of planes 1 and 3
oAxis.SetByTwoPlanes(oPlane1, oPlane3)

 

Here is the full list of Add and Set methods available to create and redefine existing work features.

 

WorkAxis object

AddByAnalyticEdge	SetByAnalyticEdge
AddByLine	SetByLine
AddByLineAndPlane	SetByLineAndPlane
AddByLineAndPoint	SetByLineAndPoint
AddByNormalToSurface	SetByNormalToSurface
AddByRevolvedFace	SetByRevolvedFace
AddByTwoPlanes	SetByTwoPlanes
AddByTwoPoints	SetByTwoPoints
AddFixed	SetFixed

 

WorkPlane

AddByLineAndTangent	SetByLineAndTangent
AddByLinePlaneAndAngle	SetByLinePlaneAndAngle
AddByNormalToCurve	SetByNormalToCurve
AddByPlaneAndOffset	SetByPlaneAndOffset
AddByPlaneAndPoint	SetByPlaneAndPoint
AddByPlaneAndTangent	SetByPlaneAndTangent
AddByPointAndTangent	SetByPointAndTangent
AddByThreePoints	SetByThreePoints
AddByTorusMidPlane	SetByTorusMidPlane
AddByTwoLines	SetByTwoLines
AddByTwoPlanes	SetByTwoPlanes
AddFixed	SetFixed

 

Workpoint

AddAtCentroid	SetAtCentroid
AddByCurveAndEntity	SetByCurveAndEntity
AddByMidPoint	SetByMidPoint
AddByPoint	SetByPoint
AddBySphereCenterPoint	SetBySphereCenterPoint
AddByThreePlanes	SetByThreePlanes
AddByTorusCenterPoint	SetByTorusCenterPoint
AddByTwoLines	SetByTwoLines
AddFixed	SetFixed

Inventor: Dirty flag of Inventor document

by Vladimir Ananyev

Q: Has API any settings that may influence the Dirty flag of the Inventor documents?

A: Since Inventor 11 there is a setting that is affecting the true/false behavior of the dirty property. In UI this setting is on the Save tab of the Application Options: "Prompt to save for re-computable updates". This flag is unchecked by default. It specifies whether a prompt to save the document should be displayed when the document is closed without being explicitly saved after any recomputable changes. The API exposes this option as SaveOptions.PromptSaveForRecomputableChanges.

Use InventorViewControl to print

by Vladimir Ananyev

Q:  Is there a way to use the Inventor View Control to print?

A:  Inventor View Control has the property ApprenticeServerDocument that gives you access to methods and properties of the ApprenticePrintManager object.  This print manager allows to adjust the printing parameters and submit the print job. 

The following button event handler prints the current document using the printer "Autodesk DWF Writer for 2D".

 

Private Sub btn_PRINT_Click(sender As Object, e As EventArgs) Handles btn_PRINT.Click

    With AxInventorViewControl1.ApprenticeServerDocument

      .PrintManager.Printer = "Autodesk DWF Writer for 2D"

      .PrintManager.SubmitPrint()

    End With

End Sub

 

The attached example prints an Inventor 2014 .ipt file from a Visual Basic 2012 project.

 

 

Download ViewerTest_1

Inventor Apprentice: Opening an Assembly Document without loading subcomponents

by Vladimir Ananyev

Issue

Is it possible to open an Assembly Document using Inventor Apprentice without loading all the subcomponents?

Solution

Yes, using the LevelOfDetailRepresentation feature in Inventor, you have control over the components those have been getting loaded when opening the assembly document.

If "All Components Suppressed" representation is used, then the subcomponents will not be loaded.

Sub Main()

 

  Dim oApp As ApprenticeServerComponent _

    = New ApprenticeServerComponent()

 

  Dim FileName As String = "C:\Users\Public\Documents\Autodesk\Inventor 2014\Samples\Models\Assemblies\Stapler\Stapler.iam"

 

  Dim LODsNames() As String

  LODsNames = oApp.FileManager _

    .GetLevelOfDetailRepresentations(FileName)

 

  Debug.Print(vbNewLine & "==========================")

  Debug.Print("Assembly: " & FileName)

  Debug.Print("LOD names:")

  For Each LODName As String In LODsNames

    Debug.Print(LODName)

  Next

  Debug.Print(vbNewLine)

 

  Dim oFileManager As FileManager = oApp.FileManager

 

  '0 - Master

  '1 - All Components Suppressed

  '2 - All Parts Suppressed

  '3 - All Content Center Suppressed

  '4 - custom LoDs

  Dim LodNo As Integer = 2

  Dim DocName As String = oFileManager _

    .GetFullDocumentName(FileName, LODsNames(LodNo))

  Debug.Print("Open DocName: " & DocName)

 

  ' Open the document

  Dim oDoc As ApprenticeServerDocument = oApp.Open(DocName)

 

  'Check the number of files in memory

  Debug.Print("Files in memory:   Files.Count = " _

              & oFileManager.Files.Count)

  For Each oFile As File In oFileManager.Files

    Debug.Print(oFile.FullFileName)

  Next

  Debug.Print(vbNewLine)

 

  oDoc.Close()

  oApp.Close()

End Sub

Inventor: Unable to select internal edge when kPartFaceFilter and kPartEdgeFilter are used

by Vladimir Ananyev

Issue

I am using InteractionEvents.SelectEvents and I would like to allow the user to select an edge that is inside of the part and hidden by an outside face (bottom of a hole for instance). If kPartEdgeFilter is used I am unable to select this inside edge. Is there a way to do this?

Solution

There is a logged Change Request for the ability to select hidden edges with both kPartFaceFilter and kPartEdgeFilter are enabled. However this behavior is consistent with the UI behavior. When no command is active and the selection priority is set to “Select Faces and Edges”, you are not be able to select a hidden edge. The only way to get to it is using the “Select Other” option and loop through the various possibilities. Now the API does not officially support “Select Other” within InteractionEvents. The normal UI behavior of the “Select Other” toolbar popping up after a few seconds has been disabled within InteractionEvents.

However, the user can get to it from the context menu and select that hidden edge (if the mouse points at approximately the same screen location as the edge). And the OnSelect event will fire, albeit with some information (such as ModelPoint of selection) missing.

Inventor: Access sheet metal part bend information from a drawing view

by Vladimir Ananyev

Q: When I select a bend line in a drawing view, I would like to have access to its flat bend results, such as the bend direction, bend angle and bend radius.

A: The following VBA example finds the bend results corresponding to a bend line from a drawing view. Before running this code select a bend line in a drawing document that belongs to the flat bend pattern of a SheetMetal Part.

Private Sub GetBendResultFromSelectedCurve()

 

  Dim oDoc As DrawingDocument

  Set oDoc = ThisApplication.ActiveDocument

 

  'Gets the selected curve segment

  Dim oDwCurveSegment As DrawingCurveSegment

  Set oDwCurveSegment = oDoc.SelectSet.Item(1)

 

  'Gets full drawing curve from the segment

  Dim oDrawingCurve As DrawingCurve

  Set oDrawingCurve = oDwCurveSegment.Parent

 

  'Gets edge

  Dim oEdge As Edge

  Set oEdge = oDrawingCurve.ModelGeometry

 

  'Retrieves component definition from the edge

  Dim oSMDef As SheetMetalComponentDefinition

  Set oSMDef = oEdge.Parent.ComponentDefinition

 

  Dim oFlatPattern As FlatPattern

  Set oFlatPattern = oSMDef.FlatPattern

 

  'Gets flat bend result corresponding to the edge

  Dim oBendResult As FlatBendResult

  Set oBendResult = oFlatPattern.FlatBendResults.Item(oEdge)

 

  'Prints Flat Bend Results

  Debug.Print "---------------- Flat Bend Infos ----------------"

  Debug.Print "Internal Name: " & oBendResult.InternalName

  If oBendResult.IsOnBottomFace Then

    Debug.Print "Bend On Bottom Face"

  Else

    Debug.Print "Bend On Top Face"

  End If

 

  Dim oUOM As UnitsOfMeasure

  Set oUOM = oDoc.UnitsOfMeasure

 

  Debug.Print "Bend Angle  = " & oUOM _

    .GetStringFromValue( _

          oBendResult.Angle, _

          kDefaultDisplayAngleUnits)

  Debug.Print "Bend Radius = " & oUOM _

    .GetStringFromValue( _

          oBendResult.InnerRadius, _

          kDefaultDisplayLengthUnits)

 

  If oBendResult.IsDirectionUp Then

    Debug.Print "Bend Direction: " & "Bend Up"

  Else

    Debug.Print "Bend Direction: " & "Bend Down"

  End If

     

  Debug.Print "-------------------------------------------------"

  Beep

End Sub