Manufacturing DevBlog

UnInclude WorkSurfaces in a DrawingView

By Adam Nagy

Let's say we have a drawing view showing an assembly with this structure:

If some of the work surfaces are visible and some are not then the context menu will show this - a filled rectangle next to Include All Surfaces:

If we want to achieve the same programmatically as clicking that menu item, i.e. either making all work surfaces visible or invisible then this is how we can do it. 

The DrawingView object has methods SetIncludeStatus and SetVisibility methods to control what is visible in the given view. As the API Help File says these methods require that the objects are in context of the document being shown by the view:

Input object to set the include status of. 
Valid objects are 2d and 3d sketches, work features, 
surface features, and proxies for all of these. 
The object needs to be supplied in the context 
of the document referenced by the drawing view. 
For instance, to set the include status of a 3D sketch 
within a part instanced in an assembly 
(and the drawing view is of the assembly), 
the input should be a Sketch3DProxy object created 
in context of the assembly. An error will occur 
if no corresponding object exists in the drawing view.

You can find more info on contexts here:
http://adndevblog.typepad.com/manufacturing/2013/07/occurrences-contexts-definitions-proxies.html 

Some objects can only be accessed through the document's definition so that you have to create the proxy for them using ComponentOccurrence.CreateObjectProxy.

In this VBA example we'll go through all the occurrences and suboccurrences in the assembly document that the selected DrawingView is referencing, create a proxy for each WorkSurface and then set the include status for them, so that they will not be visible:

Sub CollectAllSurfaces( _
occs As ComponentOccurrences, coll As ObjectCollection)
  Dim occ As ComponentOccurrence
  For Each occ In occs
    If occ.SubOccurrences.count > 0 Then
      Call CollectAllSurfaces(occ.SubOccurrences, coll)
    End If
    
    If TypeOf occ.Definition Is PartComponentDefinition Then
      Dim pcd As PartComponentDefinition
      Set pcd = occ.Definition
      
      Dim ws As WorkSurface
      For Each ws In pcd.WorkSurfaces
        Dim wsp As WorkSurfaceProxy
        Call occ.CreateGeometryProxy(ws, wsp)
        Call coll.Add(wsp)
      Next
    End If
  Next
End Sub

Sub IncludeAllSurfacesNot()
  Dim dv As DrawingView
  Set dv = ThisApplication.ActiveDocument.SelectSet(1)
  
  Dim doc As AssemblyDocument
  Set doc = dv.ReferencedDocumentDescriptor.ReferencedDocument
  
  Dim tro As TransientObjects
  Set tro = ThisApplication.TransientObjects
  
  Dim coll As ObjectCollection
  Set coll = tro.CreateObjectCollection
  
  Call CollectAllSurfaces(doc.ComponentDefinition.Occurrences, coll)
  
  Dim wsp As WorkSurfaceProxy
  For Each wsp In coll
    Call dv.SetIncludeStatus(wsp, False)
  Next
End Sub

After running the code you'll see that all work surfaces became invisible:

 

Do you want to load this add-in?

By Adam Nagy

Inventor 2016 introduced a new security measure, which makes the Add-In Manager pop up a dialog when it encounters an Add-In for the first time:

 

Here if you click Allow then from then onwards the Add-In will automatically be loaded without the message box appearing again. If you click Block then the Add-In will never be loaded until you un-tick the Block option for it in the Add-In Manager dialog:

The Add-In security message box also contains Signature, Publisher and Detail sections that are populated from the digital signature of the Add-In. Unlike in case of AutoCAD, inside Inventor the warning dialog will pop up even if the Add-In is signed, but at least the digital signature information will be there, which makes the Add-In look more professional.

Autodesk does not provide its own digital signature/certificate for 3rd party developers, because that would make the Add-Ins look as if they were developed by Autodesk, which is not correct. Developers who wish to sign their Add-Ins need to purchase their own signature/certificate. They can get a single one and used it for all their products.

A colleague looked into certificate providers and here is what he found. We are not endorsing any of them, it's just a list based on the search results and you can surely find other ones as well. You need to decide which one is best for you:

Symantec
                1 year - $499
                2 years - $873 ($436.50/year)
                3 years - $1248 ($416/year)

GoDaddy
                1 year - $200
                2 years - $360 ($180/year)
                3 years - $510 ($170/year)

Digicert
                1 year - $223
                2 years - $396 ($198/year)
                3 years - $534 ($178/year)               

Instant SSL
                1 year - $179
                2 years - $340 ($170/year)
                3 years - $501 ($167/year)               

kSoftware
                1 year - $95
                2 years - $175 ($87.50/year)
                3 years - $245 ($81.66/year)
                5 years - $365 ($73/year)

iLogic.ExternalRuleFinder.GetParsedRuleNames missing

By Adam Nagy

iLogic.ExternalRuleFinder.GetParsedRuleNames was never documented and has been moved to a different class and became internal (no longer public) in 2016. 

Instead of using that function you can just do a scan of the iLogic external rule directories for rule files. The directory names are available in the iLogic API property IiLogicAutomation.FileOptions.ExternalRuleDirectories. Here’s a sample rule to list the directory names:

For Each directoryPath As String In
iLogicVb.Automation.FileOptions.ExternalRuleDirectories
  Trace.WriteLine("Directory name: " + directoryPath)
Next

In Inventor 2016 all the rules in these directories (and subdirectories, if any) are shown on the External Rules tab in the iLogic browser - in previous versions, only manually selected rules were shown.

Version of DevExpress dlls Inventor uses

By Xiaodong Liang

A developer hit a random crash with DevExpress component. The comment from DevExpress is the version might be conflict to what Inventor uses.

So we got a list of version of DevExpress of the latest version of Inventor:

Inventor version	DevExpress version
2015 & 2016	13.1.5
2014	12.1
2013	11.1

Jump Start your Fusion Development

Autodesk recently finished the first ever Cloud Accelerator where several companies were selected to come into the San Francisco office to work on their applications, which use the Autodesk cloud technology in some way.  They were able to work directly with the ADN and clout teams to accelerate the development of their applications. 

The first event was so successful, there has been another one scheduled for June 1-12.  With the addition of add-ins, it’s now possible to create applications for Fusion and this is a great opportunity for you to quickly get up to speed.  The deadline for applications is April 19th, so it’s quickly approaching.  It would be great to work with some Fusion developers during the event.

You can learn more at the Autodesk Cloud Accelerator site.

Here are some highlights from the last event.

And a link to several more videos.

-Brian

Add Note for Centerline of Work Feature in Drawing

By Xiaodong Liang

This is a question from a forum post. The customer has the model with some work planes.

When he inserts the model to a drawing, the [Display Options] allows to include work feature or not.

Finally, the work planes can be incldued and displayed in the sheet.

However, these lines are not noted. The customer wants to pull the names of each plane from the part and add them along with these lines.

It looks API has not a direct way to enable the name, but such lines are CenterLine object in Sheet. Centerline.ModelWorkFeature tells from which object the center line comes from. So we can get the name from ModelWorkFeature. While the challenge is which object we can create as a note. I think the easiest way would be a GeneralNote(DrawingNote). You can simply set its position and formatted text. This is a code demo of VBA.

Sub addDrawingNoteForWorkPlane()
 
        Dim oDoc As DrawingDocument
        Set oDoc = ThisApplication.ActiveDocument
 
        Dim oSheet As Sheet
        Set oSheet = oDoc.ActiveSheet
 
        Dim oCenterLine As Centerline
 
        For Each oCenterLine In oSheet.Centerlines
            If Not oCenterLine.ModelWorkFeature Is Nothing Then
 
                'select start point or end point as the position for the drawing note
 
                Dim oPos As Point2d
 
                Dim oStPos As Point2d
                Set oStPos = oCenterLine.StartPoint
 
                Dim oEndPos As Point2d
                Set oEndPos = oCenterLine.EndPoint
 
                If Math.Abs(oStPos.X - oEndPos.X) > Math.Abs(oStPos.Y - oEndPos.Y) Then
                    ' put drawing note at the right of the center line
 
                    If oStPos.X > oEndPos.X Then
                        ' set position of drawing note at start point
                       Set oPos = oStPos
                    Else
                        ' set position of drawing note at end point
                       Set oPos = oEndPos
                    End If
                Else
                    ' put drawing note at the bottom of the center line
                    If oStPos.Y > oEndPos.Y Then
                        ' set position of drawing note at end point
                       Set oPos = oEndPos
                    Else
                        ' set position of drawing note at start point
                       Set oPos = oStPos
                    End If
                End If
 
                Dim oWP_Name As String
                oWP_Name = oCenterLine.ModelWorkFeature.Name
 
                Dim sNote As String
                sNote = "<StyleOverride Font='Arial' FontSize='0.2' Bold='True'>" & _
                        oWP_Name & _
                        "</StyleOverride>"
 
                Dim oGeneralNote As GeneralNote
                Set oGeneralNote = oSheet.DrawingNotes.GeneralNotes.AddFitted(oPos, sNote)
 
            End If
        Next
 
    End Sub

The disadvantage of a GeneralNote is it is not attached to the center line. So when the center line is change (e.g. the drawing view is moved), the notes cannot be moved accordingly. So we have to delegate OnChange event and move the GeneralNote.

Then I turned to LeaderNote which can be attached to a point. You can have the simplest LeaderNote that has not line/arrow. e.g.

The relevant code is as below. You will need to calculate the best position for the note according to your workflow.

Sub addLeaderForWorkPlane()

       Dim oDoc As DrawingDocument

       Set oDoc = ThisApplication.ActiveDocument

       Dim oTG As TransientGeometry

       Set oTG = ThisApplication.TransientGeometry

       Dim oActiveSheet As Sheet

       Set oActiveSheet = oDoc.ActiveSheet

       Dim oCenterLine As Centerline

       For Each oCenterLine In oActiveSheet.Centerlines

           If Not oCenterLine.ModelWorkFeature Is Nothing Then

               'select start point or end point as the position for the drawing note

               Dim oPos As Point2d

               Dim oStPos As Point2d

               Set oStPos = oCenterLine.StartPoint

               Dim oEndPos As Point2d

               Set oEndPos = oCenterLine.EndPoint

               If Math.Abs(oStPos.X - oEndPos.X) > Math.Abs(oStPos.Y - oEndPos.Y) Then

                   ' put drawing note at the right of the center line

                   If oStPos.X > oEndPos.X Then

                       ' set position of drawing note at start point

                       Set oPos = oStPos

                   Else

                       ' set position of drawing note at end point

                      Set oPos = oEndPos

                   End If

               Else

                   ' put drawing note at the bottom of the center line

                   If oStPos.Y > oEndPos.Y Then

                       ' set position of drawing note at end point

                       Set oPos = oEndPos

                   Else

                       ' set position of drawing note at start point

                      Set oPos = oStPos

                   End If

               End If

               Dim oWP_Name As String

               oWP_Name = oCenterLine.ModelWorkFeature.Name

               Dim oLeaderPoints As ObjectCollection

               Set oLeaderPoints = ThisApplication.TransientObjects.CreateObjectCollection()

               Call oLeaderPoints.Add(oTG.CreatePoint2d(oPos.X, oPos.Y))

               ' Create geometry intent from position

               Dim oGeometryIntent As GeometryIntent

               Set oGeometryIntent = oActiveSheet.CreateGeometryIntent(oCenterLine, oPos)

               Call oLeaderPoints.Add(oGeometryIntent)

               ' add leader note

               Dim oLeaderNote As LeaderNote

               Call oActiveSheet.DrawingNotes.LeaderNotes.Add(oLeaderPoints, oWP_Name)

           End If

       Next

   End Sub

Drag & Drop file from external application

By Adam Nagy

You may want to provide a user control with a list of components that you could drag & drop onto Inventor. In case of .NET it's quite easy to set up. You just have to handle the MouseDown event of the control from which you want to enable the Drag & Drop, and then set up the data that could be dragged onto another applications.

In this case we have a simple .NET Form with a button on it named myButton with text "Drag Me!". If the user starts dragging this button then it will drag a file onto other applications like Inventor, which accept such a thing.

Here is the main part of the C# source code:

using System;
using System.Collections.Specialized;
using System.Windows.Forms;

namespace DragAndDropTest
{
  public partial class MyForm : Form
  {
    public MyForm()
    {
      InitializeComponent();
    }

    private void myButton_MouseDown(
      object sender, MouseEventArgs e)
    {
      DataObject dragInfo = new DataObject();
      StringCollection coll = new StringCollection();
      coll.Add(@"c:\temp\test.ipt");
      dragInfo.SetFileDropList(coll);

      // "Copy" will let us open the ipt
      // "Link" will let us insert the ipt in an assembly
      myButton.DoDragDrop(
        dragInfo,
        DragDropEffects.Copy | DragDropEffects.Link);
    }
  }
}

Here it is in action:

 

Set context menu for OrdinateDimensionSet member

By Adam Nagy

When you right-click on an OrdinateDimensionSet then the context menu pops up offering among other things the Edit menu item. This will then edit the specific member that was closest to the cursor when the ordinate dimension set got pre-highlighted:

Which member was closest when the selection took place does not matter, because if we select the dimension set by clicking the first member, but then right-click on the second member, still the second member will be edited.

Based on this we could create our own context menu item which then will edit the member that we right-clicked on. We just need to listen to two events of the UserInputEvents object:
- OnPreSelect: here we'll find the member closest to the cursor and store the reference to that so that we can modify it later
- OnLinearMarkingMenu: here we'll add our own context menu item that can be used to edit the OrdinateDimensionSet member 

The below VBA code works for both OrdinateDimension and OrdinateDimensionSet member.

We need a class that can handle events - I named it clsLinearMarkingMenu:

Dim WithEvents uiEvents As UserInputEvents
Dim WithEvents btnDef As ButtonDefinition

' Selected / pre-highlighted dimension
Dim selDim As OrdinateDimension

Private Sub btnDef_OnExecute(ByVal Context As NameValueMap)
  ' We're just adding a plus sign to the selected
  ' dimension's text
  selDim.Text.FormattedText = selDim.Text.FormattedText + "+"
End Sub

Private Sub CreateCommand(dispText As String)
  Dim cmdMgr As CommandManager
  Set cmdMgr = ThisApplication.CommandManager

  ' Make sure our command is deleted
  ' so that we can create it new
  On Error Resume Next
  Set btnDef = cmdMgr.ControlDefinitions("DimTextPlus")
  If Not btnDef Is Nothing Then btnDef.Delete
  On Error GoTo 0
    
  Set btnDef = cmdMgr.ControlDefinitions.AddButtonDefinition( _
    dispText, "DimTextPlus", kNonShapeEditCmdType)
End Sub

Private Sub Class_Initialize()
  Dim cmdMgr As CommandManager
  Set cmdMgr = ThisApplication.CommandManager
  
  Set uiEvents = cmdMgr.UserInputEvents
End Sub

Private Sub uiEvents_OnLinearMarkingMenu( _
ByVal SelectedEntities As ObjectsEnumerator, _
ByVal SelectionDevice As SelectionDeviceEnum, _
ByVal LinearMenu As CommandControls, _
ByVal AdditionalInfo As NameValueMap)
  ' We only add our context menu item if the
  ' selected entity was an ordinate dimension
  If Not selDim Is Nothing Then
    ' We can also set the text of the menu
    ' item based on the selected dimension
    ' That's what our CreateCommand does
    Call CreateCommand(selDim.Text.Text)
    
    Call LinearMenu.AddButton(btnDef)
  End If
End Sub

Function GetClosestDimensionInSet( _
ByVal ordDimSet As OrdinateDimensionSet, _
ByVal pt As Point2d) As OrdinateDimension
  Dim tr As TransientGeometry
  Set tr = ThisApplication.TransientGeometry

  Dim ordDim As OrdinateDimension
  Dim min As Double
  min = 1000000
  
  For Each ordDim In ordDimSet.Members
    Dim poly As Polyline2d
    Set poly = ordDim.DimensionLine

    Dim i As Integer
    For i = 1 To poly.PointCount - 1
      Dim line As LineSegment2d
      Set line = tr.CreateLineSegment2d( _
        poly.PointAtIndex(i), poly.PointAtIndex(i + 1))

      Dim d As Double
      d = line.DistanceTo(pt)
      If d < min Then
        min = d
        Set GetClosestDimensionInSet = ordDim
      End If
    Next
  Next
End Function

Private Sub uiEvents_OnPreSelect( _
PreSelectEntity As Object, _
DoHighlight As Boolean, _
MorePreSelectEntities As ObjectCollection, _
ByVal SelectionDevice As SelectionDeviceEnum, _
ByVal ModelPosition As Point, _
ByVal ViewPosition As Point2d, _
ByVal View As View)
  ' Initialize our reference
  Set selDim = Nothing
  
  If TypeOf PreSelectEntity Is OrdinateDimension Then
    If PreSelectEntity.OrdinateDimensionSet Is Nothing Then
      ' It's not a dimension set, but just a single dimension
      Set selDim = PreSelectEntity
    Else
      Set selDim = GetClosestDimensionInSet( _
        PreSelectEntity.OrdinateDimensionSet, _
        ViewPosition)
    End If

    Debug.Print selDim.Text.Text
  Else
    Debug.Print TypeName(PreSelectEntity)
  End If
End Sub

Then we can instantiate this class from a module:

Dim lmm As clsLinearMarkingMenu

Sub TestLinearMarkingMenu()
  Set lmm = New clsLinearMarkingMenu
End Sub

Here it is in action:

 

Coming soon - Autodesk Cloud Accelerator v2

By Adam Nagy

Our first ever Autodesk Cloud Accelerator program was a real success ... so we decided to do it again :)

Here are the details: http://adndevblog.typepad.com/cloud_and_mobile/2015/03/coming-soon-autodesk-cloud-accelerator-v2.html

The deadline for proposals will be April 19th 2015.

Fusion 360 API: Load 3rd Library in JavaScript

By Xiaodong Liang

Fusion 360 encapsulates JavaScript and Python API that allow developers to extend the abilities of Fusion. The API manual introduces how to write and debug the script.

As a developer of JavaScript, you would be wondering where the source script is and whether it could load the 3rd library.

In [Script and Add-Ins] dialog, click the script, Details>>Full Path tells where the script is.

Generally, the built-in sample scripts reside in

C:\Users\kh\AppData\Roaming\Autodesk\Autodesk Fusion 360\API\JavaScript\Samples

While the custom scripts locate in

C:\Users\kh\AppData\Roaming\Autodesk\Autodesk Fusion 360\MyJS\Scripts\

you can set the Folder Location of your script when creating it:

In the older version of Fusion, you can find each ‘script’ is actually consist of two companion files:
- *.HTML file
- *.js file
The HTML is the skeleton like what we develop a web program. The *.js file is what you created in Fusion. e.g. the below is a snapshot of a script named Bottle.

This is the HTML file of this sample:

Its HTML loads the necessary libraries of Fusion (in the relative path of ../src/adsk/Fusion, and Bottle.js file of this sample. When we run the sample within Fusion, it will turn to the HTML to load the libraries.

In the latest version, Fusion provides the mechanism that a *.manifest file defines the profile of the sample such as the libraries. So 3 companion files now:

- *.HTML file
- *.js file
- *.manifest  file

The *.manifest file configures in a format of Json. The libraries to be loaded are defined at the node of autodeskLibraries.

{
    "autodeskProduct":    "Fusion360",
    "type":    "script",
    "author":    "Autodesk",
    "description": 
     {
        "":    "This is a test"
     },
    "supportedOS":    "windows|mac",
    "autodeskLibraries":   
     ["application",
      "dashboard",
     "geometry",
     "materials",
      "userInterface",
      "utilities",
      "bRep",
      "components",
      "construction",
      "features",
      "fusion",
      "meshBody", 
       "meshData", 
        "sketch",
         "tSpline"]
}

now, the *.HTML is much simpler. We just need to load the *.js file only.

Well, let us come back to the question of this blog title: how to load the 3rd library. The answer is very straightforward. It is like what you did in a common web programming, linking it through a relative path or the path on internet.

However currently the libraries for web UI have not been supported in Fusion 360. In another word, we cannot create the web page. While we can still link to some libraries that are algorism related.

I played with a math library Numeric. It allows you to get the result of  linear algebra, complex numbers, splines, ODE solver and so on. I downloaded the mini library numeric-1.2.6.min.js to the same folder of my sample NewScript1. NewScript1.html loads the library. This sample gets the spline values from Numeric and draws a spline in one sketch.

 

[NewScript1.html] [<!DOCTYPEhtml> <html>     <scripttype="text/javascript"src="../adsk/core/application.js"></script>     <scripttype="text/javascript"src="../adsk/core/geometry.js"></script>     <scripttype="text/javascript"src="../adsk/core/userInterface.js"></script>     <scripttype="text/javascript"src="../adsk/utilities.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/bRep.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/components.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/construction.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/features.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/fusion.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/meshBody.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/meshData.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/sketch.js"></script>     <scripttype="text/javascript"src="../adsk/Fusion/tSpline.js"></script>      <scripttype="text/javascript"src="numeric-1.2.6.min.js"></script>       <scripttype="text/javascript"src="NewScript1.js"></script>  <body> </body>

[NewScript1.js] //Author- //Description- /*globals adsk*/ (function () {       "use strict";       if (adsk.debug === true) {         /*jslint debug: true*/         debugger;         /*jslint debug: false*/     }       var ui;     try {         var app = adsk.core.Application.get();         ui = app.userInterface;           // Get the active design.         var product = app.activeProduct;         var design = adsk.fusion.Design(product);         if (!design) {             ui.messageBox('No active Fusion design');             adsk.terminate();             return;         }           // Get the root component.         var rootComp = design.rootComponent;           // Create a new sketch on the xy plane.         var sketch =             rootComp.sketches.add                        (rootComp.xYConstructionPlane);           // Create an object collection for the points.         var points =              adsk.core.ObjectCollection.create();           // This is the spline demo.         // We start by taking 30 evenly spaced points in the interval [0,3]         var x = numeric.linspace(0, 3, 30);           // We define a function f(x) = sin(x*x*x)         var f = function (x) {                      return numeric.sin(                                numeric.mul(x, x, x));                              }           // We sample the function at the 30 points we chose.         var y = f(x);           // Now we create the spline with the given control points.         var s = numeric.spline(x, y);           var x0 = numeric.linspace(0, 3, 100);           for (var xx in x0) {             var x_cor = Number(xx);             var y_cor = Number(s.at(Number(x0[xx])));             var z_cor = 0;             points.add(adsk.core.Point3D.create(                        x_cor,                        y_cor,                        z_cor));         }         // Create the spline.         sketch.sketchCurves.                   sketchFittedSplines.add(points);       }     catch (e) {         if (ui) {             ui.messageBox('Failed : ' +                          (e.description ?                           e.description : e));         }     }       adsk.terminate(); }());