Manufacturing DevBlog

Vector of minimum distance

By Adam Nagy

There is a utility object in the API called MeasureTools that enables you to do the same measuring that is available in the UI: e.g. to get the minimum distance between components of an assembly. In the UI you can also see a line showing the distance between the components:

 

You can get back the points of the distance line and the objects it was measured between using the API as well. Here is the description in the API Help file about the last parameter of GetMinimumDistance:

Context - Optional output NameValueMap object that returns additional information regarding the measurement. Following are the possible return values (descriptions are below the table):

ClosestPointOne - Point object that returns a transient point closest to entity one in the minimum distance measure. This point may or may not lie on entity one (but will lie on the plane or axis of entity one). If entity one is a position input (Point, Vertex, WorkPoint, etc.), the position of the input entity is returned

ClosestPointTwo - Point object that returns a transient point closest to entity two in the minimum distance measure. This point may or may not lie on entity two (but will lie on the plane or axis of entity two). If entity two is a position input (Point, Vertex, WorkPoint, etc.), the position of the input entity is returned

ClosestEntityOne - Object type that returns the entity on which the returned ClosestPointOne lies. This is applicable only in the case where the input EntityOne is a ComponentOccurrence (or its proxy)

ClosestEntityTwo - Object type that returns the entity on which the returned ClosestPointTwo lies. This is applicable only in the case where the input EntityTwo is a ComponentOccurrence (or its proxy)

IntersectionFound - Boolean that indicates whether an intersection was found between entities one and two. If True, the method returns a value of 0

The below VBA code will create two work points to represent the points we get from the GetMinimumDistance function:

Sub MinDistance()
  Dim doc As AssemblyDocument
  Set doc = ThisApplication.ActiveDocument
  
  Dim occs As ComponentOccurrences
  Set occs = doc.ComponentDefinition.Occurrences
  
  Dim context As NameValueMap
  Dim dist As Double
  dist = ThisApplication.MeasureTools.GetMinimumDistance( _
    occs(1), occs(2), , , context)
  
  ' Let's add the points as work points
  Dim wps As WorkPoints
  Set wps = doc.ComponentDefinition.WorkPoints
  
  Call wps.AddFixed(context.Item("ClosestPointOne"))
  Call wps.AddFixed(context.Item("ClosestPointTwo"))
End Sub

And here is the result of the above code:

 

Auto export driven dimension value to Excel

By Adam Nagy

Sometimes there could be a main dimension that causes the whole model to change, and so the values of the driven dimensions change as well. You could either monitor the main dimension for change using iLogic or one of the driven dimensions. In this case I'm going to do the latter.

Let's say we have the following part with a sketch that defines the Width and Height of the base of the model. We also have at the bottom a Driven Dimension associated with a Reference Parameter named DrivenWidth which changes when the Width changes:

I then create a rule named DrivenWidthRule which has DrivenWidth=DrivenWidth in it so it will be recognized as a Driving Rule for DrivenWidth - even though it's only affected by Width:

DrivenWidthRule:

' To fake a "Driving Rule"
DrivenWidth=DrivenWidth
' Actually simply using the parameter would be enough to trigger the rule
' Dim t = DrivenWidth

xlsFilePath = 
"C:\Users\Administrator\Documents\Inventor\MyProject\parameters.xls"

' Write info to excel file
GoExcel.Open(xlsFilePath, "Sheet1")

' Find the relevant parameter
' (in case we store many of them)
' Names are in column A with title "Name"
i = GoExcel.FindRow(xlsFilePath, "Sheet1", "Name", "=", "DrivenWidth")
If i > 0 Then
  ' Found it
  ' Values are in column B
  GoExcel.CellValue(xlsFilePath, "Sheet1", "B" + i.ToString()) = 
    DrivenWidth
End If

GoExcel.Save
GoExcel.Close

Now whenever Width changes, it will change DrivenWidth and so DrivenWidthRule will be called which then can update the values in the Excel file:

 

Find Touching Area of Two Coplanar Faces

By Xiaodong Liang

Two planar faces which are coplanar are not always overlapped. To know if they are overlapped and the touching area, one workaround could be extrude the sketches based on the faces with a tiny distance, and use TransientBRep.DoBoolean to check if the bodies of the two extrude features are intersected.

The following is demo code. It assumes two planar faces are selected. One material named “Magenta” is available.

Note: in UI, if the two planar faces are within one surface body and are overlapped, they cannot be selected independently. So to make a demo, it assumes the two planar faces are from different bodies. Of course, you can distinguish two faces from one surface body in the workflow of code.

 Private Sub Test()

 

        Try

            'get application

            oApp =

                System.Runtime.InteropServices.

                Marshal.GetActiveObject("Inventor.Application")

        Catch

        End Try

 

        Dim oPartDoc As PartDocument = oApp.ActiveDocument

        Dim oPartDef = oPartDoc.ComponentDefinition

 

        'get face1

        Dim oFace1 As Face

        oFace1 = oPartDoc.SelectSet(1)

        'get face2

        Dim oFace2 As Face

        oFace2 = oPartDoc.SelectSet(2)

 

        'if two faces are planar and coplanar

        If oFace1.SurfaceType =

                SurfaceTypeEnum.kPlaneSurface _

                    And oFace2.SurfaceType =

                    SurfaceTypeEnum.kPlaneSurface Then

 

            Dim oPlane1 As Plane

            oPlane1 = oFace1.Geometry

            Dim oPlane2 As Plane

            oPlane2 = oFace2.Geometry

 

            ' if normal of two faces are same

            If oPlane1.Normal.IsEqualTo(oPlane2.Normal) Then

 

                Dim extrudeDis As Double = 0.001

 

                'create the extrude feature from face1

                Dim oSketch1 As PlanarSketch =

                    oPartDef.Sketches.Add(oFace1)

                Dim oEdgeInFace1 As Edge

                For Each oEdgeInFace1 In oFace1.Edges

                    oSketch1.AddByProjectingEntity(oEdgeInFace1)

                Next

                Dim oProfile1 As Profile

                oProfile1 = oSketch1.Profiles.AddForSolid()

 

                Dim oExtrudeF1Def As ExtrudeDefinition

                oExtrudeF1Def =

                    oPartDef.Features.ExtrudeFeatures.

                    CreateExtrudeDefinition(oProfile1,

                        PartFeatureOperationEnum.kNewBodyOperation)

                oExtrudeF1Def.SetDistanceExtent(extrudeDis,

                        PartFeatureExtentDirectionEnum.kPositiveExtentDirection)

 

                Dim oExtrudeF1 As ExtrudeFeature

                oExtrudeF1 =

                    oPartDef.Features.ExtrudeFeatures.Add(oExtrudeF1Def)

 

                Dim oSB1 As SurfaceBody

                oSB1 = oExtrudeF1.SurfaceBodies(1)

 

 

                'create the extrude feature from face2

                Dim oSketch2 As PlanarSketch =

                    oPartDef.Sketches.Add(oFace2)

                Dim oEdgeInFace2 As Edge

                For Each oEdgeInFace2 In oFace2.Edges

                    oSketch2.AddByProjectingEntity(oEdgeInFace2)

                Next

 

                Dim oProfile2 As Profile

                oProfile2 =

                    oSketch2.Profiles.AddForSolid()

 

                Dim oExtrudeF2Def As ExtrudeDefinition

                oExtrudeF2Def =

                    oPartDef.Features.ExtrudeFeatures.

                    CreateExtrudeDefinition(oProfile2,

                                 PartFeatureOperationEnum.kNewBodyOperation)

                oExtrudeF2Def.SetDistanceExtent(extrudeDis,

                                 PartFeatureExtentDirectionEnum.

                                  kPositiveExtentDirection)

 

                Dim oExtrudeF2 As ExtrudeFeature

                oExtrudeF2 =

                    oPartDef.Features.ExtrudeFeatures.Add(oExtrudeF2Def)

 

                Dim oSB2 As SurfaceBody

                oSB2 = oExtrudeF2.SurfaceBodies(1)

 

                Dim oTransientB1 As SurfaceBody =

                    oApp.TransientBRep.Copy(oSB1)

                Dim oTransientB2 As SurfaceBody =

                    oApp.TransientBRep.Copy(oSB2)

 

                'check if bodies of the two extrude features are intersected

                oApp.TransientBRep.DoBoolean(oTransientB1,

                                   oTransientB2,

                                   BooleanTypeEnum.kBooleanTypeIntersect)

 

                If oTransientB1.Volume(0.01) > 0 Then

                    MsgBox("The two faces are overlapped!")

 

                    'create a client graphics to show the intersect area

                    Dim oClientGraphics As ClientGraphics

                    Try

                        oClientGraphics =

                            oPartDef.ClientGraphicsCollection.Item("overlap")

                        oClientGraphics.Delete()

                    Catch ex As Exception

 

                    End Try

 

                    oApp.ActiveView.Update()

 

                    oClientGraphics =

                        oPartDef.ClientGraphicsCollection.Add("overlap")

 

                    'add graphics node

                    Dim oSurfacesNode As GraphicsNode

                    oSurfacesNode =

                        oClientGraphics.AddNode(1)

 

                    'add the face of WeldBead.BeadFaces

                    Dim oSurfaceGraphics As SurfaceGraphics

                    oSurfaceGraphics =

                        oSurfacesNode.AddSurfaceGraphics(oTransientB1)

 

 

                    'set graphics' color. assume “Magenta” exists in the document

                    oSurfacesNode.Appearance =

                        oPartDoc.Assets("Magenta")

 

                    'transform the client graphics to a location

                    Dim oTransGeom As TransientGeometry

                    oTransGeom =

                        oApp.TransientGeometry

 

                    Dim oV As Vector

                    oV = oTransGeom.CreateVector(1, 1, 1)

 

                    Dim oM As Matrix

                    oM = oTransGeom.CreateMatrix()

                    Call oM.SetTranslation(oV)

 

                    oSurfacesNode.Transformation = oM

 

                    'update the view

                    oApp.ActiveView.Update()

 

 

                Else

                    MsgBox("The two faces are NOT overlapped!")

                End If

 

                oExtrudeF1.Delete()

                oExtrudeF2.Delete()

 

            Else

 

                MsgBox("the faces are NOT coplanar!")

            End If

 

        Else

 

            MsgBox("one of the faces are NOT planar!")

        End If

 

 

    End Sub

Parent of Mirror Solid

By Xiaodong Liang

We have two choices when mirroring a solid, either the mirrored body is attached with the original solid, or a new solid is created.

We have two scenarios when mirroring a solid,

1) either the mirrored body is attached with the original solid

2) or a new solid is created

MirrorFeature.MirrorOfBody tells if the mirror feature is from a solid or the features. For scenario 1 above, MirrorFeature. SurfaceBody returns the original solid. For scenario 2, there is not direct API, but we can workaround it by checking the original face of the mirrored face, by which we can get the original solid.

The code below is a small demo. It assumes a mirror feature is selected. It covers the two scenarios.

Sub FindOriginalBody()

    Dim oPart As PartDocument

    Set oPart = ThisApplication.ActiveDocument

      Dim oPdef As PartComponentDefinition

    Set oPdef = oPart.ComponentDefinition

    Dim oMirrorF As MirrorFeature

    Set oMirrorF = ThisApplication.ActiveDocument.SelectSet(1)

    Dim oFPE As FeaturePatternElement

    Dim oMirrorMatrix As Matrix

    If oMirrorF.MirrorOfBody Then

        Dim oSB As SurfaceBody

‘set end of the feature below the mirror feature

       oMirrorF.SetEndOfPart True

       Set oSB = oMirrorF.SurfaceBody

‘set the end of feature back

oPdef.Features(oPdef.Features.Count).SetEndOfPart False

‘scenario 1

       ' if the mirror feature is built in the same solid

       If Not oSB Is Nothing Then

         Debug.Print "the original body for the mirror feature is:" & oSB.Name

          Exit Sub

       End If

‘scenario 2

       'if the mirror feature is built in a new solid       

       Dim oIdentityM As Matrix

      Set oIdentityM = ThisApplication.TransientGeometry.CreateMatrix

      oIdentityM.SetToIdentity   

‘ iterate each item of the mirror elements

       For Each oFPE In oMirrorF.PatternElements

         ' actually only two elements with Mirror feature.

          ' one is the original body, the other is the mirror           

          If oFPE.Transform.IsEqualTo(oIdentityM) = False Then

             ' this is the mirror element

            Set oMirrorMatrix = oFPE.Transform

          End If

       Next

         oMirrorMatrix.Invert

        Dim oEachF As Face

        Dim oEachBody As SurfaceBody

        ' MirrorFeature.Faces contains the faces of mirror feature only

        'just check one face

        Dim oFaceOnMirror As Face

        Set oFaceOnMirror = oMirrorF.Faces(1)

          Dim oPtInFace As Point

          Set oPtInFace = oFaceOnMirror.PointOnFace

          Call oPtInFace.TransformBy(oMirrorMatrix)

          On Error Resume Next

          'find which body contains the orignal face

          For Each oEachBody In oPdef.SurfaceBodies

                Dim oOrignFace As Face

                Set oOrignFace =
                    oEachBody.LocateUsingPoint(kFaceObject, oPtInFace)

                If Err.Number = 0 Then

                    If Not oOrignFace Is Nothing Then

                     Debug.Print "the original body for the mirror feature is:" & oEachBody.Name

                     'Exit For

                    End If

                    Err.Clear

                End If                

          Next

    End If

End Sub

Get Contour of WeldBead

By Xiaodong Liang

The WeldBead object provides the two faces which generates the weld, and also provides the faces that define the geometric result of the weld bead: WeldBead.BeadFaces

The following is a small demo that get the faces, add them as a client graphics.

Public Sub test()
   
    'get document and definition
    Dim oDoc As AssemblyDocument
    Set oDoc = ThisApplication.ActiveDocument
 
    Dim oCompDef As AssemblyComponentDefinition
    Set oCompDef = oDoc.ComponentDefinition
   
    'if this is a weld document
    If oCompDef.Type = kWeldmentComponentDefinitionObject Then
        Dim wcd As WeldmentComponentDefinition
        Set wcd = oCompDef
    Else
        Exit Sub
    End If
  
    ' get one weld bead
    Dim oWB As WeldBead
    Set oWB = wcd.Welds.WeldBeads(1)
 
    On Error Resume Next
    Dim oClientGraphics As ClientGraphics
    Set oClientGraphics = oCompDef.ClientGraphicsCollection.Item("weldbead")
    If Err.Number = 0 Then
        'delete the older client graphics, if any
        On Error GoTo 0
        oClientGraphics.Delete
        ThisApplication.ActiveView.Update
    End If
  
    Err.Clear
    On Error GoTo 0
  
   ' create a client graphics
    Set oClientGraphics = oCompDef.ClientGraphicsCollection.Add("weldbead")
  
    'add graphics node
    Dim oSurfacesNode As GraphicsNode
    Set oSurfacesNode = oClientGraphics.AddNode(1)
   
    'add the face of WeldBead.BeadFaces
    Dim oSurfaceGraphics As SurfaceGraphics
    Dim oEachWeldFace As Face
    For Each oEachWeldFace In oWB.BeadFaces
      Set oSurfaceGraphics = oSurfacesNode.AddSurfaceGraphics(oEachWeldFace)
    Next
   
    'set graphics' color. assume “Magenta” exists in the document
    oSurfacesNode.Appearance = oDoc.Assets("Magenta")
   
    'transform the client graphics to a location
     Dim oTransGeom As TransientGeometry
    Set oTransGeom = ThisApplication.TransientGeometry

    Dim oV As Vector
    Set oV = oTransGeom.CreateVector(10, 10, 10)

    Dim oM As Matrix
    Set oM = oTransGeom.CreateMatrix()
    Call oM.SetTranslation(oV)

    oSurfacesNode.Transformation = oM
   
    'update the view
    ThisApplication.ActiveView.Update

End Sub

Client feature visibility in design view representa​tions

By Xiaodong Liang

Question:
I have an assembly with a client feature that contains client graphics. I have exposed the visibility (ClientFeature.Definition.ClientGraphicsCollection​[1].Visible) to the user via a context menu option. Changing the visibility currently affects all view representations. Is there a way to associate the visibility with each design view representation?

Solution:
Client Feature is API specific. UI does not know it. So the default mechanism of design view representation does not cover the feature. But you can control this by RepresentationEvents. OnActivateDesignView. The following is a demo VBA, including a macro which creates the client feature.

 

‘****module: create client feature ************

Sub CGInClientFeatureTest()

Dim oDoc As AssemblyDocument

Set oDoc = ThisApplication.ActiveDocument

 

‘create client feature definition

Dim oClientFeatureDef As ClientFeatureDefinition

Set oClientFeatureDef = oDoc.ComponentDefinition.Features.ClientFeatures.CreateDefinition("ClientFeatureTest")

 

‘create client feature

Dim oClientFeature As ClientFeature

Set oClientFeature = oDoc.ComponentDefinition.Features.ClientFeatures.Add(oClientFeatureDef, "ClientIDString")

 

‘create graphics for client feature

Dim oCGCol As ClientGraphicsCollection

Set oCGCol = oClientFeatureDef.ClientGraphicsCollection

 

Dim oCG As ClientGraphics

On Error Resume Next

Set oCG = oCGCol.Item("CGWithCF")

If oCG Is Nothing Then

Set oCG = oCGCol.Add("CGWithCF")

End If

 

‘create node

Dim oSurfacesNode As GraphicsNode

Set oSurfacesNode = oCG.AddNode(1)

 

Dim oTransientBRep As TransientBRep

Set oTransientBRep = ThisApplication.TransientBRep

 

' Create a point representing the center of the bottom of the cone

Dim oBottom As Point

Set oBottom = ThisApplication.TransientGeometry.CreatePoint(0, 0, 0)

 

' Create a point representing the tip of the cone

Dim oTop As Point

Set oTop = ThisApplication.TransientGeometry.CreatePoint(0, 10, 0)

 

' Create a transient cone body

Dim oBody As SurfaceBody

Set oBody = oTransientBRep.CreateSolidCylinderCone(oBottom, oTop, 5, 5, 0)

 

' Reset the top point indicating the center of the top of the cylinder

Set oTop = ThisApplication.TransientGeometry.CreatePoint(0, -40, 0)

 

' Create a transient cylinder body

Dim oCylBody As SurfaceBody

Set oCylBody = oTransientBRep.CreateSolidCylinderCone(oBottom, oTop, 2.5, 2.5, 2.5)

 

' Union the cone and cylinder bodies

Call oTransientBRep.DoBoolean(oBody, oCylBody, kBooleanTypeUnion)

 

' Create client graphics based on the transient body

Dim oSurfaceGraphics As SurfaceGraphics

Set oSurfaceGraphics = oSurfacesNode.AddSurfaceGraphics(oBody)

 

ThisApplication.ActiveView.Update

End Sub

 

‘*******module: start/stop RepresentationEvents event*******

Dim oCls As clsREvents

Sub startE()

    Set oCls = New clsREvents

End Sub

 

Sub stopE()

    Set oCls = Nothing

End Sub

 

‘*****Class: RepresentationEvents**************

Private WithEvents ReEvts As RepresentationEvents

 

Private Sub Class_Initialize()

   

    Set ReEvts = ThisApplication.RepresentationEvents

End Sub

 

Private Sub Class_Terminate()

    Set ReEvts = Nothing

End Sub

 

 

Private Sub ReEvts_OnActivateDesignView(ByVal DocumentObject As Document, ByVal Representation As DesignViewRepresentation, ByVal BeforeOrAfter As EventTimingEnum, ByVal Context As NameValueMap, HandlingCode As HandlingCodeEnum)

 

    Dim oDoc As AssemblyDocument

Set oDoc = ThisApplication.ActiveDocument

 

‘get Client Feature

    Dim oClientFeature As ClientFeature

Set oClientFeature = oDoc.ComponentDefinition.Features.ClientFeatures(1)      

    

  If Representation.Name = "Master" Then

oClientFeature.Definition.ClientGraphicsCollection(1).Visible = kAllGraphicsVisible

  End If

 

  If Representation.Name = "View1" Then

oClientFeature.Definition.ClientGraphicsCollection(1).Visible = kNoGraphicsVisible

  End If 

 

End Sub

Simple Exploration on CAM Simulation

By Xiaodong Liang

Autodesk provides solutions of CAM: Inventor CAM, CAM 360 etc. Some custom applications of Inventor would need to produce their own CAM process with the custom algorism. The most important step is to analogous to a machining operation.

I explored a bit with Inventor API. Basically, we need to get the update to date status of the base body that the tool has affected, by TransientBrep.DoBoolean, and display them by client graphics.

TransientBRep.DoBoolean( BlankBody As SurfaceBody,
                                         ToolBody As SurfaceBody,
                               BooleanType As BooleanTypeEnum )

BlankBody: Input/Output SurfaceBody that will be modified as a result.
ToolBody: Input SurfaceBody that is used to operate on the blank body.
BooleanType: Input BooleanTypeEnum that specifies the type of Boolean operation to perform. Valid values are kBooleanTypeDifference, kBooleanTypeUnion, and kBooleanTypeIntersect.

In CAM simulation, the BooleanType is kBooleanTypeDifference which means the tool will remove the materials of the base body.

If you are not familiar with client graphics, I’d recommend with the tutorials we posted on Brian’s blog.

The following demo tests with the attached part in a standalone EXE, in which there are one plate which is base body and a small stick as a tool. The tool will move on X-Y plane and inside the base body along Z (depth = 1cm). It removes the material from the diameter = 4 cm and shrink to diameter = 0.

Download CamPart

Inventor.Application oInvApp;

Asset toolAppearance;

Asset baseAppearance;

void CamTest()

{

    //get active Inventor process

        oInvApp =

        System.Runtime.InteropServices.Marshal.

        GetActiveObject("Inventor.Application")

        as Inventor.Application;

 

    //get active document

    PartDocument oPartDoc =

        oInvApp.ActiveDocument asPartDocument;            

    PartComponentDefinition oPartDef =

        oPartDoc.ComponentDefinition;

 

    //Transient Brep object

    TransientBRep oTBrep =

        oInvApp.TransientBRep;

    //Transient Geometry

    TransientGeometry oTG=

        oInvApp.TransientGeometry;

 

    //base body

    SurfaceBody oBaseBody =

        oPartDef.SurfaceBodies[1];

    //tool body

    SurfaceBody oToolBody =

        oPartDef.SurfaceBodies[2];

 

    //make base body and tool body invisible

    //we just show client graphics

    oBaseBody.Visible = false;

    oToolBody.Visible = false;

 

    //make a copy of base body and tool body

    //we will use them as client graphics

    SurfaceBody oBaseBody_Copy =

        oTBrep.Copy(oBaseBody);

    SurfaceBody oToolBody_Copy =

        oTBrep.Copy(oToolBody);

 

    //Client Graphics

    ClientGraphics oClientGraphics;

    try

    {

        //delete if the Client Graphics exists

        oClientGraphics =

            oPartDef.ClientGraphicsCollection["CAMDemo"];

 

        // An existing client graphics object

        // was successfully obtained so clean up.

        oClientGraphics.Delete();

 

        // update the display to see the results.

        oApp.ActiveView.Update();              

    }

    catch

    {

        //get the appearance for tool

        toolAppearance =

            oPartDoc.Assets["Gold - Metal"];

 

        baseAppearance =

            oPartDoc.Assets["Plate"];

 

        // Create the ClientGraphics

        oClientGraphics =

            oPartDef.ClientGraphicsCollection.Add("CAMDemo");

 

        //add graphics node for base body

        GraphicsNode _oNode_BaseBody =

            oClientGraphics.AddNode(1);

        //add graphics of base body

        SurfaceGraphics _Gra_BaseBody =

            _oNode_BaseBody.AddSurfaceGraphics(oBaseBody_Copy);

        _oNode_BaseBody.Appearance = baseAppearance;    

 

        //add graphics node for tool body

        GraphicsNode _oNode_ToolBody =

            oClientGraphics.AddNode(2);

        //add graphics of tool body

        SurfaceGraphics _Gra_ToolBody =

            _oNode_ToolBody.AddSurfaceGraphics(oToolBody_Copy);

        _oNode_ToolBody.Appearance = toolAppearance;           

 

        //CAM Simulation starts:

 

        //move tool inside the base along Z

        Matrix oMovingM =

            oTG.CreateMatrix();

        oMovingM.SetTranslation(oTG.CreateVector(0, 0, -1));

 

        //move tool inside base body: depth = 1

        eachCAM(oMovingM, 

            ref oBaseBody_Copy,

            ref oToolBody_Copy,

            ref _oNode_BaseBody,

            ref _oNode_ToolBody,

            ref _Gra_BaseBody,

            ref _Gra_ToolBody);

 

        // diameter of the tool body

        double toolDia = 0.5;

 

        // how many circle loops the tool will move

        int loopCount = 10;               

        //from which diamater the tool starts to move

        double max_CAM_Dia = 4.0;          

 

        //last matrix of the tool body               

        Matrix oLastMovingM = oTG.CreateMatrix();

        oLastMovingM.SetToIdentity();

 

        //tool moves from max diameter to 0

        for (int circleLoop = loopCount;

            circleLoop > 0 ;

            circleLoop--)

        {

            //diameter of this loop

            double thisDia = max_CAM_Dia * circleLoop / loopCount;

            //the perimeter of this circle

            double perimeterofLoop = Math.PI * thisDia;

            //how many steps the tool needs to move for this loop

            int circleStepCount =

                (int)(perimeterofLoop / toolDia) *2;

                   

            //moving of each circle

            for (int angleIndex = 1;

                angleIndex < circleStepCount;

                angleIndex++)

            {              

                //get the location the tool will move to     

                double x = thisDia / 2.0 *

                    Math.Cos(angleIndex * Math.PI * 2 / circleStepCount);

                double y = thisDia/ 2.0 *

                    Math.Sin(angleIndex * Math.PI * 2 / circleStepCount );

                       

                //transform matrix

                Matrix oEachMovingM = oTG.CreateMatrix();

                oEachMovingM.SetTranslation(oTG.CreateVector(x, y, 0));

                //the last location of the tool affects

                //so invert and update with the new matrix

                oLastMovingM.Invert();

                oLastMovingM.TransformBy(oEachMovingM);                       

                oMovingM = oLastMovingM;

 

                //move

                eachCAM(oMovingM,                         

                    ref oBaseBody_Copy,

                    ref oToolBody_Copy,

                    ref _oNode_BaseBody,

                    ref _oNode_ToolBody,

                    ref _Gra_BaseBody,

                    ref _Gra_ToolBody);

                       

                //record the current matrix for next use

                oLastMovingM = oEachMovingM;

            }

        }

 

    } 

 

}

 

// each step of moving

void eachCAM(Matrix _oMovingM,                 

            refSurfaceBody _BaseBody,

            refSurfaceBody _ToolBody,

            refGraphicsNode _BaseBodyNode,

            refGraphicsNode _ToolBodyNode,                   

            refSurfaceGraphics _BaseGrap,

            refSurfaceGraphics _ToolGrap                  

            )

{

    TransientBRep oTBrep = oInvApp.TransientBRep;

 

    // we need to recreate the graphics.

        _BaseGrap.Delete();

        _ToolGrap.Delete();

           

    //transform the tool body

        oTBrep.Transform(_ToolBody, _oMovingM);            

    //remove material of the base body

        oTBrep.DoBoolean(_BaseBody, _ToolBody,

            BooleanTypeEnum.kBooleanTypeDifference);

 

            

    //add the update bodies again

        _BaseGrap = _BaseBodyNode.AddSurfaceGraphics(_BaseBody);

        _ToolGrap = _ToolBodyNode.AddSurfaceGraphics(_ToolBody);

    //assign the appearance to the tool graphics

             

        _BaseBodyNode.Appearance = baseAppearance;

        _ToolBodyNode.Appearance =toolAppearance;

    //update the view

        oInvApp.ActiveView.Update();

}

 

 

Note: the residual images in this gif is caused by the video production.Tthere is no residual when working with Inventor.

Modify Ribbon and Menu items

By Adam Nagy

Just like in other Autodesk products, in Inventor as well the same library is used to present a Ribbon interface: AdWindows.dll
This provides a public API under the namespace Autodesk.Windows

Here is an example of using it inside Revit: http://thebuildingcoder.typepad.com/blog/2011/02/pimp-my-autocad-or-revit-ribbon.html

It's not a fully supported approach though, since some functions like adding a command button to the Ribbon are not supported - it would be difficut to properly hook up a control created this way to an Inventor command. For that you would need to use the Inventor API.
So when using it, take care and make sure that everything is working as expected.

E.g. the following VB.NET code could be used to hide the Options button in the Application Menu:

' 1) Need to reference AdWindows.dll from
' <Inventor Install Folder>\bin
' 2) Set it to "Copy Local" = "False"
Dim menu As Autodesk.Windows.ApplicationMenu = 
  Autodesk.Windows.ComponentManager.ApplicationMenu
menu.OptionsButton.IsVisible = False 

Note: when referencing AdWindows.dll the project will require other dependencies as well that the compiler will warn you about. You'll simply have to add a reference to those Windows .NET assemblies as well: PresentationCore, PresentationFramework, WindowsBase and System.Xaml

Autodesk Vault Plug-in Wizard Helps Creating Vault Plug-in More Easily

By Daniel Du

 

As described in Vault SDK help file, it involves several steps to create a vault plug-in, including adding references, adding vcet.config file, setting additional assembly property and implementing some interfaces. You also need to copy the output files into vault extension folder manually. I found it a little complicated and time consuming, so I went ahead to create a vault plug-in wizard, which helps me creating vault explorer plug-in, custom job handlers, event handlers more easily. If you are interested in this tool, it can be downloaded here. Please note that it is not fully tested, and you are on your own risk to use this wizard.

 

After you installed this wizard, it should appear in your Visual Studio project templates. The template are available for both C# and VB.NET. This version is targeting Autodesk Vault 2014, so you need to select .Net Framework 4.0, if it does not appear, you probably selected wrong .net framework.

 

Now name your vault plug-in and specify the location as usual. By clicking OK, a wizard form will appear as below:

You need to check the Vault SDK path, Web Service Extension 3(WSE3) path and Vault Explorer execution path at first run, if it is not correct for you, you need to specify to the correct path and it will be saved for latter use. This wizard helps you creating vault explorer plug-in, custom job handlers or event handlers. With a customized vault explorer plug-in, you can add custom commands, add custom tabs, hide existing commands or subscribe to pre and post events when any Vault Explorer commands are executed. Jobserver is a nice feature that lets you distribute work across the network.  Instead of performing a task directly, a job can be queued up so that the work can be done elsewhere.  Vault comes with a few built-in job types, but the real power comes in creating your own. You can create your own job by choosing “Custom Job” in wizard. If you want to customize the business logic, you can write event handlers by choosing “Event Handler” in wizard.  These handlers will receive notification whenever a Vault client on that machine does an action that you subscribed to.

 

Then you can get a bare bone vault plug-in project with necessary files and adding necessary references.

The sample plug-in adds the default implementation of interfaces, you need to remove the ones you do not need. The Vault Explorer Plug-in also comes with a HelloWorld sample, you can modify it to create your own explorer plug-in based on it. Please note that if you rename the class name, you also need to change it in vaultplugin.vcet.config accordingly.

For all types of plug-in, a build event is added by wizard to help you copy the output dlls and vcet.config file to %ProgramData%/Autodesk/Vault 2014/Extensions/ folder. 

For Vault Explorer, the wizard also help us to setup the debug option, you can just press F5 to start Explorer for debugging.

 

So, that’s it, simple and easy, right ?

 

Finally all source code is uploaded to github, https://github.com/ADN-DevTech/Vault-Plugin-Wizard, I would be more than happy if you’d like to keep working on it or report issues there.

 

Have fun!

Custom File Dialog with Open Express

By Xiaodong Liang

From Inventor 2014, you are allowed to open assembly in “Express Mode” which is essentially a light weight model. The benefits of this, are that you can open models faster and that you can open, and work with lots of complex geometry that may have previously been a bit too much for your graphics card to process.

           - from Clinton Brown's Blog

When you open an assembly, you can see an option [Open Express] which indicates whether opening in express mode or not.

 

API can override the built-in open dialog with the custom behaviors. But some developers found even though the custom dialog is opened correctly, the [Open Express] option is missed.

Actually, the issue is because the FileDialog.InsertMode property is true (this is the default value). We don't support opening in Express mode for insert (e.g. place component). If it is appropriate, this will happen automatically. The solution is to set the InsertMode to false prior to showing the dialog. Then the Express checkbox will be shown and enabled as appropriate. The API help reference is not well documented at this point.

In addition, when InsertMode = false, the custom file dialog will know the choice of the user of the option [Open Express]. But you need to tell Inventor if opening assembly in express or not. Otherwise, the assembly will still be opened in full mode.

The following is a VBA demo:

‘*****module******

Option Explicit

Private oEventHandler As Class1

Private Sub StartFileOpen()
   Set oEventHandler = New Class1
End Sub
  
Private Sub EndFileOpen()
    Set oEventHandler = Nothing
End Sub

‘****even class *******

Option Explicit

Private WithEvents oEvents As FileUIEvents
Private inCustomDlg As Boolean

Private Sub Class_Initialize()
Set oEvents = ThisApplication.FileUIEvents
inCustomDlg = False
End Sub

Private Sub Class_Terminate()
Set oEvents = Nothing
End Sub

Private Sub oEvents_OnFileOpenDialog(FileTypes() As String, ByVal ParentHWND As Long, FileName As String, ByVal Context As NameValueMap, HandlingCode As HandlingCodeEnum)

If inCustomDlg = False Then '  to avoid recursive callback
    inCustomDlg = True
    Dim oFileLocations As FileLocations
    Set oFileLocations = ThisApplication.FileLocations
   
    Dim FileOpenForm As FileDialog
    Call ThisApplication.CreateFileDialog(FileOpenForm)
    FileOpenForm.InsertMode = False
    FileOpenForm.InitialDirectory = oFileLocations.Workspace
    With FileOpenForm
            ' Set the initial Directory
            .InitialDirectory = oFileLocations.Workspace
            .DialogTitle = "My File Open"
            .Filter = "Part File (*.ipt)|*.ipt" _
                      & "|Assembly File (*.iam)|*.iam" _
                      & "|Presentation File (*.ipn)|*.ipn" _
                      & "|Drawing File (*.idw)|*.idw" _
                      & "|Design element File (*.ide)|*.ide" _

            .FilterIndex = 2    ' *.iam files
            .OptionsEnabled = True
            '.Flags = cdlOFNHideReadOnly
            .ShowOpen
        End With
        FileName = FileOpenForm.FileName
        If FileOpenForm.OptionValues.Count >= 6 Then
            ' assembly has 6 options
           
            Dim index As Integer
            Dim oKey As String
            For index = 1 To FileOpenForm.OptionValues.Count
            
                 oKey = FileOpenForm.OptionValues.Name(index)
                 If oKey = "OpenExpressMode" Then
                    ' this is a Boolean for OpenExpress/Don't open Express
                    If FileOpenForm.OptionValues.Item(index) Then
                        'if OpenExpress was specified, pass it back through the context
                        Context.Add "ExpressModeBehavior", "OpenExpress"
                    End If
                 End If
            Next
            
          
        End If

        If FileName = "" Then
            HandlingCode = kEventCanceled
        Else
            HandlingCode = kEventHandled
        End If
        inCustomDlg = False
End If
End Sub