Manufacturing DevBlog

[Open Containing Folder] throws exception

By Xiaodong Liang

Question
When I wanted to create the global form, clicked [Open Containing Folder] , an exception occurred. This happened with any document and all 5 of our stations. 

Solution

The global forms are stored in a subdirectory named iLogic\UI under the Design Data folder. e.g. for Inventor 2014, the default location is
C:\Users\Public\Documents\Autodesk\Inventor 2014\Design Data\iLogic\UI

The Design Data folder location can also be changed from the default within a particular project.

As a manual workaround, the user can open their Design Data folder in Windows Explorer and navigate to the subdirectory.

So, the user will need to find where the Design Data folder is? One possiblity is might be on an Office 365 drive.

Suppressing all chamfer or fillets with iLogic

By Xiaodong Liang

Question:
Is it possible to create a rule to suppress all filltes or chamfers in a part by an iLogic rule?

Solution:
The code below self explains how to suppress the specific features.

'get part document

doc = ThisDoc.Document

'get part definition

oDef = doc.ComponentDefinition

 

Dim oEachF As PartFeature

'iterare each feature

For Each oEachF In oDef.Features

    'if it is a chamfer or fillet

    If TypeOf oEachF Is ChamferFeature Or TypeOf oEachF Is FilletFeature Then

        'suppress it

        oEachF.Suppressed = True

    End If

Next

 

 

Change Balloon Property Display

By Adam Nagy

If you want to find out how to set an object through the API to achieve what you want, then the best thing is to do it through the UI and then investigate the object through the API in e.g. VBA: http://adndevblog.typepad.com/manufacturing/2013/10/discover-object-model.html

In this case I set the Balloon style's Property Display to ITEM, QTY then check in VBA where that information is stored:

I can see that the Properties of the Style object is set to "PartsListProperty='45572';PartsListProperty='45575'". I will now try to set it through the API. I first set the Property Display to something else, e.g. PART NUMBER, MASS throgh the UI and then run the below code:

Sub BalloonStyleCheck()
  Dim doc As DrawingDocument
  Set doc = ThisApplication.ActiveDocument
  
  Dim dsm As DrawingStylesManager
  Set dsm = doc.StylesManager
  
  Dim ods As ObjectDefaultsStyle
  Set ods = dsm.ActiveStandardStyle.ActiveObjectDefaults
  
  Dim bs As BalloonStyle
  Set bs = ods.BalloonStyle
  bs.Properties = _
    "PartsListProperty='45572';PartsListProperty='45575'"
End Sub

It seems to do the trick:

 

IncludeLibraryContents to include Content Center parts with AcquireFiles()

By Wayne Brill

Recently I had a case where the question was how to download content center parts. I was using code similar to the code in the example on this page and the content center parts were downloading fine from one Vault. In another Vault the content center parts were not getting downloaded. The difference was that in one Vault the Content Center parts were in a Folder and in the other Vault they were in a library. The solution was to include the library with the AcquireFilesSettings by making “IncludeLibraryContents=True”. Here is a snippet that shows this:

oSettings.OptionsRelationshipGathering. _

FileRelationshipSettings.IncludeLibraryContents = True

Configurator 360 embedded in your webpage

By Adam Nagy

Configurator 360 enables you to upload your design and then let others configure it through a web or mobile interface. Now you can even embed the web component in your own webpage. To test this feature you'll need at least a trial account, which you can get through here: http://www.autodesk.com/products/autodesk-configurator-360/free-trial

And here you can find the information on embedding the web component which also includes a link to a sample page: http://embedding.configurator360.autodesk.com/doc.html

One thing to note is that the URL of the webpage embedding the configurator needs to be exact - e.g. simply adding http://www.typepad.com is not enough. When I was writing this article and wanted to preview it, the temporary URL was different from the final URL of the blog post and so I needed to add that too:

I also needed to set Unrestricted viewing access for the model so that anyone looking at this webpage can access it:

Configurator 360 web component is using WebGL and so can be used on any WebGL enabled device. If the web control does not appear below then it is not supported on your system.

 

For some reason on typepad the content gets inserted twice (one of which is hidden) which means the script is inserted and run twice too, creating two controls one under the other. To avoid that I modified the code to store in the C360.isLoaded variable if the component is loaded already, and if not, only then run the usual code:

// Check if the API was loaded.
if (C360 && !C360.isLoaded) { 
  C360.isLoaded = true;

  // Initialize the viewer
  C360.initViewer({
    container: "myViewer",
    design: "520905552843171165/rlmjpx00pvv7",
    panes: { // Panes to show
      parameters: true
    },
    success: viewerLoaded, // Set success handler
    error: failedToLoad // Set error handler
  });
}

If you want to keep up-to-date with the latest features of Configurator 360 then keep an eye on this forum post: http://forums.autodesk.com/t5/Configurator-360-General/What-s-New-in-Configurator-360/m-p/4378949

Get occurrences whose name starts with a certain string

By Adam Nagy

If you need to get back occurrences with certain name patterns, then you just have to iterate through them and check their name. Depending on how many levels you want to check you could also use the AllLeafOccurrences property, like in this iLogic sample code that can be run inside an assembly document:

Sub Main
  Dim ocs = OccurrencesWhereNameStartsWith(
  	ThisDoc.Document.ComponentDefinition,
	"RC")

  Dim msg As String	
	
  Dim oc 	
  For Each oc In ocs
  	msg = msg + oc.Name + vbCrLf
  Next
  
  MsgBox(msg)
End Sub

Function OccurrencesWhereNameStartsWith( _
acd As AssemblyComponentDefinition, str As String) _
As ObjectCollection
  
  Dim oc As ObjectCollection
  oc = ThisApplication.TransientObjects.CreateObjectCollection()
  
  Dim co As ComponentOccurrence
  For Each co In acd.Occurrences.AllLeafOccurrences
    If co.Name.StartsWith(str) Then
      oc.Add (co)
    End If
  Next
  
  Return oc 
  
End Function

Vault 2014 – AcquireFilesSettings & AcquisitionStatus Skipped

By Wayne Brill

I had a discussion about AcquireFilesSettings used with AcquireFile() recently with a colleague in engineering. I thought it could be useful so I am posing it here:

 

This post on Doug Redmond’s blog uses the AcquireFilesSettings.AddFileToAcquire() method instead of the AddEntityToAcquire() method and then specifies the acquisition option for each individual file to download. This will work fine, but an easier way is to use the AcquireFilesSettings.DefaultAcquisitionOption to control the acquisition option for all entities in the download.

Regarding skipped files, the documentation for the AcquisitionStatus.Skipped says, “The file was not acquired.  It was skipped based on a user choice that occurred during validation.” The “validation” step the documentation is referencing is essentially equivalent to the AcquireFileExtensibilityOptions.PreFileAcquire handler.  It is during this event that potential problems that might prevent a download from succeeding are passed to the handler and the handler decides what to do. The “user choice” part is really only relevant for GUI acquires. The default behavior during a GUI acquire is to display prompts to the user such as when a file needs to be replicated before it can be downloaded. If a user ops to not acquire a file when these prompts are displayed, the file is considered “skipped”. For non-GUI downloads, the default PreFileAcquire handler doesn’t display any prompts and just decides things programmatically.  The default implementation will “skip” downloading a file for the following reasons:

•    The file to be download needs to be synced with a remote site before downloading and the AcquireFilesSettings.OptionsResolution.SyncWithRemoteSite setting is set to SyncwithRemoteSite.Validate

•   The local file that is going to be overwritten contains edits that are not stored in Vault and will be lost if the file is downloaded and the AcquireFilesSettings.OptionsResolution.OverwriteOption is not set to OverwriteOptions.ForceOverwriteAll

•    The file to be acquired is checked out to the current user in the download location and the AcquireFilesSettings.OptionsResolution.OverwriteOption is not set to OverwriteOptions.ForceOverwriteAll

If they want to force that every file that is part of the acquire is at least attempted to be downloaded, they’ll have to set the SynceWithRemoteSite setting to Always and the OverwriteOption to ForceOverwriteAll. This doesn’t mean that all entities to be acquired will succeed but I believe it will mean they will all at least be attempted.

Save RevisionTable content to CustomTable

By Adam Nagy

You may want to save the current values of the revision table before doing some modifications to the revision numbers - e.g. as a result of a Vault merger.

Here is a VBA sample showing how to do that:

Sub RevisionTableToCustomTable()
  Dim tg As TransientGeometry
  Set tg = ThisApplication.TransientGeometry

  Dim dd As DrawingDocument
  Set dd = ThisApplication.ActiveDocument
  
  Dim s As Sheet
  Set s = dd.ActiveSheet
  
  ' Get revision table
  Dim rt As RevisionTable
  Set rt = s.RevisionTables(1)
  
  ' Get dimensions
  Dim c As Integer
  Dim r As Integer
  c = rt.RevisionTableColumns.count
  r = rt.RevisionTableRows.count
  
  ' Counter
  Dim i As Integer, j As Integer
    
  ' Get headers and column widths
  ReDim headers(1 To c) As String
  ReDim widths(1 To c) As Double
  Dim rtc As RevisionTableColumn
  i = 1
  For Each rtc In rt.RevisionTableColumns
    headers(i) = rtc.Title
    widths(i) = rtc.Width
    i = i + 1
  Next
  
  ' Get contents and row heights
  ReDim contents(1 To c * r) As String
  ReDim heights(1 To r) As Double
  Dim rtr As RevisionTableRow
  i = 1: j = 1
  For Each rtr In rt.RevisionTableRows
    Dim rtcell As RevisionTableCell
    For Each rtcell In rtr
      contents(i) = rtcell.Text
      i = i + 1
    Next
    heights(j) = rtr.Height
    j = j + 1
  Next
  
  ' Create custom table with the content
  Dim ct As CustomTable
  Set ct = s.CustomTables.Add( _
    rt.Title + " (old)", _
    tg.CreatePoint2d(), _
    c, _
    r, _
    headers, _
    contents, _
    widths, _
    heights)
  
  ' Position it e.g. on top of the revision table
  Dim pt As Point2d
  Set pt = rt.Position
  Call pt.TranslateBy(tg.CreateVector2d( _
    0, Abs(ct.RangeBox.MaxPoint.Y - ct.RangeBox.MinPoint.Y)))
  ct.Position = pt
End Sub

You could also do it with fewer calls by using Export() on the RevisionTable to save contents to a CSV file and then create a CustomTable using AddCSVTable(), but in that case the table will be bound to the CSV file and that needs to exist along with the drawing file.

PLM 360 sample giving (401) Unauthorized error

By Adam Nagy

When running the C# sample from here (http://knowledge.autodesk.com/search-result/caas/downloads/content/plm-360-rest-api-v2-sample-code.html) you will get a (401) Unauthorized error if you do not change the customer key value from MYSITE to the name of the tenant. 

Here is a video with all the steps to run the sample: