Manufacturing DevBlog

Rotate assembly component around axis

By Adam Nagy

There is already a blog post on rotating inside a drawing, now we'll do the same with an assembly component / component occurrence.

Once you have the matrix of the rotation and the current transformation of the component, you just have to combine them and assign that to the component.

Just select the axis you want to use and the component you want to rotate by 90 degrees, then run the VBA code:

Sub RotateAroundAxis()
  Const PI = 3.14159265358979
  
  Dim d As AssemblyDocument
  Set d = ThisApplication.ActiveDocument
  
  Dim a As WorkAxis
  Set a = d.SelectSet(1)
  
  Dim o As ComponentOccurrence
  Set o = d.SelectSet(2)
  
  Dim t As TransientGeometry
  Set t = ThisApplication.TransientGeometry
    
  Dim l As Line
  Set l = a.Line
  
  Dim mRot As Matrix
  Set mRot = t.CreateMatrix()
  ' PI / 2 => 90 deg
  Call mRot.SetToRotation(PI / 2, l.Direction.AsVector(), l.RootPoint)
  
  Dim m As Matrix
  Set m = o.Transformation
  Call m.PreMultiplyBy(mRot)
  
  o.Transformation = m
End Sub

Result:

 

Fusion 360 Hackathon - API Intro

By Adam Nagy

Fusion 360 Hackathon had its first technical presentation yesterday by Brian.

Download the recording from here or watch it on youtube.

#Fusion360Hackathon

 

Fusion 360 Hackathon Started!

By Adam Nagy

Fusion 360 Hackathon has now officially started.

Yesterday we did the opening ceremony with Viru being master of ceremony, Patrick talking about Fusion 360 and the opportunities around it, Hazel and Anand talking about the Autodesk Exchange App Store and the benefits of using it, and last but not least you could hear Brian and me.
Then we finished with a long Q/A session.

Just like all the sessions during the hackathon, this webcast was recorded as well and can be downloaded from here or watched on youtube.

Don't forget that today we'll have our first technical session with Brian introducing the Fusion 360 API!

#Fusion360Hackathon

 

Side database issues in Mechanical

By Adam Nagy

Side database (or non-working database) is the database of a drawing loaded into memory in the background, i.e. the database of a drawing which is not visible in the UI.

Though AutoCAD Mechanical supports API interaction with side databases, you might run into issues if you try to save a side database. So the best is to avoid that by opening up the document as normal and interact with them programmatically that way.

If you still want to modify and save a drawing in the background then you could open a new AutoCAD instance (acad.exe) in the background that will open the drawing normally and interact with that programmatically (similar how background printing works). You do not have to use COM Automation for it: if the process is started with the appropriate parameters then it could run a script, or some add-in could be set up of autoload that would execute the required actions.

Some notes from the SDK readme file:  

In ACM, the non-working database must be created without associating to the current document. When create AcDbDatabase object, in the AcDbDatabase constructor, you need to set the second parameter, noDocument to true.

Non-working Database
· To use the function, AcDbDatabase::readDwgFile() to open a non-working database, you have to start a transaction first.
· If there are xref drawings attached to a non-working database, then for xref databases to be loaded and resolved, the application must explicitly call the function, acdbResolveCurrentXRefs(). This will ensure that all the xref databases are properly loaded. If the xrefs needs to be redirected, then XLOADCTL needs to be set to 1 prior to calling acdbResolveCurrentXRefs, otherwise the database will not be properly initialized.
· To use the function, amiGetDrawingType() in a non-working database, the non-working database must be created without associating to the current document. When create AcDbDatabase object, in the AcDbDatabase constructor, you need to set the second parameter, noDocument to true.
· To use the function, amiGetKeyFromId() in a non-working database, you have to open a transaction in the non-working database.

Querying a sketch profile to get regions

By Adam Nagy

Since many people are looking for info on the web I'm also adding here this API Help Sample, which in case of Inventor 2016 can be found in "C:\Program Files\Autodesk\Inventor 2016\Local Help\admapi_20_0.chm" 

Description 

This sample demonstrates getting region properties from a sketch profile. 

VBA Sample Code 

To run the sample you must have a sketch active that contains some sketch entities. 

Public Sub GetProfileRegionProperties()
    ' Set a reference to the active sketch.
    ' This assumes a 2D sketch is active.
    Dim oSketch As Sketch
    Set oSketch = ThisApplication.ActiveEditObject
    
    ' Create a default profile from the sketch.
    Dim oProfile As Profile
    Set oProfile = oSketch.Profiles.AddForSolid
    
    ' Set a reference to the region properties object.
    Dim oRegionProps As RegionProperties
    Set oRegionProps = oProfile.RegionProperties

    ' Set the accuracy to medium.
    oRegionProps.Accuracy = kMedium

    ' Display the region properties of the profile.
    Debug.Print "Area: " & oRegionProps.Area
    
    Debug.Print "Perimeter: " & oRegionProps.Perimeter
    
    Debug.Print "Centroid: " & _
                    oRegionProps.Centroid.X & ", " & _
                    oRegionProps.Centroid.Y

    Dim adPrincipalMoments(1 To 3) As Double
    Call oRegionProps.PrincipalMomentsOfInertia(adPrincipalMoments(1), _
                                                    adPrincipalMoments(2), _
                                                    adPrincipalMoments(3))
    Debug.Print "Principal Moments of Inertia: " & _
                    adPrincipalMoments(1) & ", " & _
                    adPrincipalMoments(2)

    Dim adRadiusOfGyration(1 To 3) As Double
    Call oRegionProps.RadiusOfGyration(adRadiusOfGyration(1), _
                                            adRadiusOfGyration(2), _
                                            adRadiusOfGyration(3))
    Debug.Print "Radius of Gyration: " & _
                    adRadiusOfGyration(1) & ", " & _
                    adRadiusOfGyration(2)

    Dim Ixx As Double
    Dim Iyy As Double
    Dim Izz As Double
    Dim Ixy As Double
    Dim Iyz As Double
    Dim Ixz As Double
    Call oRegionProps.MomentsOfInertia(Ixx, Iyy, Izz, Ixy, Iyz, Ixz)
    Debug.Print "Moments: "
    Debug.Print " Ixx: " & Ixx
    Debug.Print " Iyy: " & Iyy
    Debug.Print " Ixy: " & Ixy
    
    Debug.Print "Rotation Angle from projected Sketch Origin to Principle Axes: " _
    & oRegionProps.RotationAngle
    
End Sub

 

Slicing a part and getting mass / section properties from resulting bodies

By Balaji Ramamoorthy

If you wish to slice a part and get mass properties of the resulting bodies and the section properties along the section plane, here are the steps that would be needed using the Inventor API :

1. Slice the part by creating a "SplitFeature" and using the SplitBody API to retain both the resulting bodies.

2. Create two part documents (either visible or otherwise)

3. Copy the surface bodies created in step-1 to the new part documents.

4. Retrieve the Mass properties from the part documents.

5. To retrieve the section properties, use the bodies created in Step-1 and use the ImprintBodies API to identify the overlapping faces.

6. Get the section property from the overlapping faces using the Face.Evaluator. If you need any further information on the section properties, those can be computed from the Face.EdgeLoops and Face.Edges collection.

Here is a VBA code snippet :

 Dim  oPartDoc As  PartDocument

 Set  oPartDoc = ThisApplication.Documents.Add( _

 DocumentTypeEnum.kPartDocumentObject, _

 ThisApplication.FileManager.GetTemplateFile(DocumentTypeEnum.kPartDocumentObject))

 Dim  oDef As  PartComponentDefinition

 Set  oDef = oPartDoc.ComponentDefinition

 Dim  oSketch As  PlanarSketch

 Set  oSketch = oDef.Sketches.Add(oDef.WorkPlanes.Item(3))

 Dim  oTG As  TransientGeometry

 Set  oTG = ThisApplication.TransientGeometry

 Call  oSketch.SketchLines.AddAsTwoPointRectangle( _

 oTG.CreatePoint2d(0, 0), oTG.CreatePoint2d(6, 3))

 Dim  oProfile As  Profile

 Set  oProfile = oSketch.Profiles.AddForSolid()

 Dim  oBaseExtrude As  ExtrudeFeature

 Set  oBaseExtrude = _

 oDef.Features.ExtrudeFeatures.AddByDistanceExtent( _

 oProfile, 4, PartFeatureExtentDirectionEnum.kPositiveExtentDirection, _

 PartFeatureOperationEnum.kJoinOperation)

 Set  oSketch = oDef.Sketches.Add(oDef.WorkPlanes.Item(3))

 Dim  oLine As  SketchLine

 Set  oLine = oSketch.SketchLines.AddByTwoPoints( _

 oTG.CreatePoint2d(2, -1), oTG.CreatePoint2d(3, 2))

 Set  oLine = oSketch.SketchLines.AddByTwoPoints( _

 oLine.EndSketchPoint, oTG.CreatePoint2d(2, 4))

 Set  oProfile = oSketch.Profiles.AddForSurface()

 Dim  oCutExtrude As  ExtrudeFeature

 Set  oCutExtrude = _

 oDef.Features.ExtrudeFeatures.AddByDistanceExtent( _

 oProfile, 5, PartFeatureExtentDirectionEnum.kPositiveExtentDirection, _

 PartFeatureOperationEnum.kSurfaceOperation)

 Dim  oWorkSurface As  WorkSurface

 Set  oWorkSurface = oCutExtrude.SurfaceBody.Parent

 Dim  oSplit As  SplitFeature

 Set  oSplit = oDef.Features.SplitFeatures.SplitBody( _

 oWorkSurface, oDef.SurfaceBodies(1))

 Dim  oMatrix As  Matrix

 Set  oMatrix = ThisApplication.TransientGeometry.CreateMatrix

 oMatrix.SetTranslation _

 ThisApplication.TransientGeometry.CreateVector(0, 0, 10)

 Dim  oPartDoc1 As  PartDocument

 Set  oPartDoc1 = ThisApplication.Documents.Add(kPartDocumentObject, _

 ThisApplication.FileManager.GetTemplateFile(kPartDocumentObject), False )

 oPartDoc1.FullFileName = "C:\\Temp\\Part1.ipt"

 Dim  oBody1 As  SurfaceBody

 Set  oBody1 = oDef.SurfaceBodies.Item(1)

 Call  oPartDoc1.ComponentDefinition.Features.NonParametricBaseFeatures.Add( _

 oBody1, oMatrix)

 Dim  oMassProps1 As  MassProperties

 Set  oMassProps1 = oPartDoc1.ComponentDefinition.MassProperties

 oMassProps1.CacheResultsOnCompute = False 

 Dim  M1 As  Double 

 M1 = oMassProps1.Mass

 Dim  Volume1 As  Double 

 Volume1 = oMassProps1.Volume

 MsgBox "Mass 1 : (kg) " & M1 & vbNewLine & "Volume 1: (cm^3) " _

 & Volume1, vbInformation, "Split Body-1"

 Dim  oPartDoc2 As  PartDocument

 Set  oPartDoc2 = ThisApplication.Documents.Add(kPartDocumentObject, _

 ThisApplication.FileManager.GetTemplateFile(kPartDocumentObject), False )

 oPartDoc2.FullFileName = "C:\\Temp\\Part2.ipt"

 Dim  oBody2 As  SurfaceBody

 Set  oBody2 = oDef.SurfaceBodies.Item(2)

 Call  oPartDoc2.ComponentDefinition.Features.NonParametricBaseFeatures.Add( _

 oBody2, oMatrix)

 Dim  oMassProps2 As  MassProperties

 Set  oMassProps2 = oPartDoc2.ComponentDefinition.MassProperties

 oMassProps2.CacheResultsOnCompute = False 

 Dim  M2 As  Double 

 M2 = oMassProps2.Mass

 Dim  Volume2 As  Double 

 Volume2 = oMassProps2.Volume

 MsgBox "Mass 2 : (kg) " & M2 & vbNewLine & "Volume 2: (cm^3) " _

 & Volume2, vbInformation, "Split Body-2"

 Dim  newBody1 As  SurfaceBody

 Dim  newBody2 As  SurfaceBody

 Dim  body1OverlapFaces As  Faces

 Dim  body2OverlapFaces As  Faces

 Dim  body1OverlapEdges As  Edges

 Dim  body2OverlapEdges As  Edges

 Call  ThisApplication.TransientBRep.ImprintBodies( _

 oBody1, oBody2, True , _

 newBody1, newBody2, body1OverlapFaces, body2OverlapFaces, _

 body1OverlapEdges, body2OverlapEdges)

 For  i = 1 To  body1OverlapFaces.Count

     Dim  overlapFace1 As  Face 

     Set  overlapFace1 = body1OverlapFaces.Item(i)

     MsgBox "Section Area (cm^2) : " & overlapFace1.Evaluator.Area

 Next

Event of Python does not Fire

By Xiaodong Liang

Question:
I created a script by JavaScript as below. It delegates the event workspaceActivated. It works well. When switching the workspace, the event will be fired.

//define event handler var MyWorkspaceActivatedHandler = function(args) {       var ws = args.workspace;       var app = adsk.core.Application.get();       var ui  = app.userInterface;       ui.messageBox(“active workspace is: (JavaScript).'                       +ws.name );          };   function run(context) {       var app = adsk.core.Application.get();       var ui = app.userInterface;       //delegate the event with the handler       ui.workspaceActivated.add(MyWorkspaceActivatedHandler);    } }

But the similar code of Python does not work. It looks it successfully delegates the event, but the event is not fired when switching workspace.

import adsk.core, adsk.fusion, traceback #global event handlers handlers = [] #define event class class MyWorkspaceActivatedHandler(adsk.core.WorkspaceEventHandler):       def __init__(self):           super().__init__()       def notify(self, args):           #fire for the event           ws = args.workspace           app = adsk.core.Application.get()           ui  = app.userInterface                    ui.messageBox(' active workspace is: (Python).' + ws.name ) def run(context):     ui = None     try:        app = adsk.core.Application.get()        ui  = app.userInterface          #delegate the event with the handlers        onWorkspaceActivated = MyWorkspaceActivatedHandler()        ui.workspaceActivated.add(onWorkspaceActivated)        handlers.append(onWorkspaceActivated)               except:         if ui:             ui.messageBox('Failed:\n{}'.format(traceback.format_exc()))

Solution:

When the JavaScript code above runs, it connects the event and then continues to run in the background, allowing its handler to be called and respond to the event. But for a Python script (not an add-in) , it will automatically terminate when it runs. To allow the script to continue to run so it can react the event, adsk.autoTerminate(false) will need to call at the end of run fuction. The argument False indicates Fusion that the script should continue to run in the background.

import adsk.core, adsk.fusion, traceback #global event handlers handlers = [] #define event class class MyWorkspaceActivatedHandler(adsk.core.WorkspaceEventHandler):       def __init__(self):           super().__init__()       def notify(self, args):           #fire for the event           ws = args.workspace           app = adsk.core.Application.get()           ui  = app.userInterface                    ui.messageBox(' active workspace is: (Python).' + ws.name ) def run(context):     ui = None     try:        app = adsk.core.Application.get()        ui  = app.userInterface          #delegate the event with the handlers        onWorkspaceActivated = MyWorkspaceActivatedHandler()        ui.workspaceActivated.add(onWorkspaceActivated)        handlers.append(onWorkspaceActivated)               #if it is a script, call adsk.autoTerminate to indicate        #Fusion to continue run the script.        #if it is an add-in, this line is not required.        adsk.autoTerminate(False)     except:         if ui:             ui.messageBox('Failed:\n{}'.format(traceback.format_exc()))

delete and add rows to existing CustomTable

By Xiaodong Liang

Question:

Given there is a drawing with at least one custom table，and the existing table is not empty. Can I delete the existing rows and add the new data I need?

Solution:

Each Row object of CustomTable.Rows provides Delete method that can remove this row. And CustomTable.Rows also provides Add method to add a new row. So the first way is to delete all old rows one by one, and add the new row one by one. e.g. this is a test drawing with a custom table as below.

Download Testdrawing-2016

The code below will delete all old rows and add new rows.

Sub modifyTable_Way1()       Dim oDrawDoc As DrawingDocument     Set oDrawDoc = ThisApplication.ActiveDocument         ' Set a reference to the active sheet.     Dim oSheet As Sheet     Set oSheet = oDrawDoc.ActiveSheet         Dim oTB As CustomTable     Set oTB = oSheet.CustomTables(1)         'delete the old rows     Dim oRow As Row     For Each oRow In oTB.Rows            oRow.Delete            Next         'assume the new data is available     Dim oContents(1 To 3) As String     oContents(1) = "1 - new"     oContents(2) = "1 - new"     oContents(3) = "Brass- new"          Call oTB.Rows.Add(0, False, oContents)              oContents(1) = "2 - new"     oContents(2) = "2 - new"     oContents(3) = "Aluminium- new"           Call oTB.Rows.Add(0, False, oContents)          oContents(1) = "3 - new"     oContents(2) = "3 - new"     oContents(3) = "Steel- new"           Call oTB.Rows.Add(0, False, oContents)      End Sub

 

After the code, the table becomes:

 

The second way is to make a note on the columns definitions of the CustomTable, call CustomTable.Delete to delete the table, add the table again with the new data.

Sub modifyTable_Way2() ' Set a reference to the drawing document.     ' This assumes a drawing document is active.     Dim oDrawDoc As DrawingDocument     Set oDrawDoc = ThisApplication.ActiveDocument         ' Set a reference to the active sheet.     Dim oSheet As Sheet     Set oSheet = oDrawDoc.ActiveSheet         Dim oTB As CustomTable     Set oTB = oSheet.CustomTables(1)         Dim oTitles() As String     ReDim Preserve oTitles(1 To oTB.Columns.Count)     Dim i As Integer         For i = 1 To oTB.Columns.Count         oTitles(i) = oTB.Columns(i).Title     Next               ' Set the contents of the custom table (contents are set row-wise)     Dim oContents(1 To 9) As String     oContents(1) = "1 - New"     oContents(2) = "1- New"     oContents(3) = "Brass- New"     oContents(4) = "2- New"     oContents(5) = "2- New"     oContents(6) = "Aluminium- New"     oContents(7) = "3- New"     oContents(8) = "1- New"     oContents(9) = "Steel- New"           ' Create new custom table     Dim oTB_New As CustomTable     Set oTB_New = oSheet.CustomTables.Add                        (oTB.Title, oTB.Position, _                        oTB.Columns.Count,               oTB.Rows.Count, oTitles, oContents)                        'delete the old table     oTB.Delete      End Sub

Get constrained occurrences

By Adam Nagy

When you select a component occurrence in the UI the context menu provides you with the Constrained To option to select all constrained occurrences:

If you want to retrieve the same occurrences programmatically, then you can iterate through the constraints of the selected occurrence and store all the occurrences those constraints reference:

Sub ConstrainedTo()
  Dim asm As AssemblyDocument
  Set asm = ThisApplication.ActiveDocument

  Dim occSel As ComponentOccurrence
  Set occSel = asm.SelectSet(1)
  
  Dim tr As TransientObjects
  Set tr = ThisApplication.TransientObjects
  
  Dim coll As ObjectCollection
  Set coll = tr.CreateObjectCollection()
  
  Dim ac As AssemblyConstraint
  For Each ac In occSel.Constraints
    coll.Add ac.OccurrenceOne
    coll.Add ac.OccurrenceTwo
  Next
  
  ' If you want to ignore the originally
  ' selected occurrence then you can remove it
  'coll.RemoveByObject occSel
  
  ' Now we have all the occurrences
  ' Let's list their names
  Dim text As String
  Dim occ As ComponentOccurrence
  For Each occ In coll
    text = text + occ.Name + vbCrLf
  Next
  
  MsgBox text
End Sub

The result: 

 

Get to iPart factory from a member

By Adam Nagy

If there are some features that you would like to get from an iPart instance, then you'll have to get inside the factory, because the instance is just like a derived part referencing the solid from another part document:

If you're using an iPart member inside an assembly then the Open command will take you to the factory, since it's more useful, I guess:

However, when using the API, you'll have to get to the factory from the member. 

If we have the above assembly open and run the following VBA code then it will list the parameters that the iFeature has been placed with inside the iPart factory document:

Sub iFeatureFromFactory()
  Dim asm As AssemblyDocument
  Set asm = ThisApplication.ActiveDocument
  
  Dim coMember As ComponentOccurrence
  Set coMember = asm.ComponentDefinition.Occurrences(1)
  
  ' This will give you back the definition of the
  ' iPart member, not the factory "iPart-01.ipt"
  Dim pcdMember As PartComponentDefinition
  Set pcdMember = coMember.Definition
  
  ' Now this is the actual factory document "iPart.ipt"
  Dim factoryDoc As PartDocument
  Set factoryDoc = pcdMember.iPartMember. _
    ReferencedDocumentDescriptor.ReferencedDocument
  
  Dim pcdFactory As PartComponentDefinition
  Set pcdFactory = factoryDoc.ComponentDefinition
  
  Dim ifFactory As iFeature
  Set ifFactory = pcdFactory.Features.iFeatures(1)
  
  Dim text As String
  text = ifFactory.Name
  
  ' Values are in internal units, e.g. length is cm 
  Dim param As Parameter
  For Each param In ifFactory.Parameters
    text = text + vbCrLf + _
      param.Name + " = " + _
      Str(param.Value)
  Next
  
  MsgBox (text)
End Sub