Manufacturing DevBlog

Crash when creating interaction events for a second document

By Adam Nagy

This is something a .NET developer ran into and I thought could be worth sharing. Spoiler alert: the gist of the article is to free objects you do not need anymore. :)

If you have a global variable that is assigned a newly created InteractionEvents (or another object), then it won't be freed until you assign that something else: either a new InteractionEvents object or Nothing. When it gets freed, only then it will try to unsubscribe from the events the given object provides.

In our case we create an InteractionEvents object, start the interaction, finish the interaction, then close the document and open a new one. Now we start a new interaction, at which point our global variable is still pointing at the old InteractionEvents object which by now is completely invalid, since even the document that it was started in is closed now:

When we assign the new InteractionEvents object to oInteraction, only then it will try to unsubscribe from the previous object's events and that's when things go wrong. In theory it should not bring down the system, but in theory we should not hang on to invalid objects either. :)
The "Basic Selection Using Interaction Events API Sample" in the help file is also showing how to use InteractionEvents and is also assigning Nothing to the variables once the interaction is finished:

Public Function Pick(filter As SelectionFilterEnum) As Object
    ' Initialize flag.
    bStillSelecting = True

    ' Create an InteractionEvents object.
    Set oInteractEvents = ThisApplication.CommandManager.CreateInteractionEvents

    ' etc...

    ' Stop the InteractionEvents object.
    oInteractEvents.Stop

    ' Clean up.
    Set oSelectEvents = Nothing
    Set oInteractEvents = Nothing
End Function

Best thing is to follow the same practice in your code: assign Nothing to objects once you don't need them anymore.

Outer edges of tangentially connected faces

By Adam Nagy

You may want to get the outer edges of multiple connected faces, i.e. ignore the edges connecting them. In this specific case we'll get all the tangentially connected faces of the selected face then get the overall outer edges of those.

Each Face has an EdgeLoops collection, and each EdgeLoop has an IsOuterEdgeLoop property which tells us if it contains the edges of the outer border of the given face. Just because it's an outer edge of the given face it can still be an edge that is connecting two of the faces we are interested in, and if it is then we'll ignore it.

' Utility function just to check if the collection
' we are using already includes a given object
Function IsInCollection( _
o As Object, coll As ObjectCollection) As Boolean
  Dim o2 As Object
  For Each o2 In coll
    If o2 Is o Then
      IsInCollection = True
      Exit Function
    End If
  Next
  
  IsInCollection = False
End Function

' Recursively collect all tangent faces
Sub GetAllTangentiallyConnectedFaces( _
f As Face, faces As ObjectCollection)
  Dim f2 As Face
  For Each f2 In f.TangentiallyConnectedFaces
    If Not IsInCollection(f2, faces) Then
      Call faces.Add(f2)
      Call GetAllTangentiallyConnectedFaces(f2, faces)
    End If
  Next
End Sub

' Only check outer edges, and also ignore common
' edges with other faces
Sub GetOuterEdgesOfFaces( _
faces As ObjectCollection, edges As ObjectCollection)
  Dim f As Face
  For Each f In faces
    Dim el As EdgeLoop
    For Each el In f.EdgeLoops
      If el.IsOuterEdgeLoop Then
        Dim e As Edge
        For Each e In el.edges
          Dim f2 As Face
          For Each f2 In e.faces
            If (Not f Is f2) And _
               (Not IsInCollection(f2, faces)) And _
               (Not IsInCollection(e, edges)) Then
              Call edges.Add(e)
            End If
          Next
        Next
      End If
    Next
  Next
End Sub

Sub SelectOuterEdgesOfConnectedFaces()
  Dim doc As PartDocument
  Set doc = ThisApplication.ActiveDocument
  
  Dim f As Face
  Set f = doc.SelectSet(1)
  Call doc.SelectSet.Clear
  
  Dim tro As TransientObjects
  Set tro = ThisApplication.TransientObjects
  
  Dim faces As ObjectCollection
  Set faces = tro.CreateObjectCollection
  
  Call GetAllTangentiallyConnectedFaces(f, faces)
  
  Dim edges As ObjectCollection
  Set edges = tro.CreateObjectCollection
  
  Call GetOuterEdgesOfFaces(faces, edges)
  
  Call doc.SelectSet.SelectMultiple(edges)
End Sub

The code in action:

Note that in case of the given model all the outer faces are tangentially connected to the initially selected face:

 

Inventor debugging slowed down by error messages

By Adam Nagy

Many Autodesk products are using the same .NET components or the UI, and when debugging Inventor from Visual Studio they can make the Output/Debug window quite noisy, and can also slow down things considerably.

Same inside AutoCAD:
- Making AutoCAD less noisy when debugging 
- Solution for many errors when debugging my first plug-in with VB.net Express 2010

And the solution is also the same here too. 
In my Output window I saw that most entries were created by these two components: System.Windows.Data and System.Windows.Media.Animation.

So I removed them by adding this section in the Inventor.exe.config file: 

  <system.diagnostics>
    <sources>
      <source name="System.Windows.Data"
              switchName="SourceSwitch">
        <listeners>
          <remove name="Default" />
        </listeners>
      </source>
      <source name="System.Windows.Media.Animation"
              switchName="SourceSwitch">
        <listeners>
          <remove name="Default" />
        </listeners>
      </source>
    </sources>
  </system.diagnostics>

 

View specific Client Graphics

By Adam Nagy

When you create client graphics, you can also specify in which view they will be visible via the GraphicsNode.VisibleInViews collection.

Here is a VBA sample that creates view specific graphics in each view window:

Sub DisplayGraphicsInViewSample()
  ThisApplication.Documents.CloseAll
  
  Dim oDoc As PartDocument
  Set oDoc = ThisApplication.Documents.Add(kPartDocumentObject)
  oDoc.Views.Add
  
  Dim oRangeViews As ControlDefinition
  Set oRangeViews = ThisApplication.CommandManager.ControlDefinitions( _
    "AppArrangeAllWindowsCmd")
  oRangeViews.Execute
  
  Dim oCG As ClientGraphics
  Set oCG = oDoc.ComponentDefinition.ClientGraphicsCollection.Add( _
    "ClientGraphics")
  
  ' graphics in this node will be displayed in the first View
  Dim oNode1 As GraphicsNode
  Set oNode1 = oCG.AddNode(1)
  oNode1.VisibleInViews.Add oDoc.Views(1)
  
  Dim oText1 As TextGraphics
  Set oText1 = oNode1.AddTextGraphics
  oText1.Text = oDoc.Views(1).Caption
  oText1.PutTextColor 255, 0, 0
  
  ' graphics in this node will be displayed in the second View
  Dim oNode2 As GraphicsNode
  Set oNode2 = oCG.AddNode(2)
  oNode2.VisibleInViews.Add oDoc.Views(2)
  
  Dim oText2 As TextGraphics
  Set oText2 = oNode2.AddTextGraphics
  oText2.Text = oDoc.Views(2).Caption
  oText2.PutTextColor 0, 255, 0
  
  ' update views
  oDoc.Views(1).Update
  oDoc.Views(2).Update
End Sub

The result:

 

UnInclude WorkSurfaces in all DrawingViews on all Sheets

By Adam Nagy

This is a continuation of the article UnInclude WorkSurfaces in a DrawingView

The only difference is that now we are iterating through all the sheets and all the drawing views on them, and also take into account the fact that the referenced document could be an assembly or a part.

VBA code:

Sub CollectSurfacesInPart( _
doc As PartDocument, occ As ComponentOccurrence, _
coll As ObjectCollection)
Dim ws As WorkSurface
  Dim pcd As PartComponentDefinition
  Set pcd = doc.ComponentDefinition
  
  For Each ws In pcd.WorkSurfaces
    Dim wsp As WorkSurfaceProxy
    If Not occ Is Nothing Then
      Call occ.CreateGeometryProxy(ws, wsp)
      Call coll.Add(wsp)
    Else
      Call coll.Add(ws)
    End If
  Next
End Sub

Sub CollectSurfacesInAssembly( _
occs As ComponentOccurrences, coll As ObjectCollection)
  Dim occ As ComponentOccurrence
  For Each occ In occs
    If occ.SubOccurrences.Count > 0 Then
      Call CollectSurfacesInAssembly(occ.SubOccurrences, coll)
    End If
    
    If TypeOf occ.Definition Is PartComponentDefinition Then
      Call CollectSurfacesInPart(occ.Definition.Document, occ, coll)
    End If
  Next
End Sub

Sub IncludeAllSurfacesNot()
  Dim dwg As DrawingDocument
  Set dwg = ThisApplication.ActiveDocument

  ' Iterate through all the sheets
  Dim sh As Sheet
  For Each sh In dwg.Sheets
    ' Iterate through all the views
    Dim dv As DrawingView
    For Each dv In sh.DrawingViews
      Dim doc As Document
      Set doc = dv.ReferencedDocumentDescriptor.ReferencedDocument
      
      Dim tro As TransientObjects
      Set tro = ThisApplication.TransientObjects
      
      Dim coll As ObjectCollection
      Set coll = tro.CreateObjectCollection
      
      If TypeOf doc Is AssemblyDocument Then
        Call CollectSurfacesInAssembly( _
          doc.ComponentDefinition.Occurrences, coll)
      ElseIf TypeOf doc Is PartDocument Then
        Call CollectSurfacesInPart(doc, Nothing, coll)
      End If
      
      Dim ws As WorkSurface
      For Each ws In coll
        Call dv.SetIncludeStatus(ws, False)
      Next
    Next
  Next
End Sub

iLogic Rule:

Sub Main()
  Dim dwg As DrawingDocument
  dwg = ThisApplication.ActiveDocument

  ' Iterate through all the sheets
  Dim sh As Sheet
  For Each sh In dwg.Sheets
    ' Iterate through all the views
    Dim dv As DrawingView
    For Each dv In sh.DrawingViews
      Dim doc As Document
      doc = dv.ReferencedDocumentDescriptor.ReferencedDocument
      
      Dim tro As TransientObjects
      tro = ThisApplication.TransientObjects
      
      Dim coll As ObjectCollection
      coll = tro.CreateObjectCollection
      
      If TypeOf doc Is AssemblyDocument Then
        Call CollectSurfacesInAssembly( _
          doc.ComponentDefinition.Occurrences, coll)
      ElseIf TypeOf doc Is PartDocument Then
        Call CollectSurfacesInPart(doc, Nothing, coll)
      End If
      
      Dim ws As WorkSurface
      For Each ws In coll
        Call dv.SetIncludeStatus(ws, False)
      Next
    Next
  Next
End Sub

Sub CollectSurfacesInPart( _
doc As PartDocument, occ As ComponentOccurrence, _
coll As ObjectCollection)
Dim ws As WorkSurface
  Dim pcd As PartComponentDefinition
  pcd = doc.ComponentDefinition
  
  For Each ws In pcd.WorkSurfaces
    Dim wsp As WorkSurfaceProxy
    If Not occ Is Nothing Then
      Call occ.CreateGeometryProxy(ws, wsp)
      Call coll.Add(wsp)
    Else
      Call coll.Add(ws)
    End If
  Next
End Sub

Sub CollectSurfacesInAssembly( _
occs As ComponentOccurrences, coll As ObjectCollection)
  Dim occ As ComponentOccurrence
  For Each occ In occs
    If occ.SubOccurrences.Count > 0 Then
      Call CollectSurfacesInAssembly(occ.SubOccurrences, coll)
    End If
    
    If TypeOf occ.Definition Is PartComponentDefinition Then
      Call CollectSurfacesInPart(occ.Definition.Document, occ, coll)
    End If
  Next
End Sub

Here you can see a sample model where the above code would switch off all the work surfaces on all the sheets, whether the view has a part or assembly in it: 

 

Is this object supported by the API?

By Adam Nagy

If you know how to create a given object through the UI then it's quite easy to tell if it's supported by the API or not:
1) Create such an object 
2) Select it in the User Interface
3) Debug into a VBA code like the one below and check in the Watches window what info you get. If its Value is something not very useful like "Nothing" then unfortunately it's not supported

Sub GetObject()
  Dim obj As Object
  Set obj = ThisApplication.ActiveDocument.SelectSet(1)
End Sub

E.g. selecting a Welding symbol will produce such result:

 

Fusion 360 App Store

By Adam Nagy

The Fusion 360 App Store now has apps using the new APIs as well and yours could be among them too ;)

At the moment there is only Python and JavaScript API available, which do not really provide IP protection. However, it is perfect if you just want to provide some free utilities or want to hook up the app to a web service which provides the main functionality for the user.

It's already a good time to play around with the API to see what's available, how things work. So by the time the C++ API becomes available you are already familiar with the basics. The best place to get started is probably here: http://autodesk.com/developfusion   

Have fun! :) 

Autodesk Exchange Apps Store – Publisher Survey

By Virupaksha Aithal

It is my pleasure to announce the launch of inaugural Autodesk Exchange Apps Store – Publisher survey. I hope you’ll be willing to give 5-10 minutes of your time to take the survey – the results will be used to guide the efforts of Autodesk Exchange Apps Store team.

Click here to take survey

The survey will remain open until 12th of June 2015. 

Use AutoCAD API in DWG file

By Adam Nagy

When interacting with a DWG type drawing document, you can also use the AutoCAD API in it through the ObjectDBX type library.

From the DrawingDocument.ContainingDWGDocument you'll get back an AcadDatabase object that you can use to drill down into the drawing's contents.

As an example for showing how to achieve something using the Inventor API vs the AutoCAD API, here are two functions which are supposed to be doing the same thing: iterating through the Sheets (Layouts in AutoCAD) and set the Prompt Text values (Attribute Text in AutoCAD) for a given AutoCADBlock (Block Reference in AutoCAD).

Inventor code:

Sub SetAttributesOnSheets()

  Dim oDrawDoc As DrawingDocument
  Set oDrawDoc = ThisApplication.ActiveDocument
    
  Dim Blockname As String
  Blockname = "Testblock"

  Dim oSheet As Sheet
  For Each oSheet In oDrawDoc.Sheets
    Dim oBlock As AutoCADBlock
    For Each oBlock In oSheet.AutoCADBlocks
      If oBlock.Name = Blockname Then
        Dim tagStrings() As String
        Dim textStrings() As String
    
        oBlock.GetPromptTextValues tagStrings, textStrings
    
        Dim i As Integer
        For i = LBound(tagStrings) To UBound(tagStrings)
          If tagStrings(i) = "TEXT1" Then
            textStrings(i) = "text1text"
          ElseIf tagStrings(i) = "TEXT2" Then
            textStrings(i) = "text2text"
          End If
        Next
    
        ' If multiple tag strings are the same then it will
        ' only set the value for the first one of them
        ' That's one of the reasons for this article
        ' to show how to do it using the AutoCAD API instead
        ' which seems to be working fine and can be used as
        ' a workaround
        oBlock.SetPromptTextValues tagStrings, textStrings
      End If
    Next
  Next
End Sub

AutoCAD/ObjectDBX code: 

Sub SetAttributesOnLayouts()

  Dim oDrawDoc As DrawingDocument
  Set oDrawDoc = ThisApplication.ActiveDocument
   
  Dim Blockname As String
  Blockname = "Testblock"
    
  ' Using AutoCAD API
  ' If you want to declare variables using their
  ' exact type, which will provide you with intelli-sense
  ' as well, then you need to reference the
  ' "AutoCAD/ObjectDBX Common  Type Library"
  ' through "Tools >> References"
  ' You can also declare the variables as "Object" instead, in
  ' which case you are doing so called "late-binding"
  ' which does not require you to reference the type library:
  ' e.g.: Dim oDb As Object
  Dim oDb As AcadDatabase
  Set oDb = oDrawDoc.ContainingDWGDocument
  
  ' This way we can set the attribute values even inside 
  ' the model space layout which does not seem to be 
  ' possible even through the Inventor User Interface 
  Dim oLayout As AcadLayout
  For Each oLayout In oDb.Layouts
    Dim oBlock As AcadBlock
    Set oBlock = oLayout.Block
  
    Dim oEnt As AcadEntity
    For Each oEnt In oBlock
      If TypeOf oEnt Is AcadBlockReference Then
        Dim oBR As AcadBlockReference
        Set oBR = oEnt
      
        If oBR.Name = Blockname Then
          Dim oAtts As Variant
          oAtts = oBR.GetAttributes()
        
          Dim i As Integer
          For i = LBound(oAtts) To UBound(oAtts)
            Dim oRef As AcadAttributeReference
            Set oRef = oAtts(i)
          
            If oRef.TagString = "TEXT1" Then
              oRef.TextString = "text1text"
            ElseIf oRef.TagString = "TEXT2" Then
              oRef.TextString = "text2text"
            End If
          Next
        End If
      End If
    Next
  Next
  
  Call oDrawDoc.Update
End Sub

Result:

 

Use GoExcel outside a rule

By Adam Nagy

It’s possible to call GoExcel directly, but it’s not documented and we don’t support it. For Excel functionality you can use the Excel COM API directly instead of going through iLogic. That's what iLogic is using too and that should provide access to all Excel functionality, not only those exposed in iLogic. 

If you want to use GoExcel from anywhere (.NET AddIn or even external application) then you could wrap the functionality you need inside e.g. an external rule with arguments. The arguments are in the form of an Inventor NameValueMap. You can use this “rule with arguments” method to indirectly call any of the iLogic functions from an exe or addin.

Here’s a sample rule with some GoExcel code:

' In this case the code is saved 
' in "C:\Test3\iLogicExcelTest.iLogicVb"
Dim filePath As String = RuleArguments("FilePath")
Dim sheetName As String = RuleArguments("Sheet")
Dim dia As Double = RuleArguments("Dia")
Dim length As Double = RuleArguments("Length")
 
Dim rowNum As Integer = GoExcel.FindRow( _
  filePath, sheetName, "Dia", "=", dia, "Length", "=", length)
 
If (rowNum > 0) Then
  Dim outputs As NameValueMap = _
    ThisServer.TransientObjects.CreateNameValueMap()
  outputs.Add("PartNumber", GoExcel.CurrentRowValue("PartNumber"))
 
  RuleArguments.Arguments.Add("Outputs", outputs)
End If

And here’s sample code to run that rule from e.g. a VB exe or addin:

Public Sub Test()
 
  ' m_app is a member variable of type Inventor.Application
  Dim arguments As NameValueMap = _
    m_app.TransientObjects.CreateNameValueMap()
 
  arguments.Add("FilePath", "C:\Test3\Data.xlsx")
  arguments.Add("Sheet", "Sheet1")
  arguments.Add("Dia", 0.2)
  arguments.Add("Length", 4.5)
 
  Dim document As Document = m_app.ActiveDocument
  Dim externalRulePath = "C:\Test3\iLogicExcelTest.iLogicVb"

  ' m_iLogicAuto is a late-bound variable of type Object. 
  ' It implements the IiLogicAutomation interface 
  ' (defined in Autodesk.iLogic.Interfaces.dll). 
  ' See below GetiLogicAutomation() function to get 
  ' it from the application
  m_iLogicAuto.RunExternalRuleWithArguments( _
    document, externalRulePath, arguments)
 
  Dim outputs As NameValueMap = Nothing
  Try
    outputs = arguments.Value("Outputs")
    If (outputs IsNot Nothing) Then
      MessageBox.Show( _
        String.Format("PartNumber = {0}", _
        outputs.Value("PartNumber")), "ExcelTest")
    End If
  Catch ex As Exception
    MessageBox.Show(String.Format("Exception in Test: {0}", ex), _
      "ExcelTest")
  End Try
End Sub

Function GetiLogicAutomation(ByVal app As Inventor.Application) _
As Object
 
  Dim addIn As Inventor.ApplicationAddIn = Nothing
  Try
    addIn = app.ApplicationAddIns.ItemById( _
      "{3bdd8d79-2179-4b11-8a5a-257b1c0263ac}")
  Catch ex As Exception
    Return Nothing
  End Try
 
  Return addIn.Automation
End Function