Manufacturing DevBlog

Autodesk Manufacturing DevCamp material

We’ve posted the material from the recent MFG DevCamp 2012 to the following locations:-

• ADN extranet >> Events >> Autodesk DevCamps 2012 (ADN members only access)
• Autodesk Developer Network Open site >> API Training Archive section (public)

These links provide one zip for the ease of download. Classes are divided in five tracks:

1. Autodesk Inventor App Development for Beginners
2. Autodesk Inventor App Development for Experts
3. Autodesk PLM
4. Cloud and Mobile Technologies
5. (a) Business Development (b) Autodesk Engineer To Order (ETO)

 

Thanks to those who both presented classes, and those who attended the event. It was great meeting everyone in person, and very interesting hearing about all the interesting projects so many of you are involved with.

How to set the shortcut key to a customized command in Inventor?

Issue

"What is the best method to assign a shortcut key to a command in inventor programmatically via the api? I can see on the command definition there are default shortcut key and override shortcut key properties but which one should I set?"

Solution

The following VBA sample demonstrates how to assign a shortcut key to a customized button added to assembly Panel Bar.

Please note the following several points:

If the shortcut key has been consumed by another command, you can’t use it again for your own command, otherwise you will get a runtime error. For example Ctrl+A is used by the “Select All” command, so you can’t use “Ctrl+A” again. You can get a list of all commands and the shortcut keys consumed by Inventor through the “Copy to clipboard” command which is on the keyboard page of the Customize dialog (Tools>Customize¡­).

The DefaultShortcut property can be used to set the command alias, but can’t be used for setting the accelerator, you should use OverrideShortcut instead. The user interface won’t delete the controls you added, so you need to remove them manually from the user interface.

If the shortcut key is used by you, you can’t use it again even if you delete the corresponding control from UI, unless you reset all keys from the keyboard page on the customize dialog.

Shortcuts of kAcceleratorShortcut type are created by defining the OverrideShortcut to an allowed non-alphanumeric character, for example “Alt+U”, but those are defined as key combinations by Inventor, like “Ctrl+C” or “Alt+H”, you can’t use.

 

 

Private WithEvents oBtnDef As ButtonDefinition

Sub AddBtnDefWithShortcut()

Dim oControlDefs As ControlDefinitions

Set oControlDefs = ThisApplication.CommandManager.ControlDefinitions

'Create our own button command

Set oBtnDef = oControlDefs.AddButtonDefinition("MyControldefinition1", "Internal name for my controldef 1", kShapeEditCmdType)

'Assign shortcut key to the button command

oBtnDef.OverrideShortcut = "Alt+A"

' Find the main assembly command bar.

Dim oAsmCmdBar As CommandBar

Set oAsmCmdBar = ThisApplication.UserInterfaceManager.CommandBars.Item("AMxAssemblyPanelCmdBar")

' Add a control to the command bar.

Call oAsmCmdBar.Controls.AddButton(oBtnDef)

End Sub

 

You can delete the button command created by above code, like this:

 

Sub DeleteControlDef()

Dim oControlDefs As ControlDefinitions

Set oControlDefs = ThisApplication.CommandManager.ControlDefinitions

Dim oDef As ControlDefinition

Set oDef = oControlDefs.Item("Internal name for my controldef 1")

oDef.Delete

End Sub

Inventor Drawing: How to project a WorkAxis from a Part or an Assembly to a DrawingSketch?

Issue

I would like to create a SketchLine inside a DrawingSketch that represents my WorkAxis inside the referenced assembly document.

Solution

The following VB.NET example shows how to retrieve a WorkAxis inside an Assembly and project it onto a newly created DrawingSketch as a SketchLine. To run the example create an axis named "Work Axis1" in the WorkAxes of the assembly.

This VB.NET example is from a button on a form in a standalone exe that connects to Inventor from out of process.

 

Imports Inventor

    Public Class Form1

        Dim m_inventorApp As Inventor.Application = Nothing

 

        Private Sub Button1_Click(ByVal sender As System.Object,  

               ByVal e As System.EventArgs) Handles Button1.Click

 

            Try ' Try to get an active instance of Inventor

 

                Try

                    m_inventorApp = System.Runtime.InteropServices.

                      Marshal.GetActiveObject("Inventor.Application")

 

                Catch ' If not active, create a new Inventor session

 

                    Dim inventorAppType As Type = System.Type.

                            GetTypeFromProgID("Inventor.Application")

 

                    m_inventorApp = System.Activator.CreateInstance(

                                                     inventorAppType)

 

                    'Must be set visible explicitly

                    m_inventorApp.Visible = True

 

                End Try

 

            Catch

                System.Windows.Forms.MessageBox.Show(

                          "Error: couldn't create Inventor instance")

            End Try

 

            ProjectAxisToDrawing()

 

        End Sub

 

        Public Sub ProjectAxisToDrawing()

 

            If m_inventorApp.Documents.Count = 0 Then

                Exit Sub

            End If

 

            If m_inventorApp.ActiveDocument.DocumentType <>

                         DocumentTypeEnum.kDrawingDocumentObject Then

                Exit Sub

            End If

 

            Dim oDrawingDoc As DrawingDocument

            oDrawingDoc = m_inventorApp.ActiveDocument

 

            Try

                Dim oView As DrawingView

                oView = oDrawingDoc.ActiveSheet.DrawingViews(1)

 

                'Retrieve referenced assembly

                Dim oAsmDoc As AssemblyDocument

                oAsmDoc = oView.ReferencedDocumentDescriptor.

                                              ReferencedDocument

 

                'Retrieve WorkAxis

                Dim oWorkAxis As WorkAxis

                oWorkAxis = oAsmDoc.ComponentDefinition.WorkAxes.

                                                   Item("Work Axis1")

 

                Dim oStartPoint As Point = m_inventorApp.

                               TransientGeometry.CreatePoint(0, 0, 0)

                Dim oEndPoint As Point = m_inventorApp.

                               TransientGeometry.CreatePoint(0, 0, 0)

 

                'Retrieve Axis bound points (graphical points)

                Call oWorkAxis.GetSize(oStartPoint, oEndPoint)

 

                'Retrieve points coordinates in sheet space

                Dim oSheetPoint1 As Point2d

                Dim oSheetPoint2 As Point2d

 

                oSheetPoint1 = oView.ModelToSheetSpace(oStartPoint)

                oSheetPoint2 = oView.ModelToSheetSpace(oEndPoint)

 

                'Add new DrawingSketch

                Dim oSketch As DrawingSketch

                oSketch = oView.Sketches.Add

 

                'Retrieve points coordinates in sketch space

                Dim oInSketchPoint1 As Point2d

                Dim oInSketchPoint2 As Point2d

 

                oInSketchPoint1 = oSketch.SheetToSketchSpace(

                                                        oSheetPoint1)

                oInSketchPoint2 = oSketch.SheetToSketchSpace(

                                                        oSheetPoint2)

 

                'Create 2 sketch points

                Dim oSketchPoint1 As SketchPoint

                Dim oSketchPoint2 As SketchPoint

 

                'Open Sketch in Edit Mode

                oSketch.Edit()

 

                oSketchPoint1 = oSketch.SketchPoints.Add(

                                                     oInSketchPoint1)

                oSketchPoint2 = oSketch.SketchPoints.Add(

                                                     oInSketchPoint2)

 

                'Create sketch line that represents the axis

                Call oSketch.SketchLines.AddByTwoPoints(

                                        oSketchPoint1, oSketchPoint2)

 

                'Close Sketch

                Call oSketch.ExitEdit()

            Catch ex As SystemException

                MsgBox(ex.ToString())

            End Try

 

        End Sub

    End Class

In an assembly, how to iterate the attributes of the native faces of an iPart?

Issue

If the faces of an iPart have some attributes and the iPart is placed into an assembly, how to iterate the attributes.

Solution

The attributes that are added in the iPart factory document are not preserved in the iPart members. So the attributes cannot be retrieved when the iPart is inserted into the assembly. To get the attribute, iPartMember should be used.

Suppose there is an iPart whose faces have some attributes. Place the iPart into an assembly. The code below demonstrates how to iterate the attributes using the iPartMember.

 

In VB.Net

    Sub RetrieveAttribute()

        Dim m_inventorApp As Inventor.Application = Nothing

        ' Try to get an active instance of Inventor

        Try

            m_inventorApp = System.Runtime.InteropServices.Marshal.

                            GetActiveObject("Inventor.Application")

        Catch ex As Exception

        End Try

        ' If not active, create a new Inventor session

        If m_inventorApp Is Nothing Then

            Dim inventorAppType As Type = System.Type.

                        GetTypeFromProgID("Inventor.Application")

            m_inventorApp = System.Activator.CreateInstance(

                                                inventorAppType)

        End If

        Dim oAsmDoc As AssemblyDocument

        oAsmDoc = m_inventorApp.ActiveDocument

        Dim oOcc As ComponentOccurrence

        oOcc = oAsmDoc.ComponentDefinition.Occurrences.Item(1)

        Dim oPartDef As PartComponentDefinition

        oPartDef = oOcc.Definition

        Dim oDoc As PartDocument

        oDoc = oPartDef.iPartMember.ParentFactory.Parent

        Dim oSurfaceBody As SurfaceBody

        oSurfaceBody = oDoc.ComponentDefinition.SurfaceBodies.Item(1)

        Dim oFace As Face

        For Each oFace In oSurfaceBody.Faces

            Dim oAttribSet As AttributeSet

            For Each oAttribSet In oFace.AttributeSets

                Dim oAttrib As Inventor.Attribute

                For Each oAttrib In oAttribSet

                    Debug.Print("Name: " + oAttrib.Name +

                                       " Value: " + oAttrib.Value)

                Next

            Next

        Next

 

    End Sub

Error occurs using SketchLines for a profile when trying to create an extrusion

Issue

I create a sketch to create an extrusion. An error is occurring when using the sketch to create a profile. The error occurs on this line. Why am I getting the error?

Set oProfile1 = tySketch.Profiles.AddForSolid"

Here is the VBA code I am using:

 

Sub Test()
    Dim App As Inventor.Application
    Set App = ThisApplication
    ' this code will only work on an active part
    Dim Part1 As PartDocument
    Set Part1 = ThisApplication.ActiveDocument
    Dim TG As TransientGeometry
    Set TG = App.TransientGeometry
   
    'try to read face with transient id 1
    Dim oFace As Face
    Set oFace = Part1.ComponentDefinition.SurfaceBodies(1).BindTransientKeyToObject(1)
   
    Dim tySketch As PlanarSketch
    Dim oWorkPlane As WorkPlane
    Set oWorkPlane = Part1.ComponentDefinition.WorkPlanes.AddFixed(TG.CreatePoint
    (oFace.Evaluator.RangeBox.MinPoint.X, 0, 0), TG.CreateUnitVector(0, 1, 0), TG.CreateUnitVector(0, 0, 1),
    False)
   
    Set oPartCompDef = Part1.ComponentDefinition
    Set tySketch = oPartCompDef.Sketches.Add(oWorkPlane)
   
    ' create some temporary variables for drawing lines
    Dim tyStartPoint As Point2d
    Dim tyEndPoint As Point2d
    Dim tyTmpPoint As Point2d
    Dim tyLine As SketchLine
    Set tyStartPoint = TG.CreatePoint2d(0, 0)
    Set tyEndPoint = TG.CreatePoint2d(0, 0)
    Set tyTmpPoint = TG.CreatePoint2d(0, 0)
   
    'draw some lines to create a shap fo the extrusion
    Set tyStartPoint = tySketch.ModelToSketchSpace(oFace.Evaluator.RangeBox.MinPoint)
    Set tyEndPoint = tySketch.ModelToSketchSpace(oFace.Evaluator.RangeBox.MaxPoint)
    tyTmpPoint.X = tyStartPoint.X
    tyTmpPoint.Y = tyEndPoint.Y
    Set tyLine = tySketch.SketchLines.AddByTwoPoints(tyStartPoint, tyTmpPoint)
    Set tyLine = tySketch.SketchLines.AddByTwoPoints(tyTmpPoint, tyEndPoint)
    Set tyLine = tySketch.SketchLines.AddByTwoPoints(tyEndPoint, tyStartPoint)
   
    ' try to create a profile
    Dim oProfile1 As Profile
    Set oProfile1 = tySketch.Profiles.AddForSolid
    ' Do an extrusion on the solid
    oExtrusion = oPartCompDef.Features.ExtrudeFeatures.AddByDistanceExtent(oProfile, 3, kSymmetricExtentDirection, kJoinOperation, Null)

End Sub

 

Solution

The error occurs because there are no constraints between the SketchLines. You can use SketchPoint.Merge to add the constraints.  You can also use a SketchPoint directly as an argument when the Sketch geometry is being created.

 

        Set oFirstline = tySketch.SketchLines.AddByTwoPoints(¡¬¡¬)

        Set oSecondLine = tySketch.SketchLines.AddByTwoPoints(¡¬¡¬)

        Set oLastline = tySketch.SketchLines.AddByTwoPoints(¡¬¡¬)

 

        Call oFirstline.EndSketchPoint.Merge(

             oSecondLine.StartSketchPoint)

        Call oSecondLine.EndSketchPoint.Merge(

             oLastline.StartSketchPoint)

        Call oFirstline.StartSketchPoint.Merge(

             oLastline.EndSketchPoint)

 

Here is a VB.NET example that creates a sketch, uses SketchPoint.Merge and then creates an extrusion. Before running this code create a part with rectangular faces like a box. This example is from a button on a form in a standalone exe that connects to Inventor from out of process.

 

    Imports Inventor

    Public Class Form1

        Dim m_inventorApp As Inventor.Application = Nothing

 

 

        Private Sub Button1_Click(ByVal sender As System.Object,

                ByVal e As System.EventArgs) Handles Button1.Click

            Try ' Try to get an active instance of Inventor

 

                Try

                    m_inventorApp = System.Runtime.InteropServices.

                     Marshal.GetActiveObject("Inventor.Application")

 

                Catch ' If not active, create a new Inventor session

 

                    Dim inventorAppType As Type = System.Type.

                           GetTypeFromProgID("Inventor.Application")

 

                    m_inventorApp = System.Activator.CreateInstance(

                                                    inventorAppType)

 

                    'Must be set visible explicitly

                    m_inventorApp.Visible = True

 

                End Try

 

            Catch

                System.Windows.Forms.MessageBox.Show(

                   "Error: couldn't create Inventor instance")

            End Try

 

            Test()

 

        End Sub

 

        Sub Test()

            Try

                ' this code will only work on an active part

                Dim Part1 As PartDocument

                Part1 = m_inventorApp.ActiveDocument

 

                Dim TG As TransientGeometry

                TG = m_inventorApp.TransientGeometry

 

                'try to read face with transient id 1

                Dim oFace As Face

                oFace = Part1.ComponentDefinition.

                   SurfaceBodies(1).BindTransientKeyToObject(1)

 

                Dim tySketch As PlanarSketch

                Dim oWorkPlane As WorkPlane

                oWorkPlane = Part1.ComponentDefinition.WorkPlanes.

                                        AddFixed(TG.CreatePoint _

                     (oFace.Evaluator.RangeBox.MinPoint.X, 0, 0),

                                  TG.CreateUnitVector(0, 1, 0), _

                     TG.CreateUnitVector(0, 0, 1), False)

 

                Dim oPartCompDef As PartComponentDefinition

                oPartCompDef = Part1.ComponentDefinition

                tySketch = oPartCompDef.Sketches.Add(oWorkPlane)

 

                'draw some lines to create a shape for the extrusion

                Dim MinPoint As Point2d = tySketch.

                    ModelToSketchSpace(

                                  oFace.Evaluator.RangeBox.MinPoint)

                Dim MaxPoint As Point2d = tySketch.

                    ModelToSketchSpace(

                                  oFace.Evaluator.RangeBox.MaxPoint)

 

                Dim Pnt2 As Point2d = TG.CreatePoint2d(

                                             MaxPoint.X, MinPoint.Y)

 

                Dim tyLine1 As SketchLine = tySketch.SketchLines.

                                      AddByTwoPoints(MinPoint, Pnt2)

                Dim tyLine2 As SketchLine = tySketch.SketchLines.

                                      AddByTwoPoints(Pnt2, MaxPoint)

                tyLine1.EndSketchPoint.Merge(

                                           tyLine2.StartSketchPoint)

 

                Dim Pnt3 As Point2d = TG.CreatePoint2d(M

                                              inPoint.X, MaxPoint.Y)

 

                Dim tyLine3 As SketchLine = tySketch.SketchLines.

                                      AddByTwoPoints(MaxPoint, Pnt3)

                tyLine2.EndSketchPoint.Merge(

                                           tyLine3.StartSketchPoint)

 

                Dim tyLine4 As SketchLine = tySketch.SketchLines.

                                      AddByTwoPoints(Pnt3, MinPoint)

                tyLine3.EndSketchPoint.Merge(

                                           tyLine4.StartSketchPoint)

                tyLine4.EndSketchPoint.Merge(

                                           tyLine1.StartSketchPoint)

 

                ' try to create a profile

                Dim oProfile1 As Profile

                oProfile1 = tySketch.Profiles.AddForSolid

 

                ' Do an extrusion on the solid

                Dim oExtrusion As ExtrudeFeature

                oExtrusion = oPartCompDef.Features.ExtrudeFeatures.

                                  AddByDistanceExtent(oProfile1, 3, _

          PartFeatureExtentDirectionEnum.kSymmetricExtentDirection, _

                    PartFeatureOperationEnum.kJoinOperation, Nothing)

            Catch ex As Exception

                MsgBox(ex.ToString())

            End Try

        End Sub

    End Class

Use PointOnFace and LocateUsingPoint to find corresponding face on the original feature of a PatternElement face

Issue

Is there a way to find the corresponding face on the original feature for PatternElement face?

Solution

There is not a straightforward way to get at the original face. Here is an approach to find the face on the original feature:

1.    Get a sample point on the pattern element face (Face.PointOnFace property)
2.    Find which PatternElement the point belongs to
3.    Transform this point to the original occurrence of the pattern (post multiply by the inverse of the transform obtained using FeaturePatternElement.Transform)
4.    Use the transformed point in SurfaceBody.LocateUsingPoint method to obtain the original face.
5.    Use this original face to get its feature.

Here is a example. Before running this macro select a face from a CircularPatternFeature. (not a face on the original feature) The corresponding face on the original feature, including the original feature will be added to the selectSet.

VB.NET

 

    Private Sub test()

        If m_inventorApp.ActiveDocument.DocumentType <>

           DocumentTypeEnum.kPartDocumentObject Then

            MsgBox("Make a Part Document the active document")

            End

        End If

 

        Dim oPart As PartDocument = m_inventorApp.ActiveDocument

 

        If oPart.SelectSet.Count < 1 Then

            MsgBox(

             "Need to select a face of a circular pattern feature")

            End

        End If

 

        Dim testObj As Object

        testObj = oPart.SelectSet(1)

        If Not TypeOf testObj Is Face Then

            MsgBox("Select a face of a circular patern feature")

            End

        End If

 

        Dim oSelFace As Face

        oSelFace = testObj

 

        Dim oCirPattern As CircularPatternFeature

        testObj = oSelFace.CreatedByFeature

        If Not TypeOf testObj Is CircularPatternFeature Then

            MsgBox(

             "Selected face not a face of a circular patern feature")

            End

        End If

 

        oCirPattern = testObj

 

        Dim oSelFace_PatternElement As FeaturePatternElement

        Dim oPatternElement As FeaturePatternElement

        Dim oEachFace As Face

 

        For Each oPatternElement In oCirPattern.PatternElements

            For Each oEachFace In oPatternElement.Faces

                If oEachFace.TransientKey = oSelFace.TransientKey

                  Then

                    oSelFace_PatternElement = oPatternElement

                    Exit For

                End If

            Next oEachFace

 

            If Not oSelFace_PatternElement Is Nothing Then

                Exit For

            End If

        Next oPatternElement

 

        If Not oSelFace_PatternElement Is Nothing Then

 

            Dim oPtInFace As Point

            oPtInFace = oSelFace.PointOnFace

 

            Dim oMatrix As Matrix

            oMatrix = oSelFace_PatternElement.Transform

            oMatrix.Invert()

 

            Call oPtInFace.TransformBy(oMatrix)

 

            Dim oOrignFace As Face

            oOrignFace = oPart.ComponentDefinition.

              SurfaceBodies(1).

              LocateUsingPoint(ObjectTypeEnum.kFaceObject, oPtInFace)

 

            Call oPart.SelectSet.Select(oOrignFace)

            Dim oOriginalF As PartFeature

 

            oOriginalF = oOrignFace.CreatedByFeature

            Call oPart.SelectSet.Select(oOriginalF)

        End If

    End Sub

Include/exclude parameters from the base part in a derived part

Issue

I have created a derived part from a base part. I would like to programmatically modify the base part parameters that are included in the derived component. Is there a way to do this?

Solution

The Inventor API provides independent control over the base part parameters: The VBA and VB.NET example ModifDerivedParams only includes the parameter named d1 from the base component.

Before running these examples ensure a derived part document is the active document. Note the first two subs are VBA. Below this is a VB.NET example.

    Public Sub ModifDerivedParams()

        If ThisApplication.ActiveDocument.DocumentType <>

           kPartDocumentObject Then

            MsgBox("Make a Part Document the active document")

            End

        End If

 

        Dim oDerPart As PartDocument

        oDerPart = ThisApplication.ActiveDocument

 

        Dim oDerPartComp As DerivedPartComponent

        If oDerPart.ComponentDefinition.ReferenceComponents.

           DerivedPartComponents.Count < 1 Then

            MsgBox("No Derived Part Components in this part")

            End

        End If

 

        oDerPartComp =

         oDerPart.ComponentDefinition.

          ReferenceComponents.DerivedPartComponents(1)

 

        Dim oDerivedPartDef As DerivedPartUniformScaleDef

        oDerivedPartDef = oDerPartComp.Definition

 

        Dim oDerEntity As DerivedPartEntity

        For Each oDerEntity In oDerivedPartDef.Parameters

            If (oDerEntity.ReferencedEntity.Name = "d1") Then

                oDerEntity.IncludeEntity = True

                Exit For

            End If

        Next

        'Set Definition back, so DerivedPart Document is updated

        oDerPartComp.Definition = oDerivedPartDef

    End Sub

 

This VB.NET code is from a button on a Form in a stand alone exe that connects to Inventor out of process.

Imports Inventor

 

    Public Class Form1

        Dim m_inventorApp As Inventor.Application = Nothing

 

 

        Private Sub Button1_Click(ByVal sender As System.Object,  

               ByVal e As System.EventArgs) Handles Button1.Click

            Try ' Try to get an active instance of Inventor

 

                Try

                    m_inventorApp =

                      System.Runtime.InteropServices.

                      Marshal.GetActiveObject("Inventor.Application")

 

                Catch ' If not active, create a new Inventor session

 

                    Dim inventorAppType As Type = System.Type.

                           GetTypeFromProgID("Inventor.Application")

 

                    m_inventorApp = System.Activator.CreateInstance(

                                                     inventorAppType)

 

                    'Must be set visible explicitly

                    m_inventorApp.Visible = True

 

                End Try

 

            Catch

                System.Windows.Forms.MessageBox.Show(

                   "Error: couldn't create Inventor instance")

            End Try

 

            ModifDerivedParams()

 

        End Sub

 

        Public Sub ModifDerivedParams()

            If m_inventorApp.ActiveDocument.DocumentType <>

               DocumentTypeEnum.kPartDocumentObject Then

                MsgBox("Make a Part Document the active document")

                End

            End If

 

            Dim oDerPart As PartDocument

            oDerPart = m_inventorApp.ActiveDocument

 

            Dim oDerPartComp As DerivedPartComponent

            If oDerPart.ComponentDefinition.ReferenceComponents.

               DerivedPartComponents.Count < 1 Then

                MsgBox("No Derived Part Components in this part")

                End

            End If

 

            oDerPartComp =

              oDerPart.ComponentDefinition.ReferenceComponents.

              DerivedPartComponents(1)

 

            Dim oDerivedPartDef As DerivedPartUniformScaleDef

            oDerivedPartDef = oDerPartComp.Definition

 

            Dim oDerEntity As DerivedPartEntity

            For Each oDerEntity In oDerivedPartDef.Parameters

                If (oDerEntity.ReferencedEntity.Name = "d1") Then

                    oDerEntity.IncludeEntity = True

                    Exit For

                End If

            Next

            'Set Definition back, so DerivedPart Document is updated

            oDerPartComp.Definition = oDerivedPartDef

        End Sub

 

    End Class

Include sketches from sub-assemblies in a DrawingView using a sketch proxy

Issue

In the User Interface I can right click on a sub assembly in the browser and select "Get Model Sketches" to include a sketch from the sub-assembly. I need to achieve the same thing programmatically. Is there a way to do this?

Solution

To include / exclude entities for a Drawing View the "SetVisibility" method can be used. The ability to include a sketch from an assembly became available in the 2009 release. In prior versions only part sketches can be included using SetVisibility.

When dealing with a sketch contained in a sub-level assembly, you need to create a proxy for the sketch in the top-level assembly context, because the "SetVisibility" method can only handle objects that exist in the assembly that is represented in the view.

This VBA and VB.NET example iterates through the occurrences of the top-level assembly which is referenced by the view and for every assembly occurrence, it creates a SketchProxy object and includes it. The method can be extended to include sketches in deeper level sub-occurrences.

 

    Public Sub SetAssemblySketchesVisibility()

 

        Dim oDrawingDoc As DrawingDocument

        If ThisApplication.ActiveDocument.DocumentType <>

           kDrawingDocumentObject Then

            MsgBox("need to make a drawing the active document")

            End

        End If

 

        oDrawingDoc = ThisApplication.ActiveDocument

 

        Dim oView As DrawingView

        If oDrawingDoc.ActiveSheet.DrawingViews.Count < 1 Then

            MsgBox("Add a view to the drawing")

            End

        End If

 

        oView = oDrawingDoc.ActiveSheet.DrawingViews(1)

 

        Dim oDoc As Document

        oDoc = oView.ReferencedDocumentDescriptor.ReferencedDocument

 

        If oDoc.DocumentType <> kAssemblyDocumentObject Then

            MsgBox("View's Referenced doc needs to be an assembly")

            End

        End If

 

        Dim oAssy As AssemblyDocument

        oAssy = oView.ReferencedDocumentDescriptor.ReferencedDocument

 

        Dim oSubOcc As ComponentOccurrence

        For Each oSubOcc In oAssy.ComponentDefinition.Occurrences

 

            If oSubOcc.DefinitionDocumentType =

               kAssemblyDocumentObject Then

 

                Dim oSubAssyDef As AssemblyComponentDefinition

                oSubAssyDef = oSubOcc.Definition

 

                Dim oSketch As PlanarSketch

                Debug.Print(oSubAssyDef.Sketches.Count)

                For Each oSketch In oSubAssyDef.Sketches

 

                    Dim oSketchProxy As PlanarSketchProxy

                    Call oSubOcc.CreateGeometryProxy(oSketch,

                                                     oSketchProxy)

 

                    'Set Visibility of the Proxy Object DOES NOT

                    ‘support AssemblySketches with release prior

                    ‘to 2009

                    Call oView.SetVisibility(oSketchProxy, True)

                Next

            End If

        Next

    End Sub

 

This VB.NET example is from a button on a form in a stand alone exe that access Inventor from out of process.

Imports Inventor

    Public Class Form1

        Dim m_inventorApp As Inventor.Application = Nothing

 

        Private Sub Button1_Click(ByVal sender As System.Object,

              ByVal e As System.EventArgs) Handles Button1.Click

            Try ' Try to get an active instance of Inventor

 

                Try

                    m_inventorApp =

               System.Runtime.InteropServices.Marshal.GetActiveObject

                ("Inventor.Application")

 

                Catch ' If not active, create a new Inventor session

 

                    Dim inventorAppType As Type =

                System.Type.GetTypeFromProgID("Inventor.Application")

 

                    m_inventorApp = System.Activator.CreateInstance

                      (inventorAppType)

 

                    'Must be set visible explicitly

                    m_inventorApp.Visible = True

 

                End Try

 

            Catch

                System.Windows.Forms.MessageBox.Show(

                 "Error: couldn't create Inventor instance")

            End Try

 

 

            SetAssemblySketchesVisibility()

 

        End Sub

 

        Public Sub SetAssemblySketchesVisibility()

 

            Dim oDrawingDoc As DrawingDocument

            If m_inventorApp.ActiveDocument.DocumentType <>

               DocumentTypeEnum.kDrawingDocumentObject Then

                MsgBox("need to make a drawing the active document")

                End

            End If

 

            oDrawingDoc = m_inventorApp.ActiveDocument

 

            Dim oView As DrawingView

            If oDrawingDoc.ActiveSheet.DrawingViews.Count < 1 Then

                MsgBox("Add a view to the drawing")

                End

            End If

 

            oView = oDrawingDoc.ActiveSheet.DrawingViews(1)

 

            Dim oDoc As Document

            oDoc =

               oView.ReferencedDocumentDescriptor.ReferencedDocument

 

            If oDoc.DocumentType <>

            DocumentTypeEnum.kAssemblyDocumentObject Then

              MsgBox("View's Referenced doc needs to be an assembly")

              End

            End If

 

            Dim oAssy As AssemblyDocument

            oAssy =

              oView.ReferencedDocumentDescriptor.ReferencedDocument

 

            Dim oSubOcc As ComponentOccurrence

            For Each oSubOcc In oAssy.ComponentDefinition.Occurrences

 

                If oSubOcc.DefinitionDocumentType =

                DocumentTypeEnum.kAssemblyDocumentObject Then

 

                    Dim oSubAssyDef As AssemblyComponentDefinition

                    oSubAssyDef = oSubOcc.Definition

 

                    Dim oSketch As PlanarSketch

                    Debug.Print(oSubAssyDef.Sketches.Count)

                    For Each oSketch In oSubAssyDef.Sketches

 

                        Dim oSketchProxy As PlanarSketchProxy =

                          Nothing

                        Call oSubOcc.CreateGeometryProxy(oSketch,

                                                       oSketchProxy)

 

                        'Set Visibility of the Proxy Object DOES NOT

                        ‘support AssemblySketches with release prior

                        ‘to 2009

                        Call oView.SetVisibility(oSketchProxy, True)

                    Next

                End If

            Next

        End Sub

    End Class

Space entered in a text box of a modeless dialog - causes command to run again (C#)

Issue

I have a custom command that displays a modeless dialog with a textbox. If I enter a space in the textbox the message invokes my custom command so the modeless dialog appears again.  Is there a way to block the key message being sent to the Inevntor message loop when the key is a space?

Solution

To avoid this problem provide Inventor's mainframe window as the owner of the modeless dialog. This code snippet shows the idea:

In C#.Net

oDialog.Show(new InventorMainFrame(m_inventorApplication.MainFrameHWND));

 

And the definition for InventorMainFrame is as below:

 

    internal class InventorMainFrame : System.Windows.Forms.IWin32Window

    {

        public InventorMainFrame(long hWnd) { m_hWnd = hWnd; }

        public System.IntPtr Handle {

          get { return (System.IntPtr)m_hWnd; } }

        private long m_hWnd;

    }

TitleBlockDefinition cannot be deleted even though all the referenced TitleBlocks are deleted

Issue

All of the TitleBlocks which reference a TitleBlockDefinition have been deleted. The IsReferenced property still returns true and an error occurs when I call the delete method. Is there a solution for this?

Solution

If the IsReferenced property returns true it means that the TitleBlockDefinition is still being used. SheetFormats can also reference a TitleBlockDefinition. If the SheetFormats are deleted then the TitleBlockDefinition can be deleted. Access to a SheetFormat became available from Inventor 2009 API. In previous releases you have to delete SheetFormats in the User Interface.

Here is a sample from  Inventor 2009 that deletes a TitleBlockDefinition, SheetFormats and TitleBlocks. 

In VB.Net

    Sub DeleteTBD()

 

        If m_inventorApp.ActiveDocument.DocumentType <>

           DocumentTypeEnum.kDrawingDocumentObject Then

            MsgBox("Make an idw the active document")

            End

        End If

 

        Dim oDoc As DrawingDocument

        oDoc = m_inventorApp.ActiveDocument

 

        ' Find out if TitleBlockDefinition exists

        Dim bTBDfound As Boolean

        bTBDfound = False

 

        Dim oTBD As TitleBlockDefinition

        For Each oTBD In oDoc.TitleBlockDefinitions

            Debug.Print(oTBD.Name)

            If oTBD.Name = "ANSI - Large" Then

                bTBDfound = True

                Exit For

            End If

        Next oTBD

 

        If bTBDfound = False Then

            MsgBox("ANSI - Large Title block already deleted")

            End

        End If

 

        oTBD = oDoc.TitleBlockDefinitions("ANSI - Large")

        If oTBD.IsReferenced = True Then

            Dim oSheetFormat As SheetFormat, oSheet As Sheet

 

            ' Check if there is any instance in SheetFormat/Sheet

            ' that refers to the TitleBlockDefinition

            For Each oSheet In oDoc.Sheets

                If oSheet.TitleBlock.Definition Is oTBD Then

 

                    ' Delete this instance which refers to the

                    ' TitleBlockDefinition

                    oSheet.TitleBlock.Delete()

                End If

            Next

 

            For Each oSheetFormat In oDoc.SheetFormats

                If oSheetFormat.ReferencedTitleBlockDefinition Is

                  oTBD Then

                    ' Delete this instance which refers to the

                    ' TitleBlockDefinition

                    oSheetFormat.Delete()

                End If

            Next

 

            ' Now you can delete the TitleBlockDefinition.

            oTBD.Delete()

        Else

            ' TitleBlockDefinition is not referenced go ahead and

            ' delete

            oTBD.Delete()

        End If

    End Sub