AutoCAD DevBlog

Aligning MText with picked point on a curve

By Balaji Ramamoorthy

In this discussion forum post, the developer wanted an MText to align automatically with the curve without having to provide additional inputs for specifying the rotation. Kent Cooper's nice reply in that forum post provides all that is necessary to implement that. Since this requirement of aligning an MText along a curve is quite essential in Civil / Survey applications, I am posting a bare-bone implementation of it that you can customize. The key to finding the rotation is to determine the first derivative (slope) of the curve at the point the entity was selected. 

Here is the code snippet :

(vl-load-com)

(setq es    (entsel)
      entpt (osnap (cadr es) "_nea")
      ang   (angle '(0 0 0)
		   (vlax-curve-getFirstDeriv
		     (vlax-ename->vla-object (car es))
		     (vlax-curve-getParamAtPoint
		       (vlax-ename->vla-object (car es))
		       entpt
		     )
		   )
	    )
)
(if (and (> ang (/ pi 2)) (<= ang (* pi 1.5)))
  (setq ang (+ ang pi))
)
(setq hght (getreal "\nText Height : "))
(setq
  mspace (vla-get-modelspace
	   (vla-get-activedocument (vlax-get-acad-object))
	 )
)

(setq mtextobj (vla-addMText
		 mspace
		 (vlax-3d-point entpt)
		 0.0
		 "AUTOCAD"
	       )
)
(vla-put-attachmentPoint
  mtextobj
  acAttachmentPointMiddleCenter
)
(vla-put-insertionPoint mtextobj (vlax-3d-point entpt))
(vla-put-Rotation mtextobj ang)
(vla-put-Height mtextobj hght)
(vla-put-Color mtextobj 7)
(vla-put-backgroundfill mtextobj :vlax-true)

Here is a sample output :

Using DIMPOST in a Lisp routine

By Xiaodong Liang

Question
I'm trying to change DIMPOST to \X in a lisp routine. The program will not accept \X in a lsp program. I'm want to change Dimstyle using the set up; Method set to NONE for both primary(Metric) and alternate units(English) and alternate unit placement under the primary units. I can do this manually but not in the lisp.

Solution
With these Lisp statements, the dimension formatting were as requested by the developer :

<<<

; To reset the alternative dimension prefix and suffix

(command-s "DIMAPOST" ".")

; To reset the primary dimension prefix and suffix

(command-s "DIMPOST" ".")

; To set the orientation of the alternative dimension over the primary dimension

(setvar "DIMPOST" "\\X")

>>>

Copy a leader using Visual LISP

By Wayne Brill

Recently I had a case where the question was how to create a new leader based on an existing leader using AutoLISP. Here is an example that I came up with. When you run this example you select a leader and the MText annotation for the leader. After you run the function you will need to move the Leader manually to see that there are are two leaders at the same location.

Another way to do this would be to use the Copy method and set the annotation property. This example is just getting the points from the existing leader, the MText, and then creating a new Leader at the same location.   

 

(defun C:copyLeaderTest (/ vla_ldr vla_mtx coords numberOfPoints
           arrayForPoints points attachPointFromExistingMText
           textForMText widthForMText insertioinPointForMText
           acadObj doc modelSpace newMText
               drawingDirectionForMText newLeader verticalTextPosition)

  (vl-load-com)
  (setvar "osmode" 0)
  (setvar "orthomode" 0)

  ; Get Leader and MText
  (while (setq ss1 (ssget (list (cons -4 "<OR")
    (cons 0 "LEADER") (cons 0 "MTEXT")(cons -4 "OR>"))))

   ; Ensure selection set has two entities
  (if (/= (sslength ss1) 2)
    (alert "Select 1 MText and 1 leader.")
    ; Have a Leader and MText get the ActiveX Object
    (progn
      (if (= (cdr (assoc 0 (entget (ssname ss1 0)))) "LEADER")
    (setq vla_ldr (vlax-ename->vla-object (ssname ss1 0))
          vla_mtx (vlax-ename->vla-object (ssname ss1 1))
    )
    (setq vla_ldr (vlax-ename->vla-object (ssname ss1 1))
          vla_mtx (vlax-ename->vla-object (ssname ss1 0))
    )
      )

         
      ; Get the coordinates from the existing leader
      ; and make an array of doubles
      (setq coords (vlax-get vla_ldr 'Coordinates))
      (setq numberOfPoints (1- (length coords)))
      (setq arrayForPoints (cons 0 numberOfPoints))
      (setq points (vlax-make-safearray vlax-vbDouble
                             arrayForPoints))
      (vlax-safearray-fill points coords)
     
    ; Store the current attachmentpoint of the existing MText 
    (setq attachPointFromExistingMText (vla-get-attachmentpoint vla_mtx))

    ; change the attachmentPoint for existing leader to Top Left
    ; This is will make the insertion point correct for the new MText
    (vla-put-AttachmentPoint vla_mtx acAttachmentPointTopLeft)
   
    (setq textForMText (vla-get-TextString vla_mtx))
    (setq widthForMText (vla-get-width vla_mtx))
    (setq insertioinPointForMText (vla-get-insertionpoint vla_mtx))

    ; Get modelspace and add the new MText
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    (setq modelSpace (vla-get-ModelSpace doc)) 
    (setq newMText (vla-AddMText modelSpace
          insertioinPointForMText widthForMText textForMText))

    (vla-put-AttachmentPoint newMText attachPointFromExistingMText)

    ; make the attachmentPoint what it was
    (vla-put-AttachmentPoint vla_mtx attachPointFromExistingMText)

    (setq drawingDirectionForMText (vla-get-drawingdirection vla_mtx))
    (vla-put-drawingdirection newMText drawingDirectionForMText)
     
    ;; Create the leader object in model space
    (setq newLeader (vla-AddLeader modelSpace points newMText acLineWithArrow))

    (setq verticalTextPosition(vla-get-VerticalTextPosition vla_ldr))
    (vla-put-VerticalTextPosition newLeader verticalTextPosition)
     
    (vla-put-ArrowheadBlock
        newLeader
        (vla-get-ArrowheadBlock vla_ldr)
    )

    (vla-put-layer newLeader (vla-get-layer vla_ldr))
    (vla-put-layer newMText (vla-get-layer vla_mtx))

   ; (vla-Erase vla_ldr)
   ; (vla-Erase vla_mtx)

     )
  )
)

  (princ)
)

AutoLISP Documentation Updates - Windows and Mac

By Virupaksha Aithal

Our documentation team has made number of changes as part of the AutoLISP documentation. For details refer blog post http://hyperpics.blogs.com/beyond_the_ui/2013/10/autolisp-documentation-updates-windows-and-mac.html

AutoCAD “Font file doesn’t Exist” when it does!?!

by Fenton Webb

One of my developers was trying to create a toolbar button which automatically setup some text styles/parameters. Everything was fine except that on some machines, the button would fail – the error was “Font file doesn’t exist”. He was using a very commonly used font file “arial.ttf”, indeed arial.ttf is the default font for the “Standard” AutoCAD style.

It seems there are very important updates the Font packs that you need to include (update) with your Windows installation – check out http://www.microsoft.com/typography/fonts/

I’m guessing Windows update also includes these Font updates as ‘Optional’ – best install them for an easy life!

AutoCAD OEM Support for AutoLISP/LISP

by Fenton Webb

AutoCAD OEM does support LISP, but there are a few restrictions:

1. LISP applications must be compiled into .fas, raw .lsp files are not supported.
• You must compile your LISP applications using the inbuilt “AutoCAD OEM” (aoem.exe) application that is installed with the AutoCAD OEM CD.
• Once the .lsp has been compiled into a .fas, you must then bind the fas file to the OEM product in the build process. This means that you can never just load LISP files (.fas) into an OEM product, it must be registered at build time.
2. The ActiveX API is not supported in LISP; that means vlax functions do not work.
3. The VLIDE and APPLOAD commands are omitted in 3rd party AutoCAD OEM products.
4. The user-entered LISP interpreter is disabled in 3rd party AutoCAD OEM products. The (command) still works fine when invoked from an OEM bound .fas file.

Importing named Layout in an AutoCAD DWG file using LISP

By Partha Sarkar

If you are wondering how to import a named Layout into the current drawing file using LISP in AutoCAD, here you go.

LISP code snippet below, demonstrates how to import a layout named "ABC" from a selected DWG file to the current drawing file.

(defun C:LayoutImport()

  ;; Select a DWG file to import a Layout
	(setq myFile (getfiled "Select your DWG File:" " " "dwg" 8)) 
	(command"layout" "t" myFile "ABC") 
	(alert "New Layout is inserted!") 
	(princ) 
)

 

After executing the above LISP code, you would see a new Layout named “ABC” is imported to the current DWG –

 

API webcast archive

By Stephen Preston

As part of our ADN Open work to move our API content to more accessible (search-engine-findable) locations, I'm posting our webcast archive to DevBlog. Some of these recordings are  old now, but still contain useful information. And, being recordings of live webcasts, they are not as polished as our DevTV recordings.

Note that some recordings are in Chinese and some in English.

Webcast	Language	Date
AutoCAD .Net - Session 2	English	13-Sep-12
AutoCAD .Net - Session 1	English	6-Sep-12
AutoCAD API	Chinese	25-Apr-12
DevTV: AutoCAD .Net API - Chinese - Part 1	Chinese	6-Apr-12
DevTV: AutoCAD .Net API - Chinese - Part 2	Chinese	6-Apr-12
AutoCAD .NET - Session 8	English	27-Oct-11
AutoCAD .NET - Session 7	English	20-Oct-11
AutoCAD .NET - Session 6	English	13-Oct-11
AutoCAD .NET - Session 5	English	6-Oct-11
AutoCAD .NET - Session 4	English	29-Sep-11
AutoCAD .NET - Session 3	English	22-Sep-11
AutoCAD .NET - Session 2	English	15-Sep-11
AutoCAD 2012 .NET API	Chinese	7-Jun-11
AutoCAD API	Chinese	14-Sep-10
AutoCAD API	English	13-Apr-10
AutoCAD: VBA to .NET Migration	English	20-Oct-09
AutoCAD - 0 to 3D in 60 Minutes	English	13-Oct-09
AutoCAD .NET: Developing a User Interface	English	20-Aug-09
AutoCAD: Using Windows Presentation Foundation in your Applications - Part 2	English	14-Jul-09
AutoCAD: Using Windows Presentation Foundation in your Applications - Part 1	English	2-Jun-09
AutoCAD .Net	Chinese	22-May-09
AutoCAD 2010 API for CUIX	English	2-Apr-09
Developer Days Online: AutoCAD	English	10-Feb-09
AutoCAD: .NET for LISP Programmers	English	16-Oct-08
AutoCAD .NET: Developing a User Interface	English	16-Sep-08
AutoCAD: Creating a UI using WPF	English	26-Aug-08
AutoCAD: Using Jigs in .NET	English	29-Jul-08
AutoCAD : Brep .NET	English	24-Jun-08
AutoCAD: Ribbons, Task Dialogs and Tooltips	English	29-May-08
AutoCAD: TransientGraphics API	English	15-May-08
AutoCAD P&ID API	English	14-May-08
AutoCAD: CUI Deployment Best Practices	English	25-Mar-08
AutoCAD: API Overview	English	21-Feb-08
AutoCAD: .NET for LISP Programmers	English	18-Oct-07
AutoCAD: 10 easy ways to crash your AutoCAD addin	English	4-Oct-07
AutoCAD: Creating an Installer	English	16-Aug-07
AutoCAD: Custom Objects Masterclass	English	12-Jul-07
AutoCAD: Storing custom data in a drawing	English	14-Jun-07

Autoloader and localization

By Augusto Goncalves

What's coming

Have you noticed that the Autodesk Exchange Store website is showing its UI interface in non-English? From the website perspective, it will automatically select the correct version according to the ‘Language’ settings of the browser, or you can select at the bottom of the page.

Now the interesting point: we’ll soon start accepting applications that are in other languages, including multi-language or localized only (e.g. German only apps).

This post will show how make your application work for multi-language using the Autoloader mechanism.

Background

The AutoCAD command registration can work with names in English and non-English, called Global and Local names, respectively. With .NET API we can implement this feature with Resources, as described here, which work for all supported languages on the same assembly, also can be used for command line strings and for other resources. Now ObjectARX supports one Global and one Local command name, usually one English and one non-English, and can load resources for different languages (if manually implemented). Finally Lisp don’t have a build-in localization feature.

The Autoloader mechanism (.bundle folder and PackageContents.xml) can be used when the application is multi-language (i.e. supporting more than 1 language). The XML support localization for almost all properties and modules, by loading the correct file according to the product language. If you application have only 1 language, even non-English, then there is no need for this localization features (as it will always load the same modules).

Approaches

There are some approaches to create an application that can work on different languages. In some cases, the application will have only one non-English language, for instance, if is designed for a specific market. As already mentioned, if is only 1 language, then no additional work is necessary (as the same modules will load every time).

If your code automatically identify the language and change its command name and interface, e.g. using .NET Resources, then great. This post will show the simples approach: separated modules for each language.

Using the PackageContents

Let say an application have 2 languages, English and Portuguese. The idea is to enable the ‘HelloWorld’ command on English systems and ‘OlaMundo’ on Portuguese systems (either by OS, AutoCAD or Regional Settings configured to this language). The images below show it running, of English and Portuguese environments, respectively.

For this case, there are 2 DLLs, that register and have all resources for both languages. The goal is to ensure only the correct DLL will be loaded on each system. This approach can be used for DLLs, ARX, DBX, Lisp or CUIx files, just specify which file is loaded on each supported locale and the Autoloader will make sure the correct version is loaded.

The following XML code show some attributes suffixed with Ptb, which then contain the specific version of the data, and the affected lines are marked in yellow. Note the OnlineDocumentation and ModuleName attributes. The last marked lines contains the commands names, Global and Local, where the Local is suffixed by Ptb. Other markup, line Description, are required so the user can understand what the application will do. The HelpFile will make sure the proper help is opened when the user press F1.

<?xml version="1.0" encoding="utf-8"?>

<ApplicationPackage SchemaVersion="1.0"

                    AutodeskProduct="AutoCAD"

                    Name="My Global Product"

                    Description="Global Product"

                    DescriptionPtb="Produto Global"

                    AppVersion="1.0.0"

                    FriendlyVersion="1.0.0"

                    ProductType="Application"

                    SupportedLocales="Enu|Ptb"

                    AppNameSpace="appstore.exchange.autodesk.com"

                    OnlineDocumentation="www.autodesk.com"

                    OnlineDocumentationPtb="www.autodesk.com.br"

                    Author="ADN DevTech"

                    HelpFile="./Contents/Resources/helpENU.html"

                    HelpFilePtb="./Contents/Resources/helpPTB.html"

                    ProductCode=""

                    UpgradeCode="">

 

  <CompanyDetails Name="ADN DevTech"

                  Url="http://www.autodesk.com"

                  Email="[email protected]" />

 

  <RuntimeRequirements OS="Win32|Win64"

                       Platform="AutoCAD" />

  <Components Description="MainDLL">

    <RuntimeRequirements OS="Win32|Win64"

                         Platform="AutoCAD"

                         SeriesMin="R19.0" SeriesMax="R19.1" />

    <ComponentEntry AppName="Main DLL" Version="1.0"

                    ModuleName="./Contents/Win/MainModule.enu.dll"

                    ModuleNamePtb="./Contents/Win/MainModule.ptb.dll"

                    AppDescription="This is the main module"

                    LoadOnCommandInvocation="True">

      <Commands>

        <Command

          LocalPtb="olaMundo"

          Global="helloWorld" />

      </Commands>

    </ComponentEntry>

  </Components>

</ApplicationPackage>

Finally the SupportedLocales markup will make sure the Exchange Store MSI is created for the desired languages (once the application is submitted).

The list of supported languages is (link):

• Chs - Chinese Simplified (PRC)
• Cht - Chinese Traditional (Taiwan)
• Csy – Czech
• Deu – German
• Enu – English
• Esp – Spanish
• Fra – French
• Hun – Hungarian
• Ita – Italian
• Jpn – Japanese
• Kor – Korean
• Plk – Polish
• Ptb – Portuguese
• Rus - Russian

You can find another article about this topic at this post.

Submit process

Once the application is ready, you can submit it to the store as usual. It will be evaluated by the Exchange Store team. The link will be the same (link), although not yet available.

Get and set layer and entity transparency using LISP

By Adam Nagy

Why doesn't the following code work? vla-get-transparency highlights as blue in the VLIDE, but I get this error:

"Error: ActiveX Server returned the error: unknown name: Transparency"

(setq ENT (entsel))

(if ENT

  (progn

    (setq VLA_OBJ_NAME (vlax-ename->vla-object (car ENT))

    VLA_OBJ_LAYER (vla-get-layer VLA_OBJ_NAME)

    VLA_ACT_DOC (vla-get-ActiveDocument (vlax-get-Acad-Object))

    LAYERNAME (vla-Item (vla-get-Layers VLA_ACT_DOC) VLA_OBJ_LAYER)

    )

    (if (>= (atof (substr (getvar "acadver") 1 4)) 18.1)

      (setq PROPTRAN (vla-get-transparency LAYERNAME))

    )

  )

)

Solution

The properties that you access when using the COM helpers of LISP are based on the ActiveX API.

If you look for the Transparency property in the ActiveX API, then you’ll find that it is only available for AcadRasterImage and AcadWipeout entities.

The Transparency for entities (which is only available in AutoCAD 2011) is provided by new interfaces like IAcadEntity2 and they are called EntityTransparency.

In case of layers however, there is no property like that.

That transparency value can be calculated from the layer’s XData. If it’s not there, then it’s the default 0%

; gets transparency in percentage 
(defun getLayerTransparency (layerName / layer transparency) 
  (setq layer (tblobjname "LAYER" layerName)) 
  ; get the XData of AcCmTransparency    
  (setq transparency (cdr (assoc 1071 (cdar (cdr (assoc -3 
    (entget layer '("AcCmTransparency")))))))) 
  (if (= transparency nil) 
    ; if we did not get a value it must be the default 0% 
    (setq transparency 0) 
    ; if we got a value then calculate from it 
    (progn 
      ; get the lower byte of the value 0..255 
      ; (100%..0% in the AutoCAD user interface) 
      (setq transparency (lsh (lsh transparency 24) -24)) 
      ; convert the value to a percentage 
      (setq transparency (fix (- 100 (/ transparency 2.55))))    
    ) ; (progn 
  ) ; (if  
)

(defun c:testGet (/ ent layerName transparency) 
  (setq ent (car (entsel))) 
  (setq layerName (cdr (assoc 8 (entget ent))))
  (setq transparency (getLayerTransparency layerName)) 
  (princ transparency) 
  (princ) 
)

It does not seem possible to set the value the same way - by adjusting the XData value -, but you can use the _LAYER command for that:

(defun c:testSet (/ ent layerName transparency) 
  (setq ent (car (entsel))) 
  (setq transparency (getint "Transparency value")) 
  (setq layerName (cdr (assoc 8 (entget ent))))
  (command "_LAYER" "_TR" transparency layerName "") 
  (princ) 
)

Code has been updated based on BlackBox's comments. Now it is not using unnecessary ActiveX function calls.