Manufacturing DevBlog

Corrections/Clarification to Webinar

I recently posted about the Fusion API Webinar and want to correct and clarify a few things I said during the presentation and in the questions after.

1. When showing the slides comparing the JavaScript and Python code I mentioned that JavaScript is pickier about types and sometimes requires type casting.  This is not true.  There was an issue in a very early version of the API where it did require type casting but that was a Fusion API issue and not a JavaScript issue and has long since been addressed.  I’ve updated the PowerPoint slides to remove the casting line.
2. It was asked if you could begin a debug session into a running JavaScript add-in and replied that I didn’t believe it was possible.  I’ve since learned about a capability that I didn’t know about that does allow you to debug into a running JavaScript add-in or script.  From the Scripts and Add-Ins dialog you can see which scripts and add-ins are currently running by looking for the running symbol next to the name as I’ve highlighted below.  When you select a running JavaScript program, the Debug button will be enabled, as shown below.  This will open a window and allow you to begin debugging the running script.
   
   
   
3. I also mentioned TkInter as a way to create custom dialogs when using Python but that there are currently problems when using it on a Mac.  This is true but I want to clarify that it’s not a Fusion 360 API issue in this case but is a general problem with TkInter (Tcl/Tk specifically) on Mac.  We’ve attempted to find a combination of libraries that works but so far have been unsuccessful.

-Brian

Entity specific context menu

By Adam Nagy

You can add items to the context menu inside the OnLinearMarkingMenu event handler. This also provides the list of currently selected entities. You can easily check if they are of a given entity type or not - e.g. if they are Ordinate Dimensions - and based on that decide if we add our own control definition or not.

This VBA sample shows how to do it. When the class (I named it clsLinearMarkingMenu) is initialized the Class_Initialize function is called and there we check if our control definition has already been registered. If not, then we create it and register it. Inside the OnExecute event handler of our control definition we can do the operation we want when our control (context menu item in this case) is clicked. In this case we'll add a plus sign to the dimension text.

Class clsLinearMarkingMenu:

Dim WithEvents uie As UserInputEvents
Dim WithEvents bd1 As ButtonDefinition

Private Sub bd1_OnExecute(ByVal Context As NameValueMap)
  Dim ss As SelectSet
  Set ss = ThisApplication.ActiveDocument.SelectSet

  Dim ordDim As OrdinateDimension
  For Each ordDim In ss
    ' Change the text of the selected ordinate dimensions
    ordDim.Text.FormattedText = _
      ordDim.Text.FormattedText + "+"
  Next
End Sub

Private Sub Class_Initialize()
  Dim cm As CommandManager
  Set cm = ThisApplication.CommandManager
  
  Set uie = cm.UserInputEvents
      
  ' Make sure our control is available
  On Error Resume Next
  Set bd1 = cm.ControlDefinitions("DimTextPlus")
  If bd1 Is Nothing Then
    Set bd1 = cm.ControlDefinitions.AddButtonDefinition( _
      "Dim Text +", "DimTextPlus", kNonShapeEditCmdType)
  End If
End Sub

Function AreAllOrdinate(entities As ObjectsEnumerator) As Boolean
  Dim entity As Object
  For Each entity In entities
    If Not TypeOf entity Is OrdinateDimension Then
      AreAllOrdinate = False
      Exit Function
    End If
  Next
  AreAllOrdinate = True
End Function

Private Sub uie_OnLinearMarkingMenu( _
ByVal SelectedEntities As ObjectsEnumerator, _
ByVal SelectionDevice As SelectionDeviceEnum, _
ByVal LinearMenu As CommandControls, _
ByVal AdditionalInfo As NameValueMap)
  ' We only add our context menu item if the
  ' selected entities are all ordinate dimensions
  If AreAllOrdinate(SelectedEntities) Then
    Call LinearMenu.AddButton(bd1)
  End If
End Sub

Then we can instantiate our class in any of the Modules:

Dim lmm As clsLinearMarkingMenu

Sub TestLinearMarkingMenu()
  Set lmm = New clsLinearMarkingMenu
End Sub

Now when we right-click on an ordinate dimension our menu item will show up:

  

Entitlement API in Inventor

By Adam Nagy

Important: Entitlement API changes in Inventor 2020

When you write AddIn's for the exchange store then you'll probably want to check if the user logged into the Autodesk product actually bought your AddIn or just copied it from somewhere. In the 2016 releases you will be able to test this with the help of the functionality provided by the AdWebServices.dll.

The API is in C++ and so can be accessed from both C++ AddIn's and other ones using Platform Invoke (P/Invoke) - this is how I'm using it from the sample .NET AddIn too.

The main function you'll need is the GetUserId which will provide the currently logged in user's Internal Autodesk ID. Then using the Exchange Store API you can find out if the user with the given Internal Autodesk ID has actually bought your application.

You can find the sample project here: https://github.com/ADN-DevTech/EntitlementAPI_Inventor 

Because of new security measures in Inventor 2016, when loading the sample project for the first time you'll get a dialog like this, where you'll need to Allow the AddIn to load:

If there is a user currently logged into Inventor, then you'll get this message:

If no user is logged in or something goes wrong then you'll get this message:

 

Fusion 360’s API Webinar

This morning, here in slightly rainy Oregon, I presented a webinar about the Fusion 360 API.  For those of you that missed it, the entire presentation is now available on YouTube and you can also download the PowerPoint slides that I used for the presentation. 

 

You can learn more about the Fusion 360 product and also install it to get a better understanding of how it works and what it can do. I welcome any comments about the API at the Fusion 360 API and Scripts forum.

There are also corrections and additional information available about this webinar.

-Brian

Create Chamfer Feature in Assembly Document

By Xiaodong Liang

In the last post, we introduced how to create chamfer feature in part document. In an assembly document, we have two choices, either create the feature in assembly context, or create the real feature in part context. Actually, this applies to other types of feature which are supported in assembly document.

For choice 1, we need to input the proxy geometries (say EdgeProxy, FaceProxy) to the methods of chamfer feature. e.g. the code below assumes a face is selected in the assembly document. Since it is in the context of assembly, it is FaceProxy already. The same to the edges of the FaceProxy, they are EdgeProxy.

   Sub createChamferInAssemblyContext_selectedObject()

 

        Dim oDoc As AssemblyDocument

        oDoc = ThisApplication.ActiveDocument

 

        Dim oDef As AssemblyComponentDefinition

        oDef = oDoc.ComponentDefinition

 

        'selected face. in assembly this is a proxy face

        Dim oSelectedFace As FaceProxy

        oSelectedFace = oDoc.SelectSet(1)

 

        Dim oEdgeCol As EdgeCollection

        oEdgeCol = ThisApplication.TransientObjects.CreateEdgeCollection()

 

        'method 1: creates a new ChamferFeature defined by a specified distance

        'the edge from the FaceProxy is proxy edge already.

        oEdgeCol.Add oSelectedFace.Edges(1)

        oEdgeCol.Add oSelectedFace.Edges(2)

 

        Call oDef.Features.ChamferFeatures.AddUsingDistance(oEdgeCol, "0.1 in")

 

        'method 2: creates a new ChamferFeature that is defined by a distance and at a specified angle to an input face

        'the edge from the FaceProxy is proxy edge already.

        oEdgeCol.Clear()

        oEdgeCol.Add oSelectedFace.Edges(3)

        Call oDef.Features.ChamferFeatures.AddUsingDistanceAndAngle(oEdgeCol, oSelectedFace, "0.2 in", 0.5233)

 

        'creates a new ChamferFeature that is defined by two distances

        'the edge from the FaceProxy is proxy edge already.

        oEdgeCol.Clear()

        oEdgeCol.Add oSelectedFace.Edges(4)

        Call oDef.Features.ChamferFeatures.AddUsingTwoDistances(oEdgeCol, oSelectedFace, "0.1 in", "0.2 in")

 

    End Sub

 

If we get the objects of parts firstly, we can convert them to proxy objects by Occurrence.CreateGeometryProxy. Next, similarly to the above, input the proxy geometries to the methods of chamfer feature.

    Sub createChamferInAssemblyContext_objectFromPart()

 

        Dim oDoc As AssemblyDocument

        oDoc = ThisApplication.ActiveDocument

 

        Dim oAssDef As AssemblyComponentDefinition

        oAssDef = oDoc.ComponentDefinition

 

        Dim oOccurrence1 As ComponentOccurrence

        oOccurrence1 = oAssDef.Occurrences(1)

 

        Dim oPart1Def As PartComponentDefinition

        oPart1Def = oOccurrence1.Definition

 

        'get face and edge in part context

        Dim oFaceInPart As Face

        oFaceInPart = oPart1Def.SurfaceBodies(1).Faces(1)

 

        Dim oEdge1 As Edge

        oEdge1 = oFaceInPart.Edges(1)

 

        Dim oEdge2 As Edge

        oEdge2 = oFaceInPart.Edges(2)

 

        Dim oEdge3 As Edge

        oEdge3 = oFaceInPart.Edges(3)

 

        Dim oEdge4 As Edge

        oEdge4 = oFaceInPart.Edges(4)

 

        'create the proxy geometries

        Dim oFaceProxy As FaceProxy

        Call oOccurrence1.CreateGeometryProxy(oFaceInPart, oFaceProxy)

 

        Dim oEdge1Proxy As EdgeProxy

        Call oOccurrence1.CreateGeometryProxy(oEdge1, oEdge1Proxy)

 

        Dim oEdge2Proxy As EdgeProxy

        Call oOccurrence1.CreateGeometryProxy(oEdge2, oEdge2Proxy)

 

        Dim oEdge3Proxy As EdgeProxy

        Call oOccurrence1.CreateGeometryProxy(oEdge3, oEdge3Proxy)

 

        Dim oEdge4Proxy As EdgeProxy

        Call oOccurrence1.CreateGeometryProxy(oEdge4, oEdge4Proxy)

 

 

        Dim oEdgeCol As EdgeCollection

        oEdgeCol = ThisApplication.TransientObjects.CreateEdgeCollection()

 

        'method 1: creates a new ChamferFeature defined by a specified distance

        Call oEdgeCol.Add(oEdge1Proxy)

        Call oEdgeCol.Add(oEdge2Proxy)

 

        Call oAssDef.Features.ChamferFeatures.AddUsingDistance(oEdgeCol, "0.1 in")

 

        'method 2: creates a new ChamferFeature that is defined by a distance and at a specified angle to an input face

 

        oEdgeCol.Clear()

        Call oEdgeCol.Add(oEdge3Proxy)

        Call oAssDef.Features.ChamferFeatures.AddUsingDistanceAndAngle(oEdgeCol, oFaceProxy, "0.2 in", 0.5233)

 

        'creates a new ChamferFeature that is defined by two distances

 

        oEdgeCol.Clear()

        Call oEdgeCol.Add(oEdge4Proxy)

        Call oAssDef.Features.ChamferFeatures.AddUsingTwoDistances(oEdgeCol, oFaceProxy, "0.1 in", "0.2 in")

 

    End Sub

For choice 2, we can manipulate the part definition directly and save the part document. In this code, I found an issue: after the face/edge object in part is used by one chamfer method, they seem to be broken. I have to get the objects again.

Sub createChamferInPartContext()

 

        Dim oDoc As AssemblyDocument

        oDoc = ThisApplication.ActiveDocument

 

        Dim oAssDef As AssemblyComponentDefinition

        oAssDef = oDoc.ComponentDefinition

 

        Dim oOccurrence1 As ComponentOccurrence

        oOccurrence1 = oAssDef.Occurrences(1)

 

        Dim oPart1Def As PartComponentDefinition

        oPart1Def = oOccurrence1.Definition

 

        'get face and edge in part context

        Dim oFaceInPart As Face

        oFaceInPart = oPart1Def.SurfaceBodies(1).Faces(3)

 

        Dim oEdge1 As Edge

        oEdge1 = oFaceInPart.Edges(1)

 

        Dim oEdge2 As Edge

        oEdge2 = oFaceInPart.Edges(2)

 

        Dim oEdgeCol As EdgeCollection

        oEdgeCol = ThisApplication.TransientObjects.CreateEdgeCollection()

 

        'method 1: creates a new ChamferFeature defined by a specified distance

        Call oEdgeCol.Add(oEdge1)

        Call oEdgeCol.Add(oEdge2)

 

        Call oPart1Def.Features.ChamferFeatures.AddUsingDistance(oEdgeCol, "0.1 in")

 

        'method 2: creates a new ChamferFeature that is defined by a distance and at a specified angle to an input face

        ' after the face/edge object in part is used by one chamfer method, they seem to be broken.  have to get the objects again

        oEdgeCol.Clear()

        oFaceInPart = oPart1Def.SurfaceBodies(1).Faces(3)

        Dim oEdge3 As Edge

        oEdge3 = oFaceInPart.Edges(3)

 

        Call oEdgeCol.Add(oEdge3)

        Call oPart1Def.Features.ChamferFeatures.AddUsingDistanceAndAngle(oEdgeCol, oFaceInPart, "0.1 in", 0.5233)

 

        'creates a new ChamferFeature that is defined by two distances

        ' after the face/edge object in part is used by one chamfer method, they seem to be broken.  have to get the objects again

        oEdgeCol.Clear()

        oFaceInPart = oPart1Def.SurfaceBodies(1).Faces(3)

        Dim oEdge4 As Edge

        oEdge4 = oFaceInPart.Edges(4)

        Call oEdgeCol.Add(oEdge4)

        Call oPart1Def.Features.ChamferFeatures.AddUsingTwoDistances(oEdgeCol, oFaceInPart, "0.1 in", "0.2 in")

 

        Call oPart1Def.Document.Save()

 

    End Sub

 

Create Chamfer Feature in Part Document

By Xiaodong Liang

API provides the corresponding methods of UI to create chamfer feature.

ChamferFeatures.AddUsingDistance: creates a new ChamferFeature defined by a specified distance. The required arguments are the distance and the edges.

ChamferFeatures.AddUsingDistanceAndAngle: creates a new ChamferFeature that is defined by a distance and at a specified angle to an input face. The required arguments are referred face, edges, distance and angle.

ChamferFeatures.AddUsingTwoDistances: creates a new ChamferFeature that is defined by two distances. The required arguments are referred face, edges, distance one and distance two.

The code below demos the three methods. It assumes it is a part document. A face (with at least four edges) is selected.

    Sub createChamferInPart()

 

        Dim oDoc As PartDocument

        oDoc = ThisApplication.ActiveDocument

 

        Dim oDef As PartComponentDefinition

        oDef = oDoc.ComponentDefinition

 

        'selected face

        Dim oSelectedFace As Face

        oSelectedFace = oDoc.SelectSet(1)

 

        Dim oEdgeCol As EdgeCollection

        oEdgeCol = ThisApplication.TransientObjects.CreateEdgeCollection()

 

        'method 1: creates a new ChamferFeature defined by 0.1 inch.

        oEdgeCol.Add oSelectedFace.Edges(1)

        oEdgeCol.Add oSelectedFace.Edges(2)

 

        Call oDef.Features.ChamferFeatures.AddUsingDistance(oEdgeCol,

                                                                                                "0.1 in")

 

        'method 2: creates a new ChamferFeature that is defined 
         'by 0.2 inch and 30 degree
        oEdgeCol.Clear()

        oEdgeCol.Add oSelectedFace.Edges(3)

        Call oDef.Features.ChamferFeatures.AddUsingDistanceAndAngle

                       (oEdgeCol,

                        oSelectedFace,

                        "0.2 in",

                          0.5233)

 

        'method 3: creates a new ChamferFeature that is defined
         ' by 0.1 inch and 0.2 inch
        oEdgeCol.Clear()

        oEdgeCol.Add oSelectedFace.Edges(4)

        Call oDef.Features.ChamferFeatures.AddUsingTwoDistances(oEdgeCol,

                                                         oSelectedFace,

                                                         "0.1 in",

                                                         "0.2 in")

 

    End Sub

 

Get Face's parametric center

By Adam Nagy

Each face has an evaluator that can be used to check the min and max parametric values on it. If you calculate the middle of that, then you can get to the center of the Face. 

Here is a VBA sample that places a WorkPoint at the calculated center of the currently selected Face of the PartDocument.

Sub GetFaceCenter()
  Dim d As PartDocument
  Set d = ThisApplication.ActiveDocument

  Dim f As Face
  Set f = d.SelectSet(1)
  
  Dim s As SurfaceEvaluator
  Set s = f.Evaluator
  
  Dim b As Box2d
  Set b = s.ParamRangeRect
  
  ' Get center parameter
  Dim p(1) As Double
  p(0) = b.MinPoint.x + (b.MaxPoint.x - b.MinPoint.x) / 2
  p(1) = b.MinPoint.y + (b.MaxPoint.y - b.MinPoint.y) / 2
  
  ' Convert param to point
  Dim pt(2) As Double
  Call s.GetPointAtParam(p, pt)
  
  ' Add a workpoint
  Dim t As TransientGeometry
  Set t = ThisApplication.TransientGeometry
  
  Dim wpt As Point
  Set wpt = t.CreatePoint(pt(0), pt(1), pt(2))
  
  Call d.ComponentDefinition.WorkPoints.AddFixed(wpt)
End Sub

This is what I got for the various faces in one of the sample part documents:

 

Create Revision Table

By Xiaodong Liang

API provides the corresponding methods like UI to manipulate revision table.

• RevisionTables: the collection of revision table in a sheet. Its Add or Add2 method can create a new revision table.
• RevisionTable: the specific revision table. You can set its title, position and the styles of header of column or row, or even delete it.
• RevisionTableColumns: the collection of the columns. It supports to add a new column.

RevisionTableColumns.Add(
PropertyType As RevisionTablePropertyEnum,
[PropertySetId] As String,
[PropertyIdentifier] As Variant,
[TargetIndex] As Long,
[InsertBefore] As Boolean ) As RevisionTableColumn

RevisionTablePropertyEnum specifies the property type to associate with the column.

• RevisionTableColumn: the specific column. You can control the justification, title, even delete the column.
• RevisionTableRows: the collection of the rows. It supports to add a new row or custom row.
• RevisionTableRow: the specific row that can access the cell by RevisionTableRow.Item.
• RevisionTableCell : the specific cell of the row. it tells the value of the cell.

The following is a small code that demos how to create a new revision table and some kinds of columns.

Sub AddRevisionTable()

 

    Dim oDrawDoc As DrawingDocument

    oDrawDoc = ThisApplication.ActiveDocument

 

    Dim oRTBs As RevisionTables

    oRTBs = oDrawDoc.ActiveSheet.RevisionTables

 

    Dim oLocation As Point2d

    oLocation = ThisApplication.TransientGeometry.CreatePoint2d(10, 10)

 

    'add a new table

    Dim oRTB As RevisionTable

    oRTB = oRTBs.Add(oLocation)

 

    'add a new row

    Call oRTB.RevisionTableRows.Add()

 

    'add a new column of file property: Design Tracking Properties 
    '>> Part Number

    Call oRTB.RevisionTableColumns.Add(kRevisionTableFileProperty,
                                      "{32853F0F-3444-11D1-9E93-0060B03C1CA6}",
                                       5)

 

    'add a custom column. [PropertySetId] is ignored. 
    ' [PropertyIdentifier] should be specified

    Call oRTB.RevisionTableColumns.Add(kRevisionTableCustomProperty, "", "MyCustomProperty")

 

    'add a date property

    'one table can only have one Date column

    Dim oEachCol As RevisionTableColumn

    Dim hasDate As Boolean

    hasDate = False

    For Each oEachCol In oRTB.RevisionTableColumns

        If oEachCol.PropertyType = kRevisionTableDateProperty Then

            hasDate = True

            Exit For

        End If

    Next

 

    If hasDate = False Then

        Call oRTB.RevisionTableColumns.Add(kRevisionTableDateProperty)

    End If

 

End Sub

Get reference key of any object in C++

By Adam Nagy

Many different types of objects support the GetReferenceKey function that enables you to store information about a given object that will enable you to find them again using the ReferenceKeyManager of the Document. If you wanted to support all of them using early-binding, i.e. you explicitly declare all the object types you are supporting, that would be a lot of work. It's probably better to use late-binding in such a case - i.e. we do not care what type of object we are dealing with, we'll try to call GetReferenceKey on it. If it supports it then it will execute fine, otherwise the function will not be found on it. 

Just as it was discussed in this post, in .NET it's quite easy now to do late binding, but in C++ it's not, so we'll use the AutoWrap function that was introduced in the other blog post.

It could also be tricky to figure out what exact VARIANT type combination a function expects. The simplest might be to check the rxinventor.tli file that the compiler creates for us when our project is referencing the inventor type library. There you'll find all the functions, including this as well:

#pragma implementation_key(7455)
inline HRESULT Sheet::GetReferenceKey ( 
  SAFEARRAY * * ReferenceKey, long KeyContext ) {
    return _com_dispatch_raw_method(
      this, 0x7f000016, DISPATCH_METHOD, VT_EMPTY, NULL, 
      L"\x6011\x0003", ReferenceKey, KeyContext);
}

It shows what types the IDispatch::Invoke will require for the given function. ReferenceKey parameter's VARIANT type should be hexadecimal 0x6011. You can check the values e.g. from the "c:\Program Files (x86)\Windows Kits\8.0\Include\shared\wtypes.h" file. Some values there are in decimal and some in hexadecimal, so easiest is to convert all of them to hexadecimal:
- ReferenceKey's type is 0x6011. VT_BYREF = 0x4000, VT_ARRAY = 0x2000, VT_UI1 = 17 = 0x0011. If you add them together it's 0x6011
- KeyContext's type is 0x003, which is VT_I4.

If we already have an object e.g. a Face stored in pFace and the context index in lContext then this is how we could get the face's reference key. This code shows how you could do it with SAFEARRAY or CComSafeArray:

	// This is what the early-biding version would 
	// look like
	SAFEARRAY * refKeys = NULL;
	pFace->GetReferenceKey(&refKeys, lContext);

        // This is the late-binding version

        // Important to set myarray to NULL otherwise we could
        // get an error
	SAFEARRAY * myarray = NULL; 
	VARIANT param1;
	VariantInit(&param1);
	param1.vt = VT_ARRAY | VT_BYREF | VT_UI1;
	param1.pparray = &myarray;

	VARIANT param2;
	VariantInit(&param2);
	param2.vt = VT_I4;
	param2.lVal = lContext;

	VARIANT varResult;
	VariantInit(&varResult);
	Result = AutoWrap(
	  DISPATCH_METHOD, &varResult, pFace, 
          _T("GetReferenceKey"), 
	  2, param2, param1);

	// You can also wrap the result in CComSafeArray
        // Need to include "atlsafe.h"
	CComSafeArray<byte> saRefKey;
	Result = saRefKey.Attach(myarray);

It's useful to point out, because I missed it too before :), that the value you get back from CreateKeyContext and LoadContextFromArray is just an index of the context data, not the data itself. So if you want to make sure that you can find your BREP object in another session, then you'll have to follow all the steps mentioned in this post: get the context data using SaveContextToArray and then save it somewhere.

Get Attributes of source iFeature

By Adam Nagy

If you add an AttributeSet to the iFeature in the definition file (*.ide), that will not be transferred to the iFeature instance in the target part document. If the source file still exists then you can get the attributes from there like this:

Sub LookForAttributeSet()
  Dim pd As PartDocument
  Set pd = ThisApplication.ActiveDocument
  
  ' Select the iFeature instance in the Part document
  Dim oif As iFeature
  Set oif = pd.SelectSet(1)
  
  Dim pd2 As PartDocument
  Set pd2 = ThisApplication.Documents.Open( _
    oif.iFeatureTemplateDescriptor.LastKnownSourceFileName, _
    False)
    
  Dim oif2 As iFeature
  For Each oif2 In pd2.ComponentDefinition.Features.iFeatures
    If oif2.iFeatureTemplateDescriptor.InternalName = _
    oif.iFeatureTemplateDescriptor.InternalName Then
      MsgBox "First AttributeSet = " + oif2.AttributeSets(1).name
    End If
  Next
    
  pd2.Close
End Sub

I assume the best way though to pass parameters from the iFeature definition to the iFeature instance might be to add parameters to the iFeature table in the definition file:

Then with this code you can get your parameter:

Sub GetIfeatureParams()
  Dim pd As PartDocument
  Set pd = ThisApplication.ActiveDocument
  
  ' Select the iFeature instance in the Part document
  Dim oif As iFeature
  Set oif = pd.SelectSet(1)
  
  Dim c As iFeatureTableCell
  For Each c In oif.iFeatureDefinition.ActiveTableRow
    If c.Column.Heading = "MyParam" Then
      Call MsgBox(c.Value)
      Exit For
    End If
  Next
End Sub